mirror of
https://sourceware.org/git/glibc.git
synced 2024-11-27 07:20:11 +00:00
de8aadd52c
According to bug 6792, errno is not set to ERANGE/EDOM by calling log1p/log1pf/log1pl with x = -1 or x < -1. This patch adds a wrapper which sets errno in those cases and returns the value of the existing __log1p function. The log1p is now an alias to the wrapper function instead of __log1p. The files in sysdeps are reflecting these changes. The ia64 implementation sets errno by itself, thus the wrapper-file is empty. The libm-test is adjusted for log1p-tests to check errno. [BZ #6792] * math/w_log1p.c: New file. * math/w_log1pf.c: Likewise. * math/w_log1pl.c: Likewise. * math/Makefile (libm-calls): Add w_log1p. * math/s_log1pl.c (log1pl): Remove weak_alias. * sysdeps/i386/fpu/s_log1p.S (log1p): Likewise. * sysdeps/i386/fpu/s_log1pf.S (log1pf): Likewise. * sysdeps/i386/fpu/s_log1pl.S (log1pl): Likewise. * sysdeps/x86_64/fpu/s_log1pl.S (log1pl): Likewise. * sysdeps/ieee754/dbl-64/s_log1p.c (log1p): Likewise. [NO_LONG_DOUBLE] (log1pl): Likewise. * sysdeps/ieee754/flt-32/s_log1pf.c (log1pf): Likewise. * sysdeps/ieee754/ldbl-128/s_log1pl.c (log1pl): Likewise. * sysdeps/ieee754/ldbl-64-128/s_log1pl.c (log1p): Remove long_double_symbol. * sysdeps/ieee754/ldbl-128ibm/s_log1pl.c (log1pl): Likewise. * sysdeps/ieee754/ldbl-64-128/w_log1pl.c: New file. * sysdeps/ieee754/ldbl-128ibm/w_log1pl.c: Likewise. * sysdeps/m68k/m680x0/fpu/s_log1p.c: Define empty weak_alias to remove weak_alias for corresponding log1p function. * sysdeps/m68k/m680x0/fpu/s_log1pf.c: Likewise. * sysdeps/m68k/m680x0/fpu/s_log1pl.c: Likewise. * sysdeps/ia64/fpu/w_log1p.c: New file. * sysdeps/ia64/fpu/w_log1pf.c: Likewise. * sysdeps/ia64/fpu/w_log1pl.c: Likewise. * math/libm-test.inc (log1p_test_data): Add errno expectations.
78 lines
1.2 KiB
ArmAsm
78 lines
1.2 KiB
ArmAsm
/*
|
|
* Written by J.T. Conklin <jtc@netbsd.org>.
|
|
* Public domain.
|
|
*
|
|
* Adapted for `long double' by Ulrich Drepper <drepper@cygnus.com>.
|
|
*/
|
|
|
|
#include <machine/asm.h>
|
|
|
|
RCSID("$NetBSD: s_log1p.S,v 1.7 1995/05/09 00:10:58 jtc Exp $")
|
|
|
|
.section .rodata
|
|
|
|
.align ALIGNARG(4)
|
|
/* The fyl2xp1 can only be used for values in
|
|
-1 + sqrt(2) / 2 <= x <= 1 - sqrt(2) / 2
|
|
0.29 is a safe value.
|
|
*/
|
|
limit: .tfloat 0.29
|
|
/* Please note: we use a double value here. Since 1.0 has
|
|
an exact representation this does not effect the accuracy
|
|
but it helps to optimize the code. */
|
|
one: .double 1.0
|
|
|
|
/*
|
|
* Use the fyl2xp1 function when the argument is in the range -0.29 to 0.29,
|
|
* otherwise fyl2x with the needed extra computation.
|
|
*/
|
|
.text
|
|
ENTRY(__log1pl)
|
|
fldln2
|
|
|
|
fldt 4(%esp)
|
|
|
|
#ifdef PIC
|
|
LOAD_PIC_REG (dx)
|
|
#endif
|
|
|
|
fxam
|
|
fnstsw
|
|
fld %st
|
|
sahf
|
|
jc 3f // in case x is NaN or ±Inf
|
|
4:
|
|
fabs
|
|
#ifdef PIC
|
|
fldt limit@GOTOFF(%edx)
|
|
#else
|
|
fldt limit
|
|
#endif
|
|
fcompp
|
|
fnstsw
|
|
sahf
|
|
jnc 2f
|
|
|
|
movzwl 4+8(%esp), %eax
|
|
xorb $0x80, %ah
|
|
cmpl $0xc040, %eax
|
|
jae 5f
|
|
|
|
#ifdef PIC
|
|
faddl one@GOTOFF(%edx)
|
|
#else
|
|
faddl one
|
|
#endif
|
|
5: fyl2x
|
|
ret
|
|
|
|
2: fyl2xp1
|
|
ret
|
|
|
|
3: jp 4b // in case x is ±Inf
|
|
fstp %st(1)
|
|
fstp %st(1)
|
|
ret
|
|
|
|
END (__log1pl)
|