mirror of
https://sourceware.org/git/glibc.git
synced 2024-12-13 23:00:22 +00:00
3f823e87cc
On aarch64, alpha, arm, hppa, mips, nios2, powerpc, sh, sparc, tile, and x86_64 the clone syscall jumps to _exit after the child execution and the function ends the process execution by calling exit_group. This behavior have a small issue where threads created with CLONE_THREAD using clone syscall directly will eventually exit the whole group altogether instead of just the thread created. Also, s390, microblaze, ia64, i386, and m68k differs by calling exit syscall directly. This patch changes all architectures to call the exit syscall directly, as for s390, microblaze, ia64, i386, and m68k. This do not have change glibc internal behavior in any sort, since the only usage of clone implementation in posix_spawn calls _exit directly in the created child (fork uses a direct call to clone). Checked on x86_64-linux-gnu, i686-linux-gnu, aarch64-linux-gnu, powerpc-linux-gnu, powerpc64le-linux-gnu, sparc64-linux-gnu, and sparcv9-linux-gnu. [BZ #21512] * sysdeps/unix/sysv/linux/aarch64/clone.S (__clone): Call exit syscall instead of jump to _exit. (CLONE_VM_BIT): Remove unused define. (CLONE_VM): Likewise. (CLONE_THREAD_BIT): Likewise. (CLONE_THREAD): Likewise. * sysdeps/unix/sysv/linux/alpha/clone.S (__clone): Likewise. (CLONE_VM): Remove unused define. * sysdeps/unix/sysv/linux/arm/clone.S (__clone): Likewise. (CLONE_VM): Remove unused define. (CLONE_THREAD): Likewise. * sysdeps/unix/sysv/linux/i386/clone.S (CLONE_VM): Likewise. * sysdeps/unix/sysv/linux/ia64/clone2.S (__clone2): Call exit syscall instead of jump to _exit. * sysdeps/unix/sysv/linux/hppa/clone.S (__clone): Likewise. * sysdeps/unix/sysv/linux/mips/clone.S (__clone): Likewise. (CLONE_VM): Remove unused define. (CLONE_THREAD): Likewise. * sysdeps/unix/sysv/linux/nios2/clone.S (__clone): Likewise. (CLONE_VM): Remove unused define. * sysdeps/unix/sysv/linux/powerpc/powerpc32/clone.S (__clone): Likewise. (CLONE_VM): Remove unused define. (CLONE_THREAD): Likewise. * sysdeps/unix/sysv/linux/powerpc/powerpc64/clone.S (__clone): Likewise. (CLONE_VM): Remove unused define. (CLONE_THREAD): Likewise. * sysdeps/unix/sysv/linux/sh/clone.S (__clone): Likewise. * sysdeps/unix/sysv/linux/sparc/sparc32/clone.S (__clone): Likewise. (CLONE_VM): Remove unused define. * sysdeps/unix/sysv/linux/sparc/sparc64/clone.S (__clone): Likewise. (CLONE_VM): Remove unused define. * sysdeps/unix/sysv/linux/tile/clone.S (__clone): Likewise. * sysdeps/unix/sysv/linux/x86_64/clone.S (__clone): Likewise. (CLONE_VM): Remove unused define. * sysdeps/unix/sysv/linux/Makefile (tests): Add tst-clone3. * sysdeps/unix/sysv/linux/tst-clone3.c: New file. Fix
107 lines
2.8 KiB
ArmAsm
107 lines
2.8 KiB
ArmAsm
/* Copyright (C) 2001-2017 Free Software Foundation, Inc.
|
|
This file is part of the GNU C Library.
|
|
|
|
The GNU C Library is free software; you can redistribute it and/or
|
|
modify it under the terms of the GNU Lesser General Public
|
|
License as published by the Free Software Foundation; either
|
|
version 2.1 of the License, or (at your option) any later version.
|
|
|
|
The GNU C Library is distributed in the hope that it will be useful,
|
|
but WITHOUT ANY WARRANTY; without even the implied warranty of
|
|
MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
|
|
Lesser General Public License for more details.
|
|
|
|
You should have received a copy of the GNU Lesser General Public
|
|
License along with the GNU C Library; if not, see
|
|
<http://www.gnu.org/licenses/>. */
|
|
|
|
/* clone() is even more special than fork() as it mucks with stacks
|
|
and invokes a function in the right context after its all over. */
|
|
|
|
#include <sysdep.h>
|
|
#define _ERRNO_H 1
|
|
#include <bits/errno.h>
|
|
#include <asm-syntax.h>
|
|
|
|
/* The userland implementation is:
|
|
int clone (int (*fn)(void *arg), void *child_stack, int flags, void *arg),
|
|
the kernel entry is:
|
|
int clone (long flags, void *child_stack).
|
|
|
|
The parameters are passed in register and on the stack from userland:
|
|
rdi: fn
|
|
rsi: child_stack
|
|
rdx: flags
|
|
rcx: arg
|
|
r8d: TID field in parent
|
|
r9d: thread pointer
|
|
%esp+8: TID field in child
|
|
|
|
The kernel expects:
|
|
rax: system call number
|
|
rdi: flags
|
|
rsi: child_stack
|
|
rdx: TID field in parent
|
|
r10: TID field in child
|
|
r8: thread pointer */
|
|
|
|
|
|
.text
|
|
ENTRY (__clone)
|
|
/* Sanity check arguments. */
|
|
movq $-EINVAL,%rax
|
|
testq %rdi,%rdi /* no NULL function pointers */
|
|
jz SYSCALL_ERROR_LABEL
|
|
testq %rsi,%rsi /* no NULL stack pointers */
|
|
jz SYSCALL_ERROR_LABEL
|
|
|
|
/* Insert the argument onto the new stack. */
|
|
subq $16,%rsi
|
|
movq %rcx,8(%rsi)
|
|
|
|
/* Save the function pointer. It will be popped off in the
|
|
child in the ebx frobbing below. */
|
|
movq %rdi,0(%rsi)
|
|
|
|
/* Do the system call. */
|
|
movq %rdx, %rdi
|
|
movq %r8, %rdx
|
|
movq %r9, %r8
|
|
mov 8(%rsp), %R10_LP
|
|
movl $SYS_ify(clone),%eax
|
|
|
|
/* End FDE now, because in the child the unwind info will be
|
|
wrong. */
|
|
cfi_endproc;
|
|
syscall
|
|
|
|
testq %rax,%rax
|
|
jl SYSCALL_ERROR_LABEL
|
|
jz L(thread_start)
|
|
|
|
ret
|
|
|
|
L(thread_start):
|
|
cfi_startproc;
|
|
/* Clearing frame pointer is insufficient, use CFI. */
|
|
cfi_undefined (rip);
|
|
/* Clear the frame pointer. The ABI suggests this be done, to mark
|
|
the outermost frame obviously. */
|
|
xorl %ebp, %ebp
|
|
|
|
/* Set up arguments for the function call. */
|
|
popq %rax /* Function to call. */
|
|
popq %rdi /* Argument. */
|
|
call *%rax
|
|
/* Call exit with return value from function call. */
|
|
movq %rax, %rdi
|
|
movl $SYS_ify(exit), %eax
|
|
syscall
|
|
cfi_endproc;
|
|
|
|
cfi_startproc;
|
|
PSEUDO_END (__clone)
|
|
|
|
libc_hidden_def (__clone)
|
|
weak_alias (__clone, clone)
|