mirror of
https://sourceware.org/git/glibc.git
synced 2024-10-03 12:37:44 +00:00
052b6a6c94
1998-08-09 Geoff Keating <geoffk@ozemail.com.au> * sysdeps/powerpc/Makefile [subdir=elf]: Add new files split out of dl-machine.h. * sysdeps/powerpc/dl-machine.c: New file. * sysdeps/powerpc/dl-machine.h: Move much stuff into separate files. Revise ELF_PREFERRED_ADDRESS to take account of the new mapping information (fixes bug involving huge bloated web browser). Set ELF_MACHINE_PLTREL_OVERLAP. * sysdeps/powerpc/dl-start.S: New file. * elf/dl-load.c (_dl_map_object_from_fd): Initialise l_map_start, l_map_end. * elf/do-rel.h: Call elf_machine_rel only once (to save space). * elf/dynamic-link.h: Allow PLT relocs to be in the middle of the others. Call elf_dynamic_do_##reloc only once (to save even more space). * elf/link.h: Add new members l_map_start and l_map_end to keep track of the memory map. * elf/rtld.c (_dl_start): Initialise l_map_start for ld.so and the executable. 1998-09-01 11:53 Ulrich Drepper <drepper@cygnus.com> * debug/Makefile (catchsegv): We need not rewrite SOVER anymore. Reported by Andreas Jaeger. * posix/glob.h: Use __size_t instead of size_t in definitions and make sure this is defined. * manual/locale.texi: Almost complete rewrite. Document more functions
112 lines
3.7 KiB
ArmAsm
112 lines
3.7 KiB
ArmAsm
/* Machine-dependent ELF startup code. PowerPC version.
|
|
Copyright (C) 1995, 1996, 1997, 1998 Free Software Foundation, Inc.
|
|
This file is part of the GNU C Library.
|
|
|
|
The GNU C Library is free software; you can redistribute it and/or
|
|
modify it under the terms of the GNU Library General Public License as
|
|
published by the Free Software Foundation; either version 2 of the
|
|
License, or (at your option) any later version.
|
|
|
|
The GNU C Library is distributed in the hope that it will be useful,
|
|
but WITHOUT ANY WARRANTY; without even the implied warranty of
|
|
MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
|
|
Library General Public License for more details.
|
|
|
|
You should have received a copy of the GNU Library General Public
|
|
License along with the GNU C Library; see the file COPYING.LIB. If not,
|
|
write to the Free Software Foundation, Inc., 59 Temple Place - Suite 330,
|
|
Boston, MA 02111-1307, USA. */
|
|
|
|
#include <sysdep.h>
|
|
|
|
/* Initial entry point code for the dynamic linker.
|
|
The C function `_dl_start' is the real entry point;
|
|
its return value is the user program's entry point. */
|
|
ENTRY(_start)
|
|
/* We start with the following on the stack, from top:
|
|
argc (4 bytes);
|
|
arguments for program (terminated by NULL);
|
|
environment variables (terminated by NULL);
|
|
arguments for the program loader. */
|
|
|
|
/* Call _dl_start with one parameter pointing at argc */
|
|
mr %r3,%r1
|
|
/* (we have to frob the stack pointer a bit to allow room for
|
|
_dl_start to save the link register). */
|
|
li %r4,0
|
|
addi %r1,%r1,-16
|
|
stw %r4,0(%r1)
|
|
bl _dl_start@local
|
|
|
|
/* Now, we do our main work of calling initialisation procedures.
|
|
The ELF ABI doesn't say anything about parameters for these,
|
|
so we just pass argc, argv, and the environment.
|
|
Changing these is strongly discouraged (not least because argc is
|
|
passed by value!). */
|
|
|
|
/* Put our GOT pointer in r31, */
|
|
bl _GLOBAL_OFFSET_TABLE_-4@local
|
|
mflr %r31
|
|
/* the address of _start in r30, */
|
|
mr %r30,%r3
|
|
/* &_dl_argc in 29, &_dl_argv in 27, and _dl_default_scope in 28. */
|
|
lwz %r28,_dl_default_scope@got(%r31)
|
|
lwz %r29,_dl_argc@got(%r31)
|
|
lwz %r27,_dl_argv@got(%r31)
|
|
0:
|
|
/* Set initfunc = _dl_init_next(_dl_default_scope[2]) */
|
|
lwz %r3,8(%r28)
|
|
bl _dl_init_next@plt
|
|
/* If initfunc is NULL, we exit the loop; otherwise, */
|
|
cmpwi %r3,0
|
|
beq 1f
|
|
/* call initfunc(_dl_argc, _dl_argv, _dl_argv+_dl_argc+1) */
|
|
mtlr %r3
|
|
lwz %r3,0(%r29)
|
|
lwz %r4,0(%r27)
|
|
slwi %r5,%r3,2
|
|
add %r5,%r4,%r5
|
|
addi %r5,%r5,4
|
|
blrl
|
|
/* and loop. */
|
|
b 0b
|
|
1:
|
|
/* Now, to conform to the ELF ABI, we have to: */
|
|
/* Pass argc (actually _dl_argc) in r3; */
|
|
lwz %r3,0(%r29)
|
|
/* pass argv (actually _dl_argv) in r4; */
|
|
lwz %r4,0(%r27)
|
|
/* pass envp (actually _dl_argv+_dl_argc+1) in r5; */
|
|
slwi %r5,%r3,2
|
|
add %r6,%r4,%r5
|
|
addi %r5,%r6,4
|
|
/* pass the auxilary vector in r6. This is passed to us just after _envp. */
|
|
2: lwzu %r0,4(%r6)
|
|
cmpwi %r0,0
|
|
bne 2b
|
|
addi %r6,%r6,4
|
|
/* Pass a termination function pointer (in this case _dl_fini) in r7. */
|
|
lwz %r7,_dl_fini@got(%r31)
|
|
/* Now, call the start function in r30... */
|
|
mtctr %r30
|
|
lwz %r26,_dl_starting_up@got(%r31)
|
|
/* Pass the stack pointer in r1 (so far so good), pointing to a NULL value.
|
|
(This lets our startup code distinguish between a program linked statically,
|
|
which linux will call with argc on top of the stack which will hopefully
|
|
never be zero, and a dynamically linked program which will always have
|
|
a NULL on the top of the stack).
|
|
Take the opportunity to clear LR, so anyone who accidentally returns
|
|
from _start gets SEGV. Also clear the next few words of the stack. */
|
|
|
|
li %r31,0
|
|
stw %r31,0(%r1)
|
|
mtlr %r31
|
|
stw %r31,4(%r1)
|
|
stw %r31,8(%r1)
|
|
stw %r31,12(%r1)
|
|
/* Clear _dl_starting_up. */
|
|
stw %r31,0(%r26)
|
|
/* Go do it! */
|
|
bctr
|
|
END(_start)
|