mirror of
https://sourceware.org/git/glibc.git
synced 2025-01-04 08:40:15 +00:00
9ff72da471
This patch implements a new posix_spawn{p} implementation for Linux. The main
difference is it uses the clone syscall directly with CLONE_VM and CLONE_VFORK
flags and a direct allocated stack. The new stack and start function solves
most the vfork limitation (possible parent clobber due stack spilling). The
remaning issue are related to signal handling:
1. That no signal handlers must run in child context, to avoid corrupt
parent's state.
2. Child must synchronize with parent to enforce stack deallocation and
to possible return execv issues.
The first one is solved by blocking all signals in child, even NPTL-internal
ones (SIGCANCEL and SIGSETXID). The second issue is done by a stack allocation
in parent and a synchronization with using a pipe or waitpid (in case or error).
The pipe has the advantage of allowing the child signal an exec error (checked
with new tst-spawn2 test).
There is an inherent race condition in pipe2 usage for architectures that do not
support the syscall directly. In such cases the a pipe plus fctnl is used
instead and it may lead to file descriptor leak in parent (as decribed by fcntl
documentation).
The child process stack is allocate with a mmap with MAP_STACK flag using
default architecture stack size. Although it is slower than use a stack buffer
from parent, it allows some slack for the compatibility code to run scripts
with no shebang (which may use a buffer with size depending of argument list
count).
Performance should be similar to the vfork default posix implementation and
way faster than fork path (vfork on mostly linux ports are basically
clone with CLONE_VM plus CLONE_VFORK). The only difference is the syscalls
required for the stack allocation/deallocation.
It fixes BZ#10354, BZ#14750, and BZ#18433.
Tested on i386, x86_64, powerpc64le, and aarch64.
[BZ #14750]
[BZ #10354]
[BZ #18433]
* include/sched.h (__clone): Add hidden prototype.
(__clone2): Likewise.
* include/unistd.h (__dup): Likewise.
* posix/Makefile (tests): Add tst-spawn2.
* posix/tst-spawn2.c: New file.
* sysdeps/posix/dup.c (__dup): Add hidden definition.
* sysdeps/unix/sysv/linux/aarch64/clone.S (__clone): Likewise.
* sysdeps/unix/sysv/linux/alpha/clone.S (__clone): Likewise.
* sysdeps/unix/sysv/linux/arm/clone.S (__clone): Likewise.
* sysdeps/unix/sysv/linux/hppa/clone.S (__clone): Likewise.
* sysdeps/unix/sysv/linux/i386/clone.S (__clone): Likewise.
* sysdeps/unix/sysv/linux/ia64/clone2.S (__clone): Likewise.
* sysdeps/unix/sysv/linux/m68k/clone.S (__clone): Likewise.
* sysdeps/unix/sysv/linux/microblaze/clone.S (__clone): Likewise.
* sysdeps/unix/sysv/linux/mips/clone.S (__clone): Likewise.
* sysdeps/unix/sysv/linux/nios2/clone.S (__clone): Likewise.
* sysdeps/unix/sysv/linux/powerpc/powerpc32/clone.S (__clone):
Likewise.
* sysdeps/unix/sysv/linux/powerpc/powerpc64/clone.S (__clone):
Likewise.
* sysdeps/unix/sysv/linux/s390/s390-32/clone.S (__clone): Likewise.
* sysdeps/unix/sysv/linux/s390/s390-64/clone.S (__clone): Likewise.
* sysdeps/unix/sysv/linux/sh/clone.S (__clone): Likewise.
* sysdeps/unix/sysv/linux/sparc/sparc32/clone.S (__clone): Likewise.
* sysdeps/unix/sysv/linux/sparc/sparc64/clone.S (__clone): Likewise.
* sysdeps/unix/sysv/linux/tile/clone.S (__clone): Likewise.
* sysdeps/unix/sysv/linux/x86_64/clone.S (__clone): Likewise.
* sysdeps/unix/sysv/linux/nptl-signals.h
(____nptl_is_internal_signal): New function.
* sysdeps/unix/sysv/linux/spawni.c: New file.
128 lines
2.7 KiB
ArmAsm
128 lines
2.7 KiB
ArmAsm
/* Copyright (C) 1999-2016 Free Software Foundation, Inc.
|
|
This file is part of the GNU C Library.
|
|
|
|
The GNU C Library is free software; you can redistribute it and/or
|
|
modify it under the terms of the GNU Lesser General Public
|
|
License as published by the Free Software Foundation; either
|
|
version 2.1 of the License, or (at your option) any later version.
|
|
|
|
The GNU C Library is distributed in the hope that it will be useful,
|
|
but WITHOUT ANY WARRANTY; without even the implied warranty of
|
|
MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
|
|
Lesser General Public License for more details.
|
|
|
|
You should have received a copy of the GNU Lesser General Public
|
|
License along with the GNU C Library; if not, see
|
|
<http://www.gnu.org/licenses/>. */
|
|
|
|
/* clone() is even more special than fork() as it mucks with stacks
|
|
and invokes a function in the right context after its all over. */
|
|
|
|
#include <sysdep.h>
|
|
#define _ERRNO_H 1
|
|
#include <bits/errno.h>
|
|
#include <tcb-offsets.h>
|
|
|
|
/* int clone(int (*fn)(void *arg), void *child_stack, int flags, void *arg,
|
|
pid_t *ptid, void *tls, pid_t *ctid); */
|
|
|
|
.text
|
|
ENTRY(__clone)
|
|
/* sanity check arguments. */
|
|
tst r4, r4
|
|
bt/s 0f
|
|
tst r5, r5
|
|
bf 1f
|
|
0:
|
|
bra .Lsyscall_error
|
|
mov #-EINVAL,r0
|
|
1:
|
|
/* insert the args onto the new stack */
|
|
mov.l r7, @-r5
|
|
/* save the function pointer as the 0th element */
|
|
mov.l r4, @-r5
|
|
|
|
/* do the system call */
|
|
mov r6, r4
|
|
mov.l @r15, r6
|
|
mov.l @(8,r15), r7
|
|
mov.l @(4,r15), r0
|
|
mov #+SYS_ify(clone), r3
|
|
trapa #0x15
|
|
mov r0, r1
|
|
mov #-12, r2
|
|
shad r2, r1
|
|
not r1, r1 // r1=0 means r0 = -1 to -4095
|
|
tst r1, r1 // i.e. error in linux
|
|
bf .Lclone_end
|
|
.Lsyscall_error:
|
|
SYSCALL_ERROR_HANDLER
|
|
.Lclone_end:
|
|
tst r0, r0
|
|
bt 2f
|
|
.Lpseudo_end:
|
|
rts
|
|
nop
|
|
2:
|
|
/* terminate the stack frame */
|
|
mov #0, r14
|
|
mov r4, r0
|
|
shlr16 r0
|
|
tst #1, r0 // CLONE_THREAD = (1 << 16)
|
|
bf/s 4f
|
|
mov r4, r0
|
|
/* new pid */
|
|
shlr8 r0
|
|
tst #1, r0 // CLONE_VM = (1 << 8)
|
|
bf/s 3f
|
|
mov #-1, r0
|
|
mov #+SYS_ify(getpid), r3
|
|
trapa #0x15
|
|
3:
|
|
stc gbr, r1
|
|
mov.w .Lpidoff, r2
|
|
add r1, r2
|
|
mov.l r0, @r2
|
|
mov.w .Ltidoff, r2
|
|
add r1, r2
|
|
mov.l r0, @r2
|
|
4:
|
|
/* thread starts */
|
|
mov.l @r15, r1
|
|
jsr @r1
|
|
mov.l @(4,r15), r4
|
|
|
|
/* we are done, passing the return value through r0 */
|
|
mov.l .L3, r1
|
|
#ifdef SHARED
|
|
mov.l r12, @-r15
|
|
sts.l pr, @-r15
|
|
mov r0, r4
|
|
mova .LG, r0
|
|
mov.l .LG, r12
|
|
add r0, r12
|
|
mova .L3, r0
|
|
add r0, r1
|
|
jsr @r1
|
|
nop
|
|
lds.l @r15+, pr
|
|
rts
|
|
mov.l @r15+, r12
|
|
#else
|
|
jmp @r1
|
|
mov r0, r4
|
|
#endif
|
|
.align 2
|
|
.LG:
|
|
.long _GLOBAL_OFFSET_TABLE_
|
|
.L3:
|
|
.long PLTJMP(C_SYMBOL_NAME(_exit))
|
|
.Lpidoff:
|
|
.word PID - TLS_PRE_TCB_SIZE
|
|
.Ltidoff:
|
|
.word TID - TLS_PRE_TCB_SIZE
|
|
PSEUDO_END (__clone)
|
|
|
|
libc_hidden_def (__clone)
|
|
weak_alias (__clone, clone)
|