mirror of
https://sourceware.org/git/glibc.git
synced 2024-11-16 18:10:11 +00:00
15daa63995
1999-10-24 Ulrich Drepper <drepper@cygnus.com> * math/libm-test.inc: Disable some boundary case tests for inline function testing. * math/math.h: Pretty printing. * sysdeps/i386/fpu/e_atanh.S: Correct handling of NaN. * sysdeps/i386/fpu/e_atanhf.S: Likewise. * sysdeps/i386/fpu/e_atanhl.S: Likewise. * sysdeps/i386/fpu/e_log10.S: Likewise. * sysdeps/i386/fpu/e_log10f.S: Likewise. * sysdeps/i386/fpu/e_log10l.S: Likewise. * sysdeps/i386/fpu/s_log1p.S: Likewise. * sysdeps/i386/fpu/s_log1pf.S: Likewise. * sysdeps/i386/fpu/s_log1pl.S: Likewise. * sysdeps/i386/fpu/s_log2.S: Likewise. * sysdeps/i386/fpu/s_log2f.S: Likewise. * sysdeps/i386/fpu/s_log2l.S: Likewise. * sysdeps/i386/fpu/libm-test-ulps: New file. * sysdeps/i386/fpu/bits/mathinline.h (__expm1_code): Correct return value for x == 0. (pow): Correct case x == 0. (__sgn1l): Correct handling of -0.0. 1999-10-22 Andreas Jaeger <aj@suse.de> * math/libm-test.inc (asinh_test): Add test for NaN as input parameter. (atan_test): Likewise. (atanh_test): Likewise. (atan2_test): Likewise. (carg_test): Likewise. (ceil_test): Likewise. (cos_test): Likewise. (cosh_test): Likewise. (cpow_test): Likewise. (erf_test): Likewise. (erfc_test): Likewise. (exp_test): Likewise. (exp10_test): Likewise. (exp2_test): Likewise. (expm1_test): Likewise. (fabs_test): Likewise. (floor_test): Likewise. (fmod_test): Likewise. (gamma_test): Likewise. (lgamma_test): Likewise. (log10_test): Likewise. (log1p_test): Likewise. (log2_test): Likewise. (logb_test): Likewise. (nearbyint_test): Likewise. (remainder_test): Likewise. (remquo_test): Likewise. (sin_test): Likewise. (sincos_test): Likewise. (sinh_test): Likewise. (sqrt_test): Likewise. (tan_test): Likewise. (tanh_test): Likewise. (tgamma_test): Likewise.
112 lines
3.0 KiB
ArmAsm
112 lines
3.0 KiB
ArmAsm
/* ix87 specific implementation of arctanh function.
|
|
Copyright (C) 1996, 1999 Free Software Foundation, Inc.
|
|
This file is part of the GNU C Library.
|
|
Contributed by Ulrich Drepper <drepper@cygnus.com>, 1996.
|
|
|
|
The GNU C Library is free software; you can redistribute it and/or
|
|
modify it under the terms of the GNU Library General Public License as
|
|
published by the Free Software Foundation; either version 2 of the
|
|
License, or (at your option) any later version.
|
|
|
|
The GNU C Library is distributed in the hope that it will be useful,
|
|
but WITHOUT ANY WARRANTY; without even the implied warranty of
|
|
MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
|
|
Library General Public License for more details.
|
|
|
|
You should have received a copy of the GNU Library General Public
|
|
License along with the GNU C Library; see the file COPYING.LIB. If not,
|
|
write to the Free Software Foundation, Inc., 59 Temple Place - Suite 330,
|
|
Boston, MA 02111-1307, USA. */
|
|
|
|
#include <machine/asm.h>
|
|
|
|
#ifdef __ELF__
|
|
.section .rodata
|
|
#else
|
|
.text
|
|
#endif
|
|
|
|
.align ALIGNARG(4)
|
|
ASM_TYPE_DIRECTIVE(half,@object)
|
|
half: .double 0.5
|
|
ASM_SIZE_DIRECTIVE(half)
|
|
ASM_TYPE_DIRECTIVE(one,@object)
|
|
one: .double 1.0
|
|
ASM_SIZE_DIRECTIVE(one)
|
|
ASM_TYPE_DIRECTIVE(limit,@object)
|
|
limit: .double 0.29
|
|
ASM_SIZE_DIRECTIVE(limit)
|
|
.align ALIGNARG(4)
|
|
ASM_TYPE_DIRECTIVE(ln2_2,@object)
|
|
ln2_2: .tfloat 0.3465735902799726547086160
|
|
ASM_SIZE_DIRECTIVE(ln2_2)
|
|
|
|
#ifdef PIC
|
|
#define MO(op) op##@GOTOFF(%edx)
|
|
#else
|
|
#define MO(op) op
|
|
#endif
|
|
|
|
.text
|
|
ENTRY(__ieee754_atanhf)
|
|
movl 4(%esp), %ecx
|
|
|
|
movl %ecx, %eax
|
|
andl $0x7fffffff, %eax
|
|
cmpl $0x7f800000, %eax
|
|
ja 5f
|
|
|
|
#ifdef PIC
|
|
call 1f
|
|
1: popl %edx
|
|
addl $_GLOBAL_OFFSET_TABLE_+[.-1b], %edx
|
|
#endif
|
|
|
|
andl $0x80000000, %ecx // ECX == 0 iff X >= 0
|
|
|
|
fldt MO(ln2_2) // 0.5*ln2
|
|
xorl %ecx, 4(%esp)
|
|
flds 4(%esp) // |x| : 0.5*ln2
|
|
fcoml MO(half) // |x| : 0.5*ln2
|
|
fld %st(0) // |x| : |x| : 0.5*ln2
|
|
fnstsw // |x| : |x| : 0.5*ln2
|
|
sahf
|
|
jae 2f
|
|
fadd %st, %st(1) // |x| : 2*|x| : 0.5*ln2
|
|
fld %st // |x| : |x| : 2*|x| : 0.5*ln2
|
|
fsubrl MO(one) // 1-|x| : |x| : 2*|x| : 0.5*ln2
|
|
fxch // |x| : 1-|x| : 2*|x| : 0.5*ln2
|
|
fmul %st(2) // 2*|x|^2 : 1-|x| : 2*|x| : 0.5*ln2
|
|
fdivp // (2*|x|^2)/(1-|x|) : 2*|x| : 0.5*ln2
|
|
faddp // 2*|x|+(2*|x|^2)/(1-|x|) : 0.5*ln2
|
|
fcoml MO(limit) // 2*|x|+(2*|x|^2)/(1-|x|) : 0.5*ln2
|
|
fnstsw // 2*|x|+(2*|x|^2)/(1-|x|) : 0.5*ln2
|
|
sahf
|
|
jae 4f
|
|
fyl2xp1 // 0.5*ln2*ld(1+2*|x|+(2*|x|^2)/(1-|x|))
|
|
jecxz 3f
|
|
fchs // 0.5*ln2*ld(1+2*x+(2*x^2)/(1-x))
|
|
3: ret
|
|
|
|
.align ALIGNARG(4)
|
|
4: faddl MO(one) // 1+2*|x|+(2*|x|^2)/(1-|x|) : 0.5*ln2
|
|
fyl2x // 0.5*ln2*ld(1+2*|x|+(2*|x|^2)/(1-|x|))
|
|
jecxz 3f
|
|
fchs // 0.5*ln2*ld(1+2*x+(2*x^2)/(1-x))
|
|
3: ret
|
|
|
|
.align ALIGNARG(4)
|
|
2: faddl MO(one) // 1+|x| : |x| : 0.5*ln2
|
|
fxch // |x| : 1+|x| : 0.5*ln2
|
|
fsubrl MO(one) // 1-|x| : 1+|x| : 0.5*ln2
|
|
fdivrp // (1+|x|)/(1-|x|) : 0.5*ln2
|
|
fyl2x // 0.5*ln2*ld((1+|x|)/(1-|x|))
|
|
jecxz 3f
|
|
fchs // 0.5*ln2*ld((1+x)/(1-x))
|
|
3: ret
|
|
|
|
// x == NaN
|
|
5: flds 4(%esp)
|
|
ret
|
|
END(__ieee754_atanhf)
|