mirror of
https://github.com/KhronosGroup/SPIRV-Tools
synced 2024-11-23 20:20:06 +00:00
bfd7cd6d6e
Add the following macros for logging purpose: * SPIRV_ASSERT * SPIRV_DEBUG * SPIRV_UNIMPLEMENTED * SPIRV_UNREACHABLE The last two is always turned on, while the first two can only be turned on in debug build.
162 lines
5.1 KiB
CMake
162 lines
5.1 KiB
CMake
# Copyright (c) 2015-2016 The Khronos Group Inc.
|
|
#
|
|
# Licensed under the Apache License, Version 2.0 (the "License");
|
|
# you may not use this file except in compliance with the License.
|
|
# You may obtain a copy of the License at
|
|
#
|
|
# http://www.apache.org/licenses/LICENSE-2.0
|
|
#
|
|
# Unless required by applicable law or agreed to in writing, software
|
|
# distributed under the License is distributed on an "AS IS" BASIS,
|
|
# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
|
|
# See the License for the specific language governing permissions and
|
|
# limitations under the License.
|
|
|
|
cmake_minimum_required(VERSION 2.8.12)
|
|
if (POLICY CMP0054)
|
|
# Avoid dereferencing variables or interpret keywords that have been
|
|
# quoted or bracketed.
|
|
# https://cmake.org/cmake/help/v3.1/policy/CMP0054.html
|
|
cmake_policy(SET CMP0054 NEW)
|
|
endif()
|
|
|
|
project(spirv-tools)
|
|
enable_testing()
|
|
set(SPIRV_TOOLS "SPIRV-Tools")
|
|
|
|
set(CMAKE_POSITION_INDEPENDENT_CODE ON)
|
|
|
|
if("${CMAKE_SYSTEM_NAME}" STREQUAL "Linux")
|
|
add_definitions(-DSPIRV_LINUX)
|
|
elseif("${CMAKE_SYSTEM_NAME}" STREQUAL "Windows")
|
|
add_definitions(-DSPIRV_WINDOWS)
|
|
elseif("${CMAKE_SYSTEM_NAME}" STREQUAL "Darwin")
|
|
add_definitions(-DSPIRV_MAC)
|
|
elseif("${CMAKE_SYSTEM_NAME}" STREQUAL "Android")
|
|
add_definitions(-DSPIRV_ANDROID)
|
|
else()
|
|
message(FATAL_ERROR "Your platform '${CMAKE_SYSTEM_NAME}' is not supported!")
|
|
endif()
|
|
|
|
if ("${CMAKE_BUILD_TYPE}" STREQUAL "")
|
|
message(STATUS "No build type selected, default to Debug")
|
|
set(CMAKE_BUILD_TYPE "Debug")
|
|
endif()
|
|
|
|
option(SPIRV_WERROR "Enable error on warning" ON)
|
|
if(("${CMAKE_CXX_COMPILER_ID}" MATCHES "GNU") OR ("${CMAKE_CXX_COMPILER_ID}" MATCHES "Clang"))
|
|
set(COMPILER_IS_LIKE_GNU TRUE)
|
|
endif()
|
|
if(${COMPILER_IS_LIKE_GNU})
|
|
set(SPIRV_WARNINGS -Wall -Wextra -Wno-missing-field-initializers)
|
|
|
|
option(SPIRV_WARN_EVERYTHING "Enable -Weverything" ${SPIRV_WARN_EVERYTHING})
|
|
if(${SPIRV_WARN_EVERYTHING})
|
|
if("${CMAKE_CXX_COMPILER_ID}" STREQUAL "Clang")
|
|
set(SPIRV_WARNINGS ${SPIRV_WARNINGS}
|
|
-Weverything -Wno-c++98-compat -Wno-c++98-compat-pedantic -Wno-padded)
|
|
elseif("${CMAKE_CXX_COMPILER_ID}" STREQUAL "GNU")
|
|
set(SPIRV_WARNINGS ${SPIRV_WARNINGS} -Wpedantic -pedantic-errors)
|
|
else()
|
|
message(STATUS "Unknown compiler ${CMAKE_CXX_COMPILER_ID}, "
|
|
"so SPIRV_WARN_EVERYTHING has no effect")
|
|
endif()
|
|
endif()
|
|
|
|
if(${SPIRV_WERROR})
|
|
set(SPIRV_WARNINGS ${SPIRV_WARNINGS} -Werror)
|
|
endif()
|
|
elseif(MSVC)
|
|
set(SPIRV_WARNINGS -D_CRT_SECURE_NO_WARNINGS /wd4800)
|
|
|
|
if(${SPIRV_WERROR})
|
|
set(SPIRV_WARNINGS ${SPIRV_WARNINGS} /WX)
|
|
endif()
|
|
endif()
|
|
|
|
include_directories(${CMAKE_CURRENT_SOURCE_DIR}/source)
|
|
|
|
option(SPIRV_COLOR_TERMINAL "Enable color terminal output" ON)
|
|
if(${SPIRV_COLOR_TERMINAL})
|
|
add_definitions(-DSPIRV_COLOR_TERMINAL)
|
|
endif()
|
|
|
|
option(SPIRV_LOG_DEBUG "Enable excessive debug output" OFF)
|
|
if(${SPIRV_LOG_DEBUG})
|
|
add_definitions(-DSPIRV_LOG_DEBUG)
|
|
endif()
|
|
|
|
function(spvtools_default_compile_options TARGET)
|
|
target_compile_options(${TARGET} PRIVATE ${SPIRV_WARNINGS})
|
|
|
|
if (${COMPILER_IS_LIKE_GNU})
|
|
target_compile_options(${TARGET} PRIVATE
|
|
-std=c++11 -fno-exceptions -fno-rtti)
|
|
target_compile_options(${TARGET} PRIVATE
|
|
-Wall -Wextra -Wno-long-long -Wshadow -Wundef -Wconversion
|
|
-Wno-sign-conversion)
|
|
# For good call stacks in profiles, keep the frame pointers.
|
|
if(NOT "${SPIRV_PERF}" STREQUAL "")
|
|
target_compile_options(${TARGET} PRIVATE -fno-omit-frame-pointer)
|
|
endif()
|
|
if("${CMAKE_CXX_COMPILER_ID}" STREQUAL "Clang")
|
|
set(SPIRV_USE_SANITIZER "" CACHE STRING
|
|
"Use the clang sanitizer [address|memory|thread|...]")
|
|
if(NOT "${SPIRV_USE_SANITIZER}" STREQUAL "")
|
|
target_compile_options(${TARGET} PRIVATE
|
|
-fsanitize=${SPIRV_USE_SANITIZER})
|
|
endif()
|
|
else()
|
|
target_compile_options(${TARGET} PRIVATE
|
|
-Wno-missing-field-initializers)
|
|
endif()
|
|
endif()
|
|
|
|
# For MinGW cross compile, statically link to the C++ runtime.
|
|
# But it still depends on MSVCRT.dll.
|
|
if (${CMAKE_SYSTEM_NAME} MATCHES "Windows")
|
|
if (${CMAKE_CXX_COMPILER_ID} MATCHES "GNU")
|
|
set_target_properties(${TARGET} PROPERTIES
|
|
LINK_FLAGS -static -static-libgcc -static-libstdc++)
|
|
endif()
|
|
endif()
|
|
endfunction()
|
|
|
|
if(NOT COMMAND find_host_package)
|
|
macro(find_host_package)
|
|
find_package(${ARGN})
|
|
endmacro()
|
|
endif()
|
|
if(NOT COMMAND find_host_program)
|
|
macro(find_host_program)
|
|
find_program(${ARGN})
|
|
endmacro()
|
|
endif()
|
|
|
|
find_host_package(PythonInterp)
|
|
|
|
|
|
# Defaults to OFF if the user didn't set it.
|
|
option(SPIRV_SKIP_EXECUTABLES
|
|
"Skip building the executable and tests along with the library"
|
|
${SPIRV_SKIP_EXECUTABLES})
|
|
option(SPIRV_SKIP_TESTS
|
|
"Skip building tests along with the library" ${SPIRV_SKIP_TESTS})
|
|
if ("${SPIRV_SKIP_EXECUTABLES}")
|
|
set(SPIRV_SKIP_TESTS ON)
|
|
endif()
|
|
|
|
add_subdirectory(external)
|
|
|
|
add_subdirectory(source)
|
|
add_subdirectory(tools)
|
|
|
|
add_subdirectory(test)
|
|
|
|
install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/include/spirv-tools/libspirv.h
|
|
DESTINATION include/spirv-tools/)
|
|
|
|
add_test(NAME spirv-tools-copyrights
|
|
COMMAND ${PYTHON_EXECUTABLE} utils/check_copyright.py
|
|
WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR})
|