mirror of
https://sourceware.org/git/glibc.git
synced 2024-12-31 06:51:11 +00:00
Update.
2003-10-31 Steven Munroe <sjmunroe@us.ibm.com> * sysdeps/powerpc/powerpc32/strncmp.S: New File. * sysdeps/powerpc/powerpc64/strncmp.S: New File.
This commit is contained in:
Ulrich Drepper
parent
0a86d4ae81
commit
7df11052ce
@ -1,3 +1,8 @@
|
||||
2003-10-31 Steven Munroe <sjmunroe@us.ibm.com>
|
||||
|
||||
* sysdeps/powerpc/powerpc32/strncmp.S: New File.
|
||||
* sysdeps/powerpc/powerpc64/strncmp.S: New File.
|
||||
|
||||
2003-11-01 Randolph Chung <tausq@debian.org>
|
||||
|
||||
* sysdeps/unix/sysv/linux/hppa/sysdep.h (LOAD_ARGS_0, LOAD_ARGS_1,
|
||||
|
||||
156
sysdeps/powerpc/powerpc32/strncmp.S
Normal file
156
sysdeps/powerpc/powerpc32/strncmp.S
Normal file
@ -0,0 +1,156 @@
|
||||
/* Optimized strcmp implementation for PowerPC32.
|
||||
Copyright (C) 2003 Free Software Foundation, Inc.
|
||||
This file is part of the GNU C Library.
|
||||
|
||||
The GNU C Library is free software; you can redistribute it and/or
|
||||
modify it under the terms of the GNU Lesser General Public
|
||||
License as published by the Free Software Foundation; either
|
||||
version 2.1 of the License, or (at your option) any later version.
|
||||
|
||||
The GNU C Library is distributed in the hope that it will be useful,
|
||||
but WITHOUT ANY WARRANTY; without even the implied warranty of
|
||||
MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
|
||||
Lesser General Public License for more details.
|
||||
|
||||
You should have received a copy of the GNU Lesser General Public
|
||||
License along with the GNU C Library; if not, write to the Free
|
||||
Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
|
||||
02111-1307 USA. */
|
||||
|
||||
#include <sysdep.h>
|
||||
#include <bp-sym.h>
|
||||
#include <bp-asm.h>
|
||||
|
||||
/* See strlen.s for comments on how the end-of-string testing works. */
|
||||
|
||||
/* int [r3] strncmp (const char *s1 [r3], const char *s2 [r4], size_t size [r5]) */
|
||||
|
||||
EALIGN (BP_SYM(strncmp), 4, 0)
|
||||
|
||||
#define rTMP r0
|
||||
#define rRTN r3
|
||||
#define rSTR1 r3 /* first string arg */
|
||||
#define rSTR2 r4 /* second string arg */
|
||||
#define rN r5 /* max string length */
|
||||
/* Note: The Bounded pointer support in this code is broken. This code
|
||||
was inherited from PPC32 and and that support was never completed.
|
||||
Current PPC gcc does not support -fbounds-check or -fbounded-pointers. */
|
||||
#define rWORD1 r6 /* current word in s1 */
|
||||
#define rWORD2 r7 /* current word in s2 */
|
||||
#define rFEFE r8 /* constant 0xfefefeff (-0x01010101) */
|
||||
#define r7F7F r9 /* constant 0x7f7f7f7f */
|
||||
#define rNEG r10 /* ~(word in s1 | 0x7f7f7f7f) */
|
||||
#define rBITDIF r11 /* bits that differ in s1 & s2 words */
|
||||
|
||||
dcbt 0,rSTR1
|
||||
or rTMP, rSTR2, rSTR1
|
||||
lis r7F7F, 0x7f7f
|
||||
dcbt 0,rSTR2
|
||||
clrlwi. rTMP, rTMP, 30
|
||||
lis rFEFE, -0x101
|
||||
bne L(unaligned)
|
||||
/* We are word alligned so set up for two loops. first a word
|
||||
loop, then fall into the byte loop if any residual. */
|
||||
srwi. rTMP, rN, 2
|
||||
clrlwi rN, rN, 30
|
||||
addi rFEFE, rFEFE, -0x101
|
||||
addi r7F7F, r7F7F, 0x7f7f
|
||||
beq L(unaligned)
|
||||
|
||||
mtctr rTMP /* Power4 wants mtctr 1st in dispatch group. */
|
||||
lwz rWORD1, 0(rSTR1)
|
||||
lwz rWORD2, 0(rSTR2)
|
||||
b L(g1)
|
||||
|
||||
L(g0):
|
||||
lwzu rWORD1, 4(rSTR1)
|
||||
bne- cr1, L(different)
|
||||
lwzu rWORD2, 4(rSTR2)
|
||||
L(g1): add rTMP, rFEFE, rWORD1
|
||||
nor rNEG, r7F7F, rWORD1
|
||||
bdz L(tail)
|
||||
and. rTMP, rTMP, rNEG
|
||||
cmpw cr1, rWORD1, rWORD2
|
||||
beq+ L(g0)
|
||||
|
||||
/* OK. We've hit the end of the string. We need to be careful that
|
||||
we don't compare two strings as different because of gunk beyond
|
||||
the end of the strings... */
|
||||
|
||||
L(endstring):
|
||||
and rTMP, r7F7F, rWORD1
|
||||
beq cr1, L(equal)
|
||||
add rTMP, rTMP, r7F7F
|
||||
xor. rBITDIF, rWORD1, rWORD2
|
||||
|
||||
andc rNEG, rNEG, rTMP
|
||||
blt- L(highbit)
|
||||
cntlzw rBITDIF, rBITDIF
|
||||
cntlzw rNEG, rNEG
|
||||
addi rNEG, rNEG, 7
|
||||
cmpw cr1, rNEG, rBITDIF
|
||||
sub rRTN, rWORD1, rWORD2
|
||||
blt- cr1, L(equal)
|
||||
srawi rRTN, rRTN, 31
|
||||
ori rRTN, rRTN, 1
|
||||
blr
|
||||
L(equal):
|
||||
li rRTN, 0
|
||||
blr
|
||||
|
||||
L(different):
|
||||
lwzu rWORD1, -4(rSTR1)
|
||||
xor. rBITDIF, rWORD1, rWORD2
|
||||
sub rRTN, rWORD1, rWORD2
|
||||
blt- L(highbit)
|
||||
srawi rRTN, rRTN, 31
|
||||
ori rRTN, rRTN, 1
|
||||
blr
|
||||
L(highbit):
|
||||
srwi rWORD2, rWORD2, 24
|
||||
srwi rWORD1, rWORD1, 24
|
||||
sub rRTN, rWORD1, rWORD2
|
||||
blr
|
||||
|
||||
|
||||
/* Oh well. In this case, we just do a byte-by-byte comparison. */
|
||||
.align 4
|
||||
L(tail):
|
||||
and. rTMP, rTMP, rNEG
|
||||
cmpw cr1, rWORD1, rWORD2
|
||||
bne- L(endstring)
|
||||
addi rSTR1, rSTR1, 4
|
||||
bne- cr1, L(different)
|
||||
addi rSTR2, rSTR2, 4
|
||||
L(unaligned):
|
||||
mtctr rN /* Power4 wants mtctr 1st in dispatch group */
|
||||
cmpwi rN,0
|
||||
lbz rWORD1, 0(rSTR1)
|
||||
lbz rWORD2, 0(rSTR2)
|
||||
bgt L(u1)
|
||||
L(ux):
|
||||
li rRTN, 0
|
||||
blr
|
||||
|
||||
L(u0):
|
||||
lbzu rWORD2, 1(rSTR2)
|
||||
L(u1):
|
||||
bdz L(u3)
|
||||
cmpwi cr1, rWORD1, 0
|
||||
cmpw rWORD1, rWORD2
|
||||
beq- cr1, L(u3)
|
||||
lbzu rWORD1, 1(rSTR1)
|
||||
bne- L(u2)
|
||||
lbzu rWORD2, 1(rSTR2)
|
||||
bdz L(u3)
|
||||
cmpwi cr1, rWORD1, 0
|
||||
cmpw rWORD1, rWORD2
|
||||
bne- L(u3)
|
||||
lbzu rWORD1, 1(rSTR1)
|
||||
bne+ cr1, L(u0)
|
||||
|
||||
L(u2): lbzu rWORD1, -1(rSTR1)
|
||||
L(u3): sub rRTN, rWORD1, rWORD2
|
||||
blr
|
||||
END (BP_SYM (strncmp))
|
||||
libc_hidden_builtin_def (strncmp)
|
||||
159
sysdeps/powerpc/powerpc64/strncmp.S
Normal file
159
sysdeps/powerpc/powerpc64/strncmp.S
Normal file
@ -0,0 +1,159 @@
|
||||
/* Optimized strcmp implementation for PowerPC64.
|
||||
Copyright (C) 2003 Free Software Foundation, Inc.
|
||||
This file is part of the GNU C Library.
|
||||
|
||||
The GNU C Library is free software; you can redistribute it and/or
|
||||
modify it under the terms of the GNU Lesser General Public
|
||||
License as published by the Free Software Foundation; either
|
||||
version 2.1 of the License, or (at your option) any later version.
|
||||
|
||||
The GNU C Library is distributed in the hope that it will be useful,
|
||||
but WITHOUT ANY WARRANTY; without even the implied warranty of
|
||||
MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
|
||||
Lesser General Public License for more details.
|
||||
|
||||
You should have received a copy of the GNU Lesser General Public
|
||||
License along with the GNU C Library; if not, write to the Free
|
||||
Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
|
||||
02111-1307 USA. */
|
||||
|
||||
#include <sysdep.h>
|
||||
#include <bp-sym.h>
|
||||
#include <bp-asm.h>
|
||||
|
||||
/* See strlen.s for comments on how the end-of-string testing works. */
|
||||
|
||||
/* int [r3] strncmp (const char *s1 [r3], const char *s2 [r4], size_t size [r5]) */
|
||||
|
||||
EALIGN (BP_SYM(strncmp), 4, 0)
|
||||
|
||||
#define rTMP r0
|
||||
#define rRTN r3
|
||||
#define rSTR1 r3 /* first string arg */
|
||||
#define rSTR2 r4 /* second string arg */
|
||||
#define rN r5 /* max string length */
|
||||
/* Note: The Bounded pointer support in this code is broken. This code
|
||||
was inherited from PPC32 and and that support was never completed.
|
||||
Current PPC gcc does not support -fbounds-check or -fbounded-pointers. */
|
||||
#define rWORD1 r6 /* current word in s1 */
|
||||
#define rWORD2 r7 /* current word in s2 */
|
||||
#define rFEFE r8 /* constant 0xfefefefefefefeff (-0x0101010101010101) */
|
||||
#define r7F7F r9 /* constant 0x7f7f7f7f7f7f7f7f */
|
||||
#define rNEG r10 /* ~(word in s1 | 0x7f7f7f7f7f7f7f7f) */
|
||||
#define rBITDIF r11 /* bits that differ in s1 & s2 words */
|
||||
|
||||
dcbt 0,rSTR1
|
||||
or rTMP, rSTR2, rSTR1
|
||||
lis r7F7F, 0x7f7f
|
||||
dcbt 0,rSTR2
|
||||
clrldi. rTMP, rTMP, 61
|
||||
lis rFEFE, -0x101
|
||||
bne L(unaligned)
|
||||
/* We are doubleword alligned so set up for two loops. first a double word
|
||||
loop, then fall into the byte loop if any residual. */
|
||||
srdi. rTMP, rN, 3
|
||||
clrldi rN, rN, 61
|
||||
addi rFEFE, rFEFE, -0x101
|
||||
addi r7F7F, r7F7F, 0x7f7f
|
||||
beq L(unaligned)
|
||||
|
||||
mtctr rTMP /* Power4 wants mtctr 1st in dispatch group. */
|
||||
ld rWORD1, 0(rSTR1)
|
||||
ld rWORD2, 0(rSTR2)
|
||||
sldi rTMP, rFEFE, 32
|
||||
insrdi r7F7F, r7F7F, 32, 0
|
||||
add rFEFE, rFEFE, rTMP
|
||||
b L(g1)
|
||||
|
||||
L(g0):
|
||||
ldu rWORD1, 8(rSTR1)
|
||||
bne- cr1, L(different)
|
||||
ldu rWORD2, 8(rSTR2)
|
||||
L(g1): add rTMP, rFEFE, rWORD1
|
||||
nor rNEG, r7F7F, rWORD1
|
||||
bdz L(tail)
|
||||
and. rTMP, rTMP, rNEG
|
||||
cmpd cr1, rWORD1, rWORD2
|
||||
beq+ L(g0)
|
||||
|
||||
/* OK. We've hit the end of the string. We need to be careful that
|
||||
we don't compare two strings as different because of gunk beyond
|
||||
the end of the strings... */
|
||||
|
||||
L(endstring):
|
||||
and rTMP, r7F7F, rWORD1
|
||||
beq cr1, L(equal)
|
||||
add rTMP, rTMP, r7F7F
|
||||
xor. rBITDIF, rWORD1, rWORD2
|
||||
|
||||
andc rNEG, rNEG, rTMP
|
||||
blt- L(highbit)
|
||||
cntlzd rBITDIF, rBITDIF
|
||||
cntlzd rNEG, rNEG
|
||||
addi rNEG, rNEG, 7
|
||||
cmpd cr1, rNEG, rBITDIF
|
||||
sub rRTN, rWORD1, rWORD2
|
||||
blt- cr1, L(equal)
|
||||
sradi rRTN, rRTN, 63
|
||||
ori rRTN, rRTN, 1
|
||||
blr
|
||||
L(equal):
|
||||
li rRTN, 0
|
||||
blr
|
||||
|
||||
L(different):
|
||||
ldu rWORD1, -8(rSTR1)
|
||||
xor. rBITDIF, rWORD1, rWORD2
|
||||
sub rRTN, rWORD1, rWORD2
|
||||
blt- L(highbit)
|
||||
sradi rRTN, rRTN, 63
|
||||
ori rRTN, rRTN, 1
|
||||
blr
|
||||
L(highbit):
|
||||
srdi rWORD2, rWORD2, 56
|
||||
srdi rWORD1, rWORD1, 56
|
||||
sub rRTN, rWORD1, rWORD2
|
||||
blr
|
||||
|
||||
|
||||
/* Oh well. In this case, we just do a byte-by-byte comparison. */
|
||||
.align 4
|
||||
L(tail):
|
||||
and. rTMP, rTMP, rNEG
|
||||
cmpd cr1, rWORD1, rWORD2
|
||||
bne- L(endstring)
|
||||
addi rSTR1, rSTR1, 8
|
||||
bne- cr1, L(different)
|
||||
addi rSTR2, rSTR2, 8
|
||||
L(unaligned):
|
||||
mtctr rN /* Power4 wants mtctr 1st in dispatch group */
|
||||
cmpdi rN,0
|
||||
lbz rWORD1, 0(rSTR1)
|
||||
lbz rWORD2, 0(rSTR2)
|
||||
bgt L(u1)
|
||||
L(ux):
|
||||
li rRTN, 0
|
||||
blr
|
||||
|
||||
L(u0):
|
||||
lbzu rWORD2, 1(rSTR2)
|
||||
L(u1):
|
||||
bdz L(u3)
|
||||
cmpdi cr1, rWORD1, 0
|
||||
cmpd rWORD1, rWORD2
|
||||
beq- cr1, L(u3)
|
||||
lbzu rWORD1, 1(rSTR1)
|
||||
bne- L(u2)
|
||||
lbzu rWORD2, 1(rSTR2)
|
||||
bdz L(u3)
|
||||
cmpdi cr1, rWORD1, 0
|
||||
cmpd rWORD1, rWORD2
|
||||
bne- L(u3)
|
||||
lbzu rWORD1, 1(rSTR1)
|
||||
bne+ cr1, L(u0)
|
||||
|
||||
L(u2): lbzu rWORD1, -1(rSTR1)
|
||||
L(u3): sub rRTN, rWORD1, rWORD2
|
||||
blr
|
||||
END (BP_SYM (strncmp))
|
||||
libc_hidden_builtin_def (strncmp)
|
||||
Loading…
Reference in New Issue
Block a user