mirror of
https://sourceware.org/git/glibc.git
synced 2024-12-28 05:21:13 +00:00
2b778ceb40
I used these shell commands: ../glibc/scripts/update-copyrights $PWD/../gnulib/build-aux/update-copyright (cd ../glibc && git commit -am"[this commit message]") and then ignored the output, which consisted lines saying "FOO: warning: copyright statement not found" for each of 6694 files FOO. I then removed trailing white space from benchtests/bench-pthread-locks.c and iconvdata/tst-iconv-big5-hkscs-to-2ucs4.c, to work around this diagnostic from Savannah: remote: *** pre-commit check failed ... remote: *** error: lines with trailing whitespace found remote: error: hook declined to update refs/heads/master
107 lines
2.8 KiB
ArmAsm
107 lines
2.8 KiB
ArmAsm
/* Copyright (C) 2001-2021 Free Software Foundation, Inc.
|
|
This file is part of the GNU C Library.
|
|
|
|
The GNU C Library is free software; you can redistribute it and/or
|
|
modify it under the terms of the GNU Lesser General Public
|
|
License as published by the Free Software Foundation; either
|
|
version 2.1 of the License, or (at your option) any later version.
|
|
|
|
The GNU C Library is distributed in the hope that it will be useful,
|
|
but WITHOUT ANY WARRANTY; without even the implied warranty of
|
|
MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
|
|
Lesser General Public License for more details.
|
|
|
|
You should have received a copy of the GNU Lesser General Public
|
|
License along with the GNU C Library; if not, see
|
|
<https://www.gnu.org/licenses/>. */
|
|
|
|
/* clone() is even more special than fork() as it mucks with stacks
|
|
and invokes a function in the right context after its all over. */
|
|
|
|
#include <sysdep.h>
|
|
#define _ERRNO_H 1
|
|
#include <bits/errno.h>
|
|
#include <asm-syntax.h>
|
|
|
|
/* The userland implementation is:
|
|
int clone (int (*fn)(void *arg), void *child_stack, int flags, void *arg),
|
|
the kernel entry is:
|
|
int clone (long flags, void *child_stack).
|
|
|
|
The parameters are passed in register and on the stack from userland:
|
|
rdi: fn
|
|
rsi: child_stack
|
|
rdx: flags
|
|
rcx: arg
|
|
r8d: TID field in parent
|
|
r9d: thread pointer
|
|
%esp+8: TID field in child
|
|
|
|
The kernel expects:
|
|
rax: system call number
|
|
rdi: flags
|
|
rsi: child_stack
|
|
rdx: TID field in parent
|
|
r10: TID field in child
|
|
r8: thread pointer */
|
|
|
|
|
|
.text
|
|
ENTRY (__clone)
|
|
/* Sanity check arguments. */
|
|
movq $-EINVAL,%rax
|
|
testq %rdi,%rdi /* no NULL function pointers */
|
|
jz SYSCALL_ERROR_LABEL
|
|
testq %rsi,%rsi /* no NULL stack pointers */
|
|
jz SYSCALL_ERROR_LABEL
|
|
|
|
/* Insert the argument onto the new stack. */
|
|
subq $16,%rsi
|
|
movq %rcx,8(%rsi)
|
|
|
|
/* Save the function pointer. It will be popped off in the
|
|
child in the ebx frobbing below. */
|
|
movq %rdi,0(%rsi)
|
|
|
|
/* Do the system call. */
|
|
movq %rdx, %rdi
|
|
movq %r8, %rdx
|
|
movq %r9, %r8
|
|
mov 8(%rsp), %R10_LP
|
|
movl $SYS_ify(clone),%eax
|
|
|
|
/* End FDE now, because in the child the unwind info will be
|
|
wrong. */
|
|
cfi_endproc;
|
|
syscall
|
|
|
|
testq %rax,%rax
|
|
jl SYSCALL_ERROR_LABEL
|
|
jz L(thread_start)
|
|
|
|
ret
|
|
|
|
L(thread_start):
|
|
cfi_startproc;
|
|
/* Clearing frame pointer is insufficient, use CFI. */
|
|
cfi_undefined (rip);
|
|
/* Clear the frame pointer. The ABI suggests this be done, to mark
|
|
the outermost frame obviously. */
|
|
xorl %ebp, %ebp
|
|
|
|
/* Set up arguments for the function call. */
|
|
popq %rax /* Function to call. */
|
|
popq %rdi /* Argument. */
|
|
call *%rax
|
|
/* Call exit with return value from function call. */
|
|
movq %rax, %rdi
|
|
movl $SYS_ify(exit), %eax
|
|
syscall
|
|
cfi_endproc;
|
|
|
|
cfi_startproc;
|
|
PSEUDO_END (__clone)
|
|
|
|
libc_hidden_def (__clone)
|
|
weak_alias (__clone, clone)
|