mirror of
https://sourceware.org/git/glibc.git
synced 2024-11-08 14:20:07 +00:00
af296fcdab
This patch removes the --enable-oldest-abi configure option, which has long been bitrotten (as reported in bug 6652). The principle of removing this option was agreed in the thread starting at <https://sourceware.org/ml/libc-alpha/2013-07/msg00174.html>. Tested for x86_64 and x86 that the installed shared libraries other than libc.so are unchanged by this patch and that libc.so disassembly and symbol versions are unchanged (debug info changes because of changed line numbers in csu/version.c). [BZ #6652] * Makeconfig (soversions-default-setname): Remove variable. ($(common-objpfx)soversions.i): Don't pass default_setname to soversions.awk. * Makerules ($(common-objpfx)abi-versions.h): Don't pass oldest_abi to abi-versions.awk. * config.h.in (GLIBC_OLDEST_ABI): Remove macro undefine. * config.make.in (oldest-abi): Remove variable. * configure.ac (--enable-oldest-abi): Remove configure option. * configure: Regenerated. * csu/version.c (banner) [GLIBC_OLDEST_ABI]: Remove conditional text. * scripts/abi-versions.awk: Do not handle oldest_abi variable. * scripts/soversions.awk: Do not handle default_setname variable. * sysdeps/mach/hurd/configure.ac: Do not handle oldest_abi variable. * sysdeps/mach/hurd/configure: Regenerated. * sysdeps/unix/sysv/linux/configure.ac: Do not handle oldest_abi variable. * sysdeps/unix/sysv/linux/configure: Regenerated.
47 lines
1.0 KiB
Awk
47 lines
1.0 KiB
Awk
# Script to generate <abi-versions.h> header file from Versions.all list.
|
|
# See include/shlib-compat.h comments for explanation.
|
|
|
|
BEGIN {
|
|
print "/* This file is automatically generated by abi-versions.awk.";
|
|
print " It defines symbols used by shlib-compat.h, which see. */";
|
|
print "\n#ifndef _ABI_VERSIONS_H\n#define _ABI_VERSIONS_H";
|
|
}
|
|
|
|
NF == 2 && $2 == "{" {
|
|
thislib = $1;
|
|
gsub(/[^A-Za-z0-9_ ]/, "_"); libid = $1;
|
|
printf "\n/* start %s */\n", thislib;
|
|
n = 0;
|
|
start = 0;
|
|
next;
|
|
}
|
|
$1 == "}" {
|
|
printf "/* end %s */\n", thislib;
|
|
next;
|
|
}
|
|
|
|
$2 == "=" {
|
|
old = $1; new = $3;
|
|
gsub(/[^A-Za-z0-9_ ]/, "_");
|
|
oldid = $1; newid = $3;
|
|
|
|
printf "#define ABI_%s_%s\tABI_%s_%s\n", libid, oldid, libid, newid;
|
|
printf "#define VERSION_%s_%s\t%s\n", libid, oldid, new;
|
|
|
|
next;
|
|
}
|
|
|
|
{
|
|
vers = $1;
|
|
gsub(/[^A-Za-z0-9_ ]/, "_");
|
|
versid = $1;
|
|
|
|
printf "#define ABI_%s_%s\t%d\t/* support %s */\n", libid, versid, ++n, vers;
|
|
printf "#define VERSION_%s_%s\t%s\n", libid, versid, vers;
|
|
next;
|
|
}
|
|
|
|
END {
|
|
print "\n#endif /* abi-versions.h */";
|
|
}
|