mirror of
https://github.com/microsoft/DirectXMath
synced 2024-11-08 13:40:09 +00:00
70 lines
2.0 KiB
CMake
70 lines
2.0 KiB
CMake
# Copyright (c) Microsoft Corporation.
|
|
# Licensed under the MIT License.
|
|
|
|
cmake_minimum_required (VERSION 3.14)
|
|
|
|
set(DIRECTXMATH_VERSION 3.1.7)
|
|
|
|
project(DirectXMath
|
|
VERSION ${DIRECTXMATH_VERSION}
|
|
DESCRIPTION "DirectXMath SIMD C++ math library"
|
|
HOMEPAGE_URL "https://go.microsoft.com/fwlink/?LinkID=615560"
|
|
LANGUAGES CXX)
|
|
|
|
include(GNUInstallDirs)
|
|
|
|
#--- Library
|
|
set(LIBRARY_HEADERS
|
|
Inc/DirectXCollision.h
|
|
Inc/DirectXCollision.inl
|
|
Inc/DirectXColors.h
|
|
Inc/DirectXMath.h
|
|
Inc/DirectXMathConvert.inl
|
|
Inc/DirectXMathMatrix.inl
|
|
Inc/DirectXMathMisc.inl
|
|
Inc/DirectXMathVector.inl
|
|
Inc/DirectXPackedVector.h
|
|
Inc/DirectXPackedVector.inl)
|
|
|
|
add_library(${PROJECT_NAME} INTERFACE)
|
|
|
|
target_include_directories(${PROJECT_NAME} INTERFACE
|
|
$<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/Inc>
|
|
$<INSTALL_INTERFACE:${CMAKE_INSTALL_INCLUDEDIR}/directxmath>)
|
|
|
|
target_compile_features(${PROJECT_NAME} INTERFACE cxx_std_11)
|
|
|
|
#--- Package
|
|
include(CMakePackageConfigHelpers)
|
|
|
|
string(TOLOWER ${PROJECT_NAME} PACKAGE_NAME)
|
|
|
|
write_basic_package_version_file(
|
|
${PACKAGE_NAME}-config-version.cmake
|
|
VERSION ${DIRECTXMATH_VERSION}
|
|
COMPATIBILITY AnyNewerVersion
|
|
ARCH_INDEPENDENT)
|
|
|
|
install(TARGETS ${PROJECT_NAME}
|
|
EXPORT ${PROJECT_NAME}-targets
|
|
ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
|
|
LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
|
|
RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR})
|
|
|
|
configure_package_config_file(${CMAKE_CURRENT_SOURCE_DIR}/.nuget/${PROJECT_NAME}-config.cmake.in
|
|
${CMAKE_CURRENT_BINARY_DIR}/${PACKAGE_NAME}-config.cmake
|
|
INSTALL_DESTINATION ${CMAKE_INSTALL_DATAROOTDIR}/${PACKAGE_NAME})
|
|
|
|
install(EXPORT ${PROJECT_NAME}-targets
|
|
FILE ${PROJECT_NAME}-targets.cmake
|
|
NAMESPACE Microsoft::
|
|
DESTINATION ${CMAKE_INSTALL_DATAROOTDIR}/${PACKAGE_NAME})
|
|
|
|
install(FILES ${LIBRARY_HEADERS}
|
|
DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}/directxmath)
|
|
|
|
install(FILES
|
|
${CMAKE_CURRENT_BINARY_DIR}/${PACKAGE_NAME}-config.cmake
|
|
${CMAKE_CURRENT_BINARY_DIR}/${PACKAGE_NAME}-config-version.cmake
|
|
DESTINATION ${CMAKE_INSTALL_DATAROOTDIR}/${PACKAGE_NAME})
|