mirror of
https://sourceware.org/git/glibc.git
synced 2024-11-17 18:40:14 +00:00
60 lines
1.2 KiB
ArmAsm
60 lines
1.2 KiB
ArmAsm
|
/*
|
||
|
|
* Written by J.T. Conklin <jtc@netbsd.org>.
|
||
|
|
* Adapted for use as log2 by Ulrich Drepper <drepper@cygnus.com>.
|
||
|
|
* Public domain.
|
||
|
|
*
|
||
|
|
* Changed to use fyl2xp1 for values near 1, <drepper@cygnus.com>.
|
||
|
|
*/
|
||
|
|
|
||
|
|
#include <machine/asm.h>
|
||
|
|
|
||
|
|
#ifdef __ELF__
|
||
|
|
.section .rodata
|
||
|
|
#else
|
||
|
|
.text
|
||
|
|
#endif
|
||
|
|
.align ALIGNARG(4)
|
||
|
|
ASM_TYPE_DIRECTIVE(one,@object)
|
||
|
|
one: .double 1.0
|
||
|
|
ASM_SIZE_DIRECTIVE(one)
|
||
|
|
/* It is not important that this constant is precise. It is only
|
||
|
|
a value which is known to be on the safe side for using the
|
||
|
|
fyl2xp1 instruction. */
|
||
|
|
ASM_TYPE_DIRECTIVE(limit,@object)
|
||
|
|
limit: .double 0.29
|
||
|
|
ASM_SIZE_DIRECTIVE(limit)
|
||
|
|
|
||
|
|
|
||
|
|
#ifdef PIC
|
||
|
|
#define MO(op) op##@GOTOFF(%edx)
|
||
|
|
#else
|
||
|
|
#define MO(op) op
|
||
|
|
#endif
|
||
|
|
|
||
|
|
.text
|
||
|
|
ENTRY(__log2f)
|
||
|
|
#ifdef PIC
|
||
|
|
call 1f
|
||
|
|
1: popl %edx
|
||
|
|
addl $_GLOBAL_OFFSET_TABLE_+[.-1b], %edx
|
||
|
|
#endif
|
||
|
|
fldl MO(one)
|
||
|
|
flds 4(%esp) // x : 1
|
||
|
|
fld %st // x : x : 1
|
||
|
|
fsub %st(2), %st // x-1 : x : 1
|
||
|
|
fld %st // x-1 : x-1 : x : 1
|
||
|
|
fabs // |x-1| : x-1 : x : 1
|
||
|
|
fcompl MO(limit) // x-1 : x : 1
|
||
|
|
fnstsw // x-1 : x : 1
|
||
|
|
andb $0x45, %ah
|
||
|
|
jz 2f
|
||
|
|
fstp %st(1) // x-1 : 1
|
||
|
|
fyl2xp1 // log(x)
|
||
|
|
ret
|
||
|
|
|
||
|
|
2: fstp %st(0) // x : 1
|
||
|
|
fyl2x // log(x)
|
||
|
|
ret
|
||
|
|
END (__log2f)
|
||
|
|
weak_alias (__log2f, log2f)
|