mirror of
https://sourceware.org/git/glibc.git
synced 2024-11-23 13:30:06 +00:00
f7be737659
According to ISO C Annex F, log (1) should be +0 in all rounding modes, but some implementations in glibc wrongly return -0 in round-downward mode (mapping to log1p (x - 1) is problematic because 1 - 1 is -0 in round-downward mode, and log1p (-0) is -0). This patch fixes this. (It helps with some implementations of other functions such as acosh, log2 and log10 that call out to log, but not enough to enable all-rounding-modes testing for those functions without further fixes to other implementations of them.) Tested x86_64 and x86 and ulps updated accordingly, and did spot tests for mips64 for the ldbl-128 fix, and i586 for the sysdeps/i386/fpu implementations shadowed by those in sysdeps/i386/i686/fpu. [BZ #16731] * sysdeps/i386/fpu/e_log.S (__ieee754_log): Take absolute value when x - 1 is zero. * sysdeps/i386/fpu/e_logf.S (__ieee754_logf): Likewise. * sysdeps/i386/fpu/e_logl.S (__ieee754_logl): Likewise. * sysdeps/i386/i686/fpu/e_logl.S (__ieee754_logl): Likewise. * sysdeps/ieee754/dbl-64/e_log.c (__ieee754_log): Return +0 when argument is 1. * sysdeps/ieee754/ldbl-128/e_logl.c (__ieee754_logl): Likewise. * sysdeps/x86_64/fpu/e_logl.S: Take absolute value when x - 1 is zero. * math/libm-test.inc (log_test): Use ALL_RM_TEST. * sysdeps/i386/fpu/libm-test-ulps: Update. * sysdeps/x86_64/fpu/libm-test-ulps: Likewise.
88 lines
1.7 KiB
ArmAsm
88 lines
1.7 KiB
ArmAsm
/*
|
|
* Written by J.T. Conklin <jtc@netbsd.org>.
|
|
* Public domain.
|
|
*
|
|
* Adapted for `long double' by Ulrich Drepper <drepper@cygnus.com>.
|
|
*/
|
|
|
|
#include <machine/asm.h>
|
|
|
|
|
|
.section .rodata.cst8,"aM",@progbits,8
|
|
|
|
.p2align 3
|
|
.type one,@object
|
|
one: .double 1.0
|
|
ASM_SIZE_DIRECTIVE(one)
|
|
/* It is not important that this constant is precise. It is only
|
|
a value which is known to be on the safe side for using the
|
|
fyl2xp1 instruction. */
|
|
.type limit,@object
|
|
limit: .double 0.29
|
|
ASM_SIZE_DIRECTIVE(limit)
|
|
|
|
|
|
#ifdef PIC
|
|
# define MO(op) op##@GOTOFF(%edx)
|
|
#else
|
|
# define MO(op) op
|
|
#endif
|
|
|
|
.text
|
|
ENTRY(__ieee754_logl)
|
|
fldln2 // log(2)
|
|
fldt 4(%esp) // x : log(2)
|
|
fxam
|
|
fnstsw
|
|
#ifdef PIC
|
|
LOAD_PIC_REG (dx)
|
|
#endif
|
|
fld %st // x : x : log(2)
|
|
sahf
|
|
jc 3f // in case x is NaN or +-Inf
|
|
4: fsubl MO(one) // x-1 : x : log(2)
|
|
fld %st // x-1 : x-1 : x : log(2)
|
|
fabs // |x-1| : x-1 : x : log(2)
|
|
fcompl MO(limit) // x-1 : x : log(2)
|
|
fnstsw // x-1 : x : log(2)
|
|
andb $0x45, %ah
|
|
jz 2f
|
|
fxam
|
|
fnstsw
|
|
andb $0x45, %ah
|
|
cmpb $0x40, %ah
|
|
jne 5f
|
|
fabs // log(1) is +0 in all rounding modes.
|
|
5: fstp %st(1) // x-1 : log(2)
|
|
fyl2xp1 // log(x)
|
|
ret
|
|
|
|
2: fstp %st(0) // x : log(2)
|
|
fyl2x // log(x)
|
|
ret
|
|
|
|
3: jp 4b // in case x is +-Inf
|
|
fstp %st(1)
|
|
fstp %st(1)
|
|
ret
|
|
END (__ieee754_logl)
|
|
|
|
ENTRY(__logl_finite)
|
|
fldln2 // log(2)
|
|
fldt 4(%esp) // x : log(2)
|
|
#ifdef PIC
|
|
LOAD_PIC_REG (dx)
|
|
#endif
|
|
fld %st // x : x : log(2)
|
|
fsubl MO(one) // x-1 : x : log(2)
|
|
fld %st // x-1 : x-1 : x : log(2)
|
|
fabs // |x-1| : x-1 : x : log(2)
|
|
fcompl MO(limit) // x-1 : x : log(2)
|
|
fnstsw // x-1 : x : log(2)
|
|
andb $0x45, %ah
|
|
jz 2b
|
|
fstp %st(1) // x-1 : log(2)
|
|
fyl2xp1 // log(x)
|
|
ret
|
|
END(__logl_finite)
|