mirror of
https://sourceware.org/git/glibc.git
synced 2024-12-12 06:10:10 +00:00
0cb313f7cb
As discussed in libc-alpha [1] current clone with CLONE_VM (without
CLONE_THREAD set) will reset the pthread pid/tid fields to -1. The
issue is since memory is shared between the parent and child it will
clobber parent's cached pid/tid leading to internal inconsistencies
if the value is not restored.
And even it is restored it may lead to racy conditions when between
set/restore a thread might invoke pthread function that validate the
pthread with INVALID_TD_P/INVALID_NOT_TERMINATED_TD_P and thus get
wrong results.
As stated in BZ19957, previously reports of this behaviour was close
with EWONTFIX due the fact usage of clone outside glibc is tricky
since glibc requires consistent internal pthread, while using clone
directly may not provide it. However since now posix_spawn uses
clone (CLONE_VM) to fixes various issues related to previous vfork
usage this issue requires fixing.
The vfork implementation also does something similar, but instead
it negates and restores only the *pid* field and functions that
might access its value know to handle such case (getpid, raise
and pthread ones that uses INVALID_TD_P/INVALID_NOT_TERMINATED_TD_P
macros that check only *tid* field). Also vfork does not call
__clone directly, instead calling either __NR_vfork or __NR_clone
directly.
So this patch removes this clone behavior by avoiding setting
the pthread pid/tid field for CLONE_VM. There is no need to
check for CLONE_THREAD, since the minimum supported kernel in all
architecture implies that CLONE_VM must be used with CLONE_THREAD,
otherwise clone returns EINVAL.
Instead of current approach of:
int clone(int (*fn)(void *), void *child_stack, int flags, ...)
[...]
if (flags & CLONE_THREAD)
goto do_syscall;
pid_t new_value;
if (flags & CLONE_VM)
new_value = -1;
else
new_value = getpid ();
THREAD_SETMEM (THREAD_SELF, pid, new_value);
THREAD_SETMEM (THREAD_SELF, tid, new_value);
do_syscall:
[...]
The new approach uses:
int clone(int (*fn)(void *), void *child_stack, int flags, ...)
[...]
if (flags & CLONE_VM)
goto do_syscall;
pid_t new_value = getpid ();
THREAD_SETMEM (THREAD_SELF, pid, new_value);
THREAD_SETMEM (THREAD_SELF, tid, new_value);
do_syscall:
[...]
It also removes the linux tst-getpid2.c test which expects the previous
behavior and instead add another clone test.
Tested on x86_64, i686, x32, powerpc64le, aarch64, armhf, s390, and
s390x. I also did limited check on mips32 and sparc64 (using the new
added test).
I also got reviews from both m68k, hppa, and tile. So I presume for
these architecture the patch works.
The fixes for alpha, microblaze, sh, ia64, and nio2 have not been
tested.
[1] https://sourceware.org/ml/libc-alpha/2016-04/msg00307.html
* sysdeps/unix/sysv/linux/Makefile [$(subdir) == nptl] (test): Remove
tst-getpid2.
(test): Add tst-clone2.
* sysdeps/unix/sysv/linux/tst-clone2.c: New file.
* sysdeps/unix/sysv/linux/aarch64/clone.S (__clone): Do not change
pid/tid fields for CLONE_VM.
* sysdeps/unix/sysv/linux/arm/clone.S: Likewise.
* sysdeps/unix/sysv/linux/i386/clone.S: Likewise.
* sysdeps/unix/sysv/linux/mips/clone.S: Likewise.
* sysdeps/unix/sysv/linux/powerpc/powerpc32/clone.S: Likewise.
* sysdeps/unix/sysv/linux/powerpc/powerpc64/clone.S: Likewise.
* sysdeps/unix/sysv/linux/s390/s390-32/clone.S: Likewise.
* sysdeps/unix/sysv/linux/s390/s390-64/clone.S: Likewise.
* sysdeps/unix/sysv/linux/sparc/sparc32/clone.S: Likewise.
* sysdeps/unix/sysv/linux/sparc/sparc64/clone.S: Likewise.
* sysdeps/unix/sysv/linux/x86_64/clone.S: Likewise.
* sysdeps/unix/sysv/linux/tst-getpid2.c: Remove file.
129 lines
3.3 KiB
ArmAsm
129 lines
3.3 KiB
ArmAsm
/* Wrapper around clone system call. PowerPC64 version.
|
|
Copyright (C) 1997-2016 Free Software Foundation, Inc.
|
|
This file is part of the GNU C Library.
|
|
|
|
The GNU C Library is free software; you can redistribute it and/or
|
|
modify it under the terms of the GNU Lesser General Public
|
|
License as published by the Free Software Foundation; either
|
|
version 2.1 of the License, or (at your option) any later version.
|
|
|
|
The GNU C Library is distributed in the hope that it will be useful,
|
|
but WITHOUT ANY WARRANTY; without even the implied warranty of
|
|
MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
|
|
Lesser General Public License for more details.
|
|
|
|
You should have received a copy of the GNU Lesser General Public
|
|
License along with the GNU C Library; if not, see
|
|
<http://www.gnu.org/licenses/>. */
|
|
|
|
#include <sysdep.h>
|
|
#define _ERRNO_H 1
|
|
#include <bits/errno.h>
|
|
|
|
#define CLONE_VM 0x00000100
|
|
#define CLONE_THREAD 0x00010000
|
|
|
|
/* This is the only really unusual system call in PPC linux, but not
|
|
because of any weirdness in the system call itself; because of
|
|
all the freaky stuff we have to do to make the call useful. */
|
|
|
|
/* int [r3] clone(int (*fn)(void *arg) [r3], void *child_stack [r4],
|
|
int flags [r5], void *arg [r6], void *parent_tid [r7],
|
|
void *tls [r8], void *child_tid [r9]); */
|
|
|
|
ENTRY (__clone)
|
|
CALL_MCOUNT 7
|
|
|
|
/* Check for child_stack == NULL || fn == NULL. */
|
|
cmpdi cr0,r4,0
|
|
cmpdi cr1,r3,0
|
|
cror cr0*4+eq,cr1*4+eq,cr0*4+eq
|
|
beq- cr0,L(badargs)
|
|
|
|
/* Save some regs in the "red zone". */
|
|
std r29,-24(r1)
|
|
std r30,-16(r1)
|
|
std r31,-8(r1)
|
|
cfi_offset(r29,-24)
|
|
cfi_offset(r30,-16)
|
|
cfi_offset(r31,-8)
|
|
|
|
/* Set up stack frame for child. */
|
|
clrrdi r4,r4,4
|
|
li r0,0
|
|
stdu r0,-FRAME_MIN_SIZE_PARM(r4)
|
|
|
|
/* Save fn, args, stack across syscall. */
|
|
mr r30,r3 /* Function in r30. */
|
|
mr r29,r5 /* Flags in r29. */
|
|
mr r31,r6 /* Argument in r31. */
|
|
|
|
/* 'flags' argument is first parameter to clone syscall.
|
|
Second is the stack pointer, already in r4. */
|
|
mr r3,r5
|
|
/* Move the parent_tid, child_tid and tls arguments. */
|
|
mr r5,r7
|
|
mr r6,r8
|
|
mr r7,r9
|
|
|
|
/* End FDE now, because in the child the unwind info will be
|
|
wrong. */
|
|
cfi_endproc
|
|
|
|
/* Do the call. */
|
|
DO_CALL(SYS_ify(clone))
|
|
|
|
/* Check for child process. */
|
|
cmpdi cr1,r3,0
|
|
crandc cr1*4+eq,cr1*4+eq,cr0*4+so
|
|
bne- cr1,L(parent) /* The '-' is to minimise the race. */
|
|
|
|
/* If CLONE_VM is set do not update the pid/tid field. */
|
|
rldicl. r0,r29,56,63 /* flags & CLONE_VM. */
|
|
bne+ cr0,L(oldpid)
|
|
|
|
DO_CALL(SYS_ify(getpid))
|
|
stw r3,TID(r13)
|
|
stw r3,PID(r13)
|
|
L(oldpid):
|
|
|
|
std r2,FRAME_TOC_SAVE(r1)
|
|
/* Call procedure. */
|
|
PPC64_LOAD_FUNCPTR r30
|
|
mr r3,r31
|
|
bctrl
|
|
ld r2,FRAME_TOC_SAVE(r1)
|
|
/* Call _exit with result from procedure. */
|
|
#ifdef SHARED
|
|
b JUMPTARGET(__GI__exit)
|
|
#else
|
|
b JUMPTARGET(_exit)
|
|
/* We won't ever get here but provide a nop so that the linker
|
|
will insert a toc adjusting stub if necessary. */
|
|
nop
|
|
#endif
|
|
|
|
L(badargs):
|
|
cfi_startproc
|
|
li r3,EINVAL
|
|
TAIL_CALL_SYSCALL_ERROR
|
|
|
|
L(parent):
|
|
/* Parent. Restore registers & return. */
|
|
cfi_offset(r29,-24)
|
|
cfi_offset(r30,-16)
|
|
cfi_offset(r31,-8)
|
|
ld r29,-24(r1)
|
|
ld r30,-16(r1)
|
|
ld r31,-8(r1)
|
|
cfi_restore(r29)
|
|
cfi_restore(r30)
|
|
cfi_restore(r31)
|
|
|
|
PSEUDO_RET
|
|
|
|
END (__clone)
|
|
|
|
libc_hidden_def (__clone)
|
|
weak_alias (__clone, clone)
|