mirror of
https://sourceware.org/git/glibc.git
synced 2024-11-17 02:20:10 +00:00
5ac4c397b7
* sysdeps/mips/elf/start.S: Use __PIC__ instead of PIC. * sysdeps/mips/mips64/add_n.S: Likewise. * sysdeps/mips/mips64/bsd-_setjmp.S: Likewise. * sysdeps/mips/mips64/lshift.S: Likewise. * sysdeps/mips/mips64/mul_1.S: Likewise. * sysdeps/mips/mips64/rshift.S: Likewise. * sysdeps/mips/mips64/setjmp.S: Likewise. * sysdeps/mips/mips64/sub_n.S: Likewise. * sysdeps/mips/mips64/submul_1.S: Likewise. * sysdeps/mips/dl-machine.h (elf_machine_got_rel): Remove strtab and update comment. The strtab from _dl_relocate_object can be used.
102 lines
2.0 KiB
ArmAsm
102 lines
2.0 KiB
ArmAsm
/* MIPS3 __mpn_rshift --
|
|
*
|
|
* Copyright (C) 1995, 2000 Free Software Foundation, Inc.
|
|
*
|
|
* This file is part of the GNU MP Library.
|
|
*
|
|
* The GNU MP Library is free software; you can redistribute it and/or modify
|
|
* it under the terms of the GNU Library General Public License as published by
|
|
* the Free Software Foundation; either version 2 of the License, or (at your
|
|
* option) any later version.
|
|
*
|
|
* The GNU MP Library is distributed in the hope that it will be useful, but
|
|
* WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
|
|
* or FITNESS FOR A PARTICULAR PURPOSE. See the GNU Library General Public
|
|
* License for more details.
|
|
*
|
|
* You should have received a copy of the GNU Library General Public License
|
|
* along with the GNU MP Library; see the file COPYING.LIB. If not, write to
|
|
* the Free Software Foundation, Inc., 59 Temple Place - Suite 330, Boston,
|
|
* MA 02111-1307, USA.
|
|
*/
|
|
|
|
#include <sysdep.h>
|
|
|
|
/* INPUT PARAMETERS
|
|
* res_ptr $4
|
|
* src_ptr $5
|
|
* size $6
|
|
* cnt $7
|
|
*/
|
|
|
|
#ifdef __PIC__
|
|
.option pic2
|
|
#endif
|
|
.text
|
|
.align 2
|
|
.globl __mpn_rshift
|
|
.ent __mpn_rshift
|
|
__mpn_rshift:
|
|
.set noreorder
|
|
#ifdef __PIC__
|
|
.cpload t9
|
|
#endif
|
|
.set nomacro
|
|
|
|
ld $10,0($5) # load first limb
|
|
dsubu $13,$0,$7
|
|
daddiu $6,$6,-1
|
|
and $9,$6,4-1 # number of limbs in first loop
|
|
beq $9,$0,.L0 # if multiple of 4 limbs, skip first loop
|
|
dsll $2,$10,$13 # compute function result
|
|
|
|
dsubu $6,$6,$9
|
|
|
|
.Loop0: ld $3,8($5)
|
|
daddiu $4,$4,8
|
|
daddiu $5,$5,8
|
|
daddiu $9,$9,-1
|
|
dsrl $11,$10,$7
|
|
dsll $12,$3,$13
|
|
move $10,$3
|
|
or $8,$11,$12
|
|
bne $9,$0,.Loop0
|
|
sd $8,-8($4)
|
|
|
|
.L0: beq $6,$0,.Lend
|
|
nop
|
|
|
|
.Loop: ld $3,8($5)
|
|
daddiu $4,$4,32
|
|
daddiu $6,$6,-4
|
|
dsrl $11,$10,$7
|
|
dsll $12,$3,$13
|
|
|
|
ld $10,16($5)
|
|
dsrl $14,$3,$7
|
|
or $8,$11,$12
|
|
sd $8,-32($4)
|
|
dsll $9,$10,$13
|
|
|
|
ld $3,24($5)
|
|
dsrl $11,$10,$7
|
|
or $8,$14,$9
|
|
sd $8,-24($4)
|
|
dsll $12,$3,$13
|
|
|
|
ld $10,32($5)
|
|
dsrl $14,$3,$7
|
|
or $8,$11,$12
|
|
sd $8,-16($4)
|
|
dsll $9,$10,$13
|
|
|
|
daddiu $5,$5,32
|
|
or $8,$14,$9
|
|
bgtz $6,.Loop
|
|
sd $8,-8($4)
|
|
|
|
.Lend: dsrl $8,$10,$7
|
|
j $31
|
|
sd $8,0($4)
|
|
.end __mpn_rshift
|