mirror of
https://sourceware.org/git/glibc.git
synced 2024-11-14 17:11:06 +00:00
61 lines
1.2 KiB
ArmAsm
61 lines
1.2 KiB
ArmAsm
/*
|
|
* Written by J.T. Conklin <jtc@netbsd.org>.
|
|
* Public domain.
|
|
* Adapted for float by Ulrich Drepper <drepper@cygnus.com>.
|
|
*
|
|
* Changed to use fyl2xp1 for values near 1, <drepper@cygnus.com>.
|
|
*/
|
|
|
|
#include <machine/asm.h>
|
|
|
|
RCSID("$NetBSD: e_log.S,v 1.4 1995/05/08 23:48:39 jtc Exp $")
|
|
|
|
#ifdef __ELF__
|
|
.section .rodata
|
|
#else
|
|
.text
|
|
#endif
|
|
.align ALIGNARG(4)
|
|
ASM_TYPE_DIRECTIVE(one,@object)
|
|
one: .double 1.0
|
|
ASM_SIZE_DIRECTIVE(one)
|
|
/* It is not important that this constant is precise. It is only
|
|
a value which is known to be on the safe side for using the
|
|
fyl2xp1 instruction. */
|
|
ASM_TYPE_DIRECTIVE(limit,@object)
|
|
limit: .double 0.29
|
|
ASM_SIZE_DIRECTIVE(limit)
|
|
|
|
|
|
#ifdef PIC
|
|
#define MO(op) op##@GOTOFF(%edx)
|
|
#else
|
|
#define MO(op) op
|
|
#endif
|
|
|
|
.text
|
|
ENTRY(__ieee754_logf)
|
|
fldln2 // log(2)
|
|
flds 4(%esp) // x : log(2)
|
|
#ifdef PIC
|
|
call 1f
|
|
1: popl %edx
|
|
addl $_GLOBAL_OFFSET_TABLE_+[.-1b], %edx
|
|
#endif
|
|
fld %st // x : x : log(2)
|
|
fsubl MO(one) // x-1 : x : log(2)
|
|
fld %st // x-1 : x-1 : x : log(2)
|
|
fabs // |x-1| : x-1 : x : log(2)
|
|
fcompl MO(limit) // x-1 : x : log(2)
|
|
fnstsw // x-1 : x : log(2)
|
|
andb $0x45, %ah
|
|
jz 2f
|
|
fstp %st(1) // x-1 : log(2)
|
|
fyl2xp1 // log(x)
|
|
ret
|
|
|
|
2: fstp %st(0) // x : log(2)
|
|
fyl2x // log(x)
|
|
ret
|
|
END (__ieee754_logf)
|