mirror of
https://sourceware.org/git/glibc.git
synced 2024-12-26 04:31:03 +00:00
389d1f1b23
* sysdeps/aarch64/crti.S: Add include of sysdep.h. (call_weak_fn): Use PTR_REG to get correct reg name in ILP32. * sysdeps/aarch64/dl-irel.h: Add include of sysdep.h. (elf_irela): Use AARCH64_R macro to get correct relocation in ILP32. * sysdeps/aarch64/dl-machine.h: Add include of sysdep.h. (elf_machine_load_address, RTLD_START, RTLD_START_1, RTLD_START, elf_machine_type_class, ELF_MACHINE_JMP_SLOT, elf_machine_rela, elf_machine_lazy_rel): Add ifdef's for ILP32 support. * sysdeps/aarch64/dl-tlsdesc.S (_dl_tlsdesc_return, _dl_tlsdesc_return_lazy, _dl_tlsdesc_dynamic, _dl_tlsdesc_resolve_hold): Extend pointers in ILP32, use PTR_REG to get correct reg name for ILP32. * sysdeps/aarch64/dl-trampoline.S (ip01): New Macro. (RELA_SIZE): New Macro. (_dl_runtime_resolve, _dl_runtime_profile): Use new macros and PTR_REG to support ILP32. * sysdeps/aarch64/jmpbuf-unwind.h (_JMPBUF_CFA_UNWINDS_ADJ): Add cast for ILP32 mode. * sysdeps/aarch64/memcmp.S (memcmp): Extend arg pointers for ILP32 mode. * sysdeps/aarch64/memcpy.S (memmove, memcpy): Ditto. * sysdeps/aarch64/memset.S (__memset): Ditto. * sysdeps/aarch64/strchr.S (strchr): Ditto. * sysdeps/aarch64/strchrnul.S (__strchrnul): Ditto. * sysdeps/aarch64/strcmp.S (strcmp): Ditto. * sysdeps/aarch64/strcpy.S (strcpy): Ditto. * sysdeps/aarch64/strlen.S (__strlen): Ditto. * sysdeps/aarch64/strncmp.S (strncmp): Ditto. * sysdeps/aarch64/strnlen.S (strnlen): Ditto. * sysdeps/aarch64/strrchr.S (strrchr): Ditto. * sysdeps/unix/sysv/linux/aarch64/clone.S: Ditto. * sysdeps/unix/sysv/linux/aarch64/setcontext.S (__setcontext): Ditto. * sysdeps/unix/sysv/linux/aarch64/swapcontext.S (__swapcontext): Ditto. * sysdeps/aarch64/__longjmp.S (__longjmp): Extend pointers in ILP32, change PTR_MANGLE call to use register numbers instead of names. * sysdeps/unix/sysv/linux/aarch64/getcontext.S (__getcontext): Ditto. * sysdeps/aarch64/setjmp.S (__sigsetjmp): Extend arg pointers for ILP32 mode, change PTR_MANGLE calls to use register numbers. * sysdeps/aarch64/start.S (_start): Ditto. * sysdeps/aarch64/nptl/bits/pthreadtypes.h (__PTHREAD_RWLOCK_INT_FLAGS_SHARED): New define. (__SIZEOF_PTHREAD_ATTR_T, __SIZEOF_PTHREAD_MUTEX_T, __SIZEOF_PTHREAD_MUTEXATTR_T, __SIZEOF_PTHREAD_COND_T, __SIZEOF_PTHREAD_COND_COMPAT_T, __SIZEOF_PTHREAD_CONDATTR_T, __SIZEOF_PTHREAD_RWLOCK_T, __SIZEOF_PTHREAD_RWLOCKATTR_T, __SIZEOF_PTHREAD_BARRIER_T, __SIZEOF_PTHREAD_BARRIERATTR_T): Make defined values dependent on __ILP32__. * sysdeps/aarch64/nptl/bits/semaphore.h (__SIZEOF_SEM_T): Change define. (sem_t): Change __align type. * sysdeps/aarch64/sysdep.h (AARCH64_R, PTR_REG, PTR_LOG_SIZE, DELOUSE, PTR_SIZE): New Macros. (LDST_PCREL, LDST_GLOBAL) Update to use PTR_REG. * sysdeps/unix/sysv/linux/aarch64/bits/fcntl.h (O_LARGEFILE): Set when in ILP32 mode. (F_GETLK64, F_SETLK64, F_SETLKW64): Only set in LP64 mode. * sysdeps/unix/sysv/linux/aarch64/dl-cache.h (DL_CACHE_DEFAULT_ID): Set elf flags for ILP32. (add_system_dir): Set ILP32 library directories. * sysdeps/unix/sysv/linux/aarch64/init-first.c (_libc_vdso_platform_setup): Set minimum kernel version for ILP32. * sysdeps/unix/sysv/linux/aarch64/ldconfig.h (SYSDEP_KNOWN_INTERPRETER_NAMES): Add ILP32 names. * sysdeps/unix/sysv/linux/aarch64/sigcontextinfo.h (GET_PC, SET_PC): New Macros. * sysdeps/unix/sysv/linux/aarch64/sysdep.h: Handle ILP32 pointers.
119 lines
3.5 KiB
ArmAsm
119 lines
3.5 KiB
ArmAsm
/* Copyright (C) 1997-2016 Free Software Foundation, Inc.
|
|
|
|
This file is part of the GNU C Library.
|
|
|
|
The GNU C Library is free software; you can redistribute it and/or
|
|
modify it under the terms of the GNU Lesser General Public License as
|
|
published by the Free Software Foundation; either version 2.1 of the
|
|
License, or (at your option) any later version.
|
|
|
|
The GNU C Library is distributed in the hope that it will be useful,
|
|
but WITHOUT ANY WARRANTY; without even the implied warranty of
|
|
MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
|
|
Lesser General Public License for more details.
|
|
|
|
You should have received a copy of the GNU Lesser General Public
|
|
License along with the GNU C Library. If not, see
|
|
<http://www.gnu.org/licenses/>. */
|
|
|
|
#include <sysdep.h>
|
|
#include <jmpbuf-offsets.h>
|
|
#include <stap-probe.h>
|
|
|
|
/* __longjmp(jmpbuf, val) */
|
|
|
|
ENTRY (__longjmp)
|
|
cfi_def_cfa(x0, 0)
|
|
cfi_offset(x19, JB_X19<<3)
|
|
cfi_offset(x20, JB_X20<<3)
|
|
cfi_offset(x21, JB_X21<<3)
|
|
cfi_offset(x22, JB_X22<<3)
|
|
cfi_offset(x23, JB_X23<<3)
|
|
cfi_offset(x24, JB_X24<<3)
|
|
cfi_offset(x25, JB_X25<<3)
|
|
cfi_offset(x26, JB_X26<<3)
|
|
cfi_offset(x27, JB_X27<<3)
|
|
cfi_offset(x28, JB_X28<<3)
|
|
cfi_offset(x29, JB_X29<<3)
|
|
cfi_offset(x30, JB_LR<<3)
|
|
|
|
cfi_offset( d8, JB_D8<<3)
|
|
cfi_offset( d9, JB_D9<<3)
|
|
cfi_offset(d10, JB_D10<<3)
|
|
cfi_offset(d11, JB_D11<<3)
|
|
cfi_offset(d12, JB_D12<<3)
|
|
cfi_offset(d13, JB_D13<<3)
|
|
cfi_offset(d14, JB_D14<<3)
|
|
cfi_offset(d15, JB_D15<<3)
|
|
|
|
DELOUSE (0)
|
|
|
|
ldp x19, x20, [x0, #JB_X19<<3]
|
|
ldp x21, x22, [x0, #JB_X21<<3]
|
|
ldp x23, x24, [x0, #JB_X23<<3]
|
|
ldp x25, x26, [x0, #JB_X25<<3]
|
|
ldp x27, x28, [x0, #JB_X27<<3]
|
|
#ifdef PTR_DEMANGLE
|
|
ldp x29, x4, [x0, #JB_X29<<3]
|
|
PTR_DEMANGLE (30, 4, 3, 2)
|
|
#else
|
|
ldp x29, x30, [x0, #JB_X29<<3]
|
|
#endif
|
|
/* longjmp probe takes 3 arguments, address of jump buffer as
|
|
first argument (8@x0), return value as second argument (-4@x1),
|
|
and target address (8@x30), respectively. */
|
|
LIBC_PROBE (longjmp, 3, 8@x0, -4@x1, 8@x30)
|
|
ldp d8, d9, [x0, #JB_D8<<3]
|
|
ldp d10, d11, [x0, #JB_D10<<3]
|
|
ldp d12, d13, [x0, #JB_D12<<3]
|
|
ldp d14, d15, [x0, #JB_D14<<3]
|
|
|
|
/* Originally this was implemented with a series of
|
|
.cfi_restore() directives.
|
|
|
|
The theory was that cfi_restore should revert to previous
|
|
frame value is the same as the current value. In practice
|
|
this doesn't work, even after cfi_restore() gdb continues
|
|
to try to recover a previous frame value offset from x0,
|
|
which gets stuffed after a few more instructions. The
|
|
cfi_same_value() mechanism appears to work fine. */
|
|
|
|
cfi_same_value(x19)
|
|
cfi_same_value(x20)
|
|
cfi_same_value(x21)
|
|
cfi_same_value(x22)
|
|
cfi_same_value(x23)
|
|
cfi_same_value(x24)
|
|
cfi_same_value(x25)
|
|
cfi_same_value(x26)
|
|
cfi_same_value(x27)
|
|
cfi_same_value(x28)
|
|
cfi_same_value(x29)
|
|
cfi_same_value(x30)
|
|
cfi_same_value(d8)
|
|
cfi_same_value(d9)
|
|
cfi_same_value(d10)
|
|
cfi_same_value(d11)
|
|
cfi_same_value(d12)
|
|
cfi_same_value(d13)
|
|
cfi_same_value(d14)
|
|
cfi_same_value(d15)
|
|
#ifdef PTR_DEMANGLE
|
|
ldr x4, [x0, #JB_SP<<3]
|
|
PTR_DEMANGLE (5, 4, 3, 2)
|
|
#else
|
|
ldr x5, [x0, #JB_SP<<3]
|
|
#endif
|
|
mov sp, x5
|
|
|
|
/* longjmp_target probe takes 3 arguments, address of jump buffer
|
|
as first argument (8@x0), return value as second argument (-4@x1),
|
|
and target address (8@x30), respectively. */
|
|
LIBC_PROBE (longjmp_target, 3, 8@x0, -4@x1, 8@x30)
|
|
cmp x1, #0
|
|
mov x0, #1
|
|
csel x0, x1, x0, ne
|
|
/* Use br instead of ret because ret is guaranteed to mispredict */
|
|
br x30
|
|
END (__longjmp)
|