mirror of
https://sourceware.org/git/glibc.git
synced 2024-12-12 22:30:12 +00:00
37d13b179c
For each function setjmp, longjmp, getcontext, there exist a symbol <func> and a default/versioned symbol <func>@@GLIBC_2.x in the build obj-files. This is wrong because it should only exist an unversioned or a default-versioned symbol with the same name in an obj-file. Glibc can't be build with recent binutils. See the already fixed linker bug https://sourceware.org/bugzilla/show_bug.cgi?id=19073. Nevertheless, this patch cleans this up. Furthermore the BSD entry points setjmp, _setjmp were marked as weak, but should be strong as on other architectures. (see https://sourceware.org/ml/libc-alpha/2014-07/msg00568.html for an older discussion with Andreas Schwab) Some whitespace issues are corrected in sysdeps/s390/s390-64/setjmp.S, too. But there is no change in the assembler code. ChangeLog: * sysdeps/s390/longjmp.c (longjmp, _longjmp, siglongjmp): Don't create weak aliases, because versioned symbols are created later. * sysdeps/s390/s390-32/setjmp.S (setjmp, _setjmp): Remove weak and rename to an unique name in SHARED case due to existing versioned symbols. * sysdeps/s390/s390-64/setjmp.S: Likewise. * sysdeps/unix/sysv/linux/s390/s390-32/getcontext.S (getcontext): Create weak alias only in non SHARED case. * sysdeps/unix/sysv/linux/s390/s390-64/getcontext.S: Likewise.
90 lines
2.7 KiB
ArmAsm
90 lines
2.7 KiB
ArmAsm
/* Copyright (C) 2001-2015 Free Software Foundation, Inc.
|
|
This file is part of the GNU C Library.
|
|
Contributed by Martin Schwidefsky (schwidefsky@de.ibm.com).
|
|
|
|
The GNU C Library is free software; you can redistribute it and/or
|
|
modify it under the terms of the GNU Lesser General Public
|
|
License as published by the Free Software Foundation; either
|
|
version 2.1 of the License, or (at your option) any later version.
|
|
|
|
The GNU C Library is distributed in the hope that it will be useful,
|
|
but WITHOUT ANY WARRANTY; without even the implied warranty of
|
|
MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
|
|
Lesser General Public License for more details.
|
|
|
|
You should have received a copy of the GNU Lesser General Public
|
|
License along with the GNU C Library; if not, see
|
|
<http://www.gnu.org/licenses/>. */
|
|
|
|
#include <sysdep.h>
|
|
#include <features.h>
|
|
|
|
#include "ucontext_i.h"
|
|
|
|
#include <shlib-compat.h>
|
|
|
|
/* __getcontext (const ucontext_t *ucp)
|
|
|
|
Saves the machine context in UCP such that when it is activated,
|
|
it appears as if __getcontext() returned again.
|
|
|
|
This implementation is intended to be used for *synchronous* context
|
|
switches only. Therefore, it does not have to save anything
|
|
other than the PRESERVED state. */
|
|
|
|
ENTRY(__getcontext)
|
|
lr %r1,%r2
|
|
|
|
/* rt_sigprocmask (SIG_BLOCK, NULL, &sc->sc_mask, sigsetsize). */
|
|
la %r2,SIG_BLOCK
|
|
slr %r3,%r3
|
|
la %r4,SC_MASK(%r1)
|
|
lhi %r5,_NSIG8
|
|
svc SYS_ify(rt_sigprocmask)
|
|
|
|
/* Store fpu context. */
|
|
stfpc SC_FPC(%r1)
|
|
std %f0,SC_FPRS(%r1)
|
|
std %f1,SC_FPRS+8(%r1)
|
|
std %f2,SC_FPRS+16(%r1)
|
|
std %f3,SC_FPRS+24(%r1)
|
|
std %f4,SC_FPRS+32(%r1)
|
|
std %f5,SC_FPRS+40(%r1)
|
|
std %f6,SC_FPRS+48(%r1)
|
|
std %f7,SC_FPRS+56(%r1)
|
|
std %f8,SC_FPRS+64(%r1)
|
|
std %f9,SC_FPRS+72(%r1)
|
|
std %f10,SC_FPRS+80(%r1)
|
|
std %f11,SC_FPRS+88(%r1)
|
|
std %f12,SC_FPRS+96(%r1)
|
|
std %f13,SC_FPRS+104(%r1)
|
|
std %f14,SC_FPRS+112(%r1)
|
|
std %f15,SC_FPRS+120(%r1)
|
|
|
|
/* Set __getcontext return value to 0. */
|
|
slr %r2,%r2
|
|
|
|
/* Store access registers. */
|
|
stam %a0,%a15,SC_ACRS(%r1)
|
|
|
|
/* Store general purpose registers. */
|
|
stm %r0,%r15,SC_GPRS(%r1)
|
|
|
|
/* Return. */
|
|
br %r14
|
|
END(__getcontext)
|
|
|
|
#if defined SHARED && SHLIB_COMPAT (libc, GLIBC_2_19, GLIBC_2_20)
|
|
/* In glibc release 2.19 a new version of getcontext was introduced,
|
|
but was reverted before 2.20. Thus both versions are the same function. */
|
|
weak_alias (__getcontext, __v1__getcontext)
|
|
weak_alias (__getcontext, __v2__getcontext)
|
|
versioned_symbol (libc, __v1__getcontext, getcontext, GLIBC_2_1)
|
|
compat_symbol (libc, __v2__getcontext, getcontext, GLIBC_2_19)
|
|
|
|
#else
|
|
|
|
weak_alias (__getcontext, getcontext)
|
|
|
|
#endif /* !(defined SHARED && SHLIB_COMPAT (libc, GLIBC_2_19, GLIBC_2_20)) */
|