AuroraMiddleware/glibc
1
0
Fork 0
mirror of https://sourceware.org/git/glibc.git synced 2024-12-23 11:20:07 +00:00
Code Issues Packages Projects Releases Wiki Activity

getcontext implementation for Linux/x86.

Browse Source
This commit is contained in:
Ulrich Drepper 2001-04-07 20:08:02 +00:00
parent 6e6917b042
commit 71483c00a8
1 changed files with 79 additions and 0 deletions
Show Stats Download Patch File Download Diff File Expand all files Collapse all files

79
sysdeps/unix/sysv/linux/i386/getcontext.S Normal file
View File

@ -0,0 +1,79 @@
/* Save current context.
Copyright (C) 2001 Free Software Foundation, Inc.
This file is part of the GNU C Library.
Contributed by Ulrich Drepper <drepper@redhat.com>, 2001.
The GNU C Library is free software; you can redistribute it and/or
modify it under the terms of the GNU Library General Public License as
published by the Free Software Foundation; either version 2 of the
License, or (at your option) any later version.
The GNU C Library is distributed in the hope that it will be useful,
but WITHOUT ANY WARRANTY; without even the implied warranty of
MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
Library General Public License for more details.
You should have received a copy of the GNU Library General Public
License along with the GNU C Library; see the file COPYING.LIB. If not,
write to the Free Software Foundation, Inc., 59 Temple Place - Suite 330,
Boston, MA 02111-1307, USA. */
#include <sysdep.h>
#include "ucontext_i.h"
ENTRY(__getcontext)
/* Load address of the context data structure. */
movl 4(%esp), %eax
/* Return value of getcontext. EAX is the only register whose
value is not preserved. */
movl $0, oEAX(%eax)
/* Save the 32-bit register values and the return address. */
movl %ecx, oECX(%eax)
movl %edx, oEDX(%eax)
movl %edi, oEDI(%eax)
movl %esi, oESI(%eax)
movl %ebp, oEBP(%eax)
movl (%esp), %ecx
movl %ecx, oEIP(%eax)
leal 4(%esp), %ecx /* Exclude the return address. */
movl %ecx, oESP(%eax)
movl %ebx, oEBX(%eax)
/* Save the FS and GS segment register. */
xorl %edx, %edx
xorl %ecx, %ecx
movw %gs, %dx
movw %fs, %cx
movl %edx, oGS(%eax)
movl %ecx, oFS(%eax)
/* We have separate floating-point register content memory on the
stack. We use the __fpregs_mem block in the context. Set the
links up correctly. */
leal oFPREGSMEM(%eax), %ecx
movl %ecx, oFPREGS(%eax)
/* Save the floating-point context. */
fnstenv (%ecx)
/* Save the current signal mask. */
pushl %ebx
leal oSIGMASK(%eax), %edx
xorl %ecx, %ecx
movl $SIG_BLOCK, %ebx
movl $__NR_sigprocmask, %eax
int $0x80
popl %ebx
cmpl $-4095, %eax /* Check %eax for error. */
jae SYSCALL_ERROR_LABEL /* Jump to error handler if error. */
/* All done, return 0 for success. */
xorl %eax, %eax
L(pseudo_end):
ret
PSEUDO_END(__getcontext)
weak_alias(__getcontext, getcontext)