mirror of
https://sourceware.org/git/glibc.git
synced 2024-11-24 05:50:14 +00:00
c2f55635da
* sysdeps/alpha/elf/configure.in: Likewise.
* sysdeps/i386/elf/configure.in: Likewise.
* sysdeps/mach/hurd/configure.in: Likewise.
* sysdeps/x86_64/elf/configure.in: Likewise.
65 lines
1.9 KiB
Plaintext
65 lines
1.9 KiB
Plaintext
GLIBC_PROVIDES dnl See aclocal.m4 in the top level source directory.
|
|
|
|
# GNU libc on the Hurd is always reentrant.
|
|
DEFINES="$DEFINES -D_LIBC_REENTRANT"
|
|
|
|
dnl We need this setting because of the need for PLT calls in ld.so.
|
|
AC_DEFINE([NO_HIDDEN])
|
|
|
|
# Don't bother trying to generate any glue code to be compatible with the
|
|
# existing system library, because we are the only system library.
|
|
inhibit_glue=yes
|
|
|
|
if test "x$prefix" != x; then
|
|
AC_MSG_WARN([--prefix= (empty) is required for GNU/Hurd to work normally])
|
|
fi
|
|
|
|
case "$machine" in
|
|
i386*)
|
|
# The default oldest ABI is 2.2.6.
|
|
# We only need a "yes" here if the oldest ABI supported will be < 2.2.6.
|
|
if test "$oldest_abi" != default && test "$oldest_abi" \< "2.2.6"; then
|
|
libc_cv_gcc_unwind_find_fde=yes
|
|
fi
|
|
;;
|
|
esac
|
|
|
|
AC_CACHE_CHECK(Hurd header version, libc_cv_hurd_version, [dnl
|
|
AC_TRY_COMPILE(dnl
|
|
[#include <hurd/version.h>], [
|
|
#define NEED_VERSION 20020609
|
|
#if HURD_INTERFACE_VERSION < NEED_VERSION
|
|
# error Hurd version too old: HURD_INTERFACE_VERSION < NEED_VERSION
|
|
#endif],
|
|
libc_cv_hurd_version=ok,
|
|
libc_cv_hurd_version=bad)])
|
|
if test "x$libc_cv_hurd_version" != xok; then
|
|
AC_MSG_ERROR(Hurd headers not installed or too old)
|
|
fi
|
|
|
|
dnl Swiped from hurd/aclocal.m4
|
|
AC_DEFUN([hurd_MIG_RETCODE], [dnl
|
|
# See if mig groks `retcode'.
|
|
AC_CACHE_CHECK(whether $MIG supports the retcode keyword, hurd_cv_mig_retcode,
|
|
[cat > conftest.defs <<\EOF
|
|
#include <mach/std_types.defs>
|
|
#include <mach/mach_types.defs>
|
|
subsystem foobar 1000;
|
|
type reply_port_t = polymorphic | MACH_MSG_TYPE_PORT_SEND_ONCE
|
|
ctype: mach_port_t;
|
|
simpleroutine foobar_reply (
|
|
reply_port: reply_port_t;
|
|
err: kern_return_t, RetCode);
|
|
EOF
|
|
if AC_TRY_COMMAND([CC="${CC}" ${MIG-false} -n conftest.defs 1>&AS_MESSAGE_LOG_FD]); then
|
|
hurd_cv_mig_retcode=yes
|
|
else
|
|
hurd_cv_mig_retcode=no
|
|
fi
|
|
rm -f conftest*])
|
|
if test $hurd_cv_mig_retcode = yes; then
|
|
AC_DEFINE(HAVE_MIG_RETCODE)
|
|
fi])
|
|
|
|
hurd_MIG_RETCODE
|