mirror of
https://sourceware.org/git/glibc.git
synced 2024-11-12 08:10:06 +00:00
8f5ca04bc7
* malloc/malloc.c (_malloc_internal): Performance fix. Move
if statement out of loop.
* stdio/_itoa.c, stdio/_itoa.h: Complete rewrite. Much faster
implementation using GMP functions. Contributed by
Torbjorn Granlund and Ulrich Drepper.
* stdio/test_rdwr.c: Include <errno.h>.
* sysdeps/i386/i586/Implies: New file.
New highly optimized string functions for i[345]86.
* sysdeps/i386/memchr.S, sysdeps/i386/memcmp.S: New files.
* sysdeps/i386/stpcpy.S, sysdeps/i386/stpncpy.S: New files.
* sysdeps/i386/strchr.S, sysdeps/i386/strcspn.S: New files.
* sysdeps/i386/strpbrk.S, sysdeps/i386/strrchr.S: New files.
* sysdeps/i386/strspn.S, sysdeps/i386/i486/strcat.S: New files.
* sysdeps/i386/i486/strlen.S, sysdeps/i386/i586/strchr.S: New files.
* sysdeps/i386/i586/strlen.S: New file.
* sysdeps/i386/memchr.c: Removed. There is now an assembler version.
* sysdeps/i386/i586/memcopy.h (WORD_COPY_BWD): Parameters did
not correspond to used values.
* sysdeps/unix/sysv/linux/nfs/nfs.h: New file. Simply a wrapper
around a kernel header file.
* sysdeps/unix/sysv/linux/Dist: Add it.
* sysdeps/unix/sysv/linux/Makefile [$(subdir)=sunrpc] (headers):
Likewise.
* sysdeps/unix/sysv/linux/local_lim.h: Rewrite. Instead of
defining ourself we use a kernel header file.
* sysdeps/unix/sysv/linux/i386/sysdep.h (DO_CALL): Optimize system
call handler for i586.
* sysdeps/unix/sysv/linux/sys/param.h: Add copyright and clean up.
Sat Oct 14 02:52:36 1995 Ulrich Drepper <drepper@ipd.info.uni-karlsruhe.de>
* malloc/malloc.c (_malloc_internal): Performance fix. Move
if statement out of loop.
* stdio/_itoa.c, stdio/_itoa.h: Complete rewrite. Much faster
implementation using GMP functions. Contributed by
Torbjorn Granlund and Ulrich Drepper.
* stdio/test_rdwr.c: Include <errno.h>.
* sysdeps/i386/i586/Implies: New file.
New highly optimized string functions for i[345]86.
* sysdeps/i386/memchr.S, sysdeps/i386/memcmp.S: New files.
* sysdeps/i386/stpcpy.S, sysdeps/i386/stpncpy.S: New files.
* sysdeps/i386/strchr.S, sysdeps/i386/strcspn.S: New files.
* sysdeps/i386/strpbrk.S, sysdeps/i386/strrchr.S: New files.
* sysdeps/i386/strspn.S, sysdeps/i386/i486/strcat.S: New files.
* sysdeps/i386/i486/strlen.S, sysdeps/i386/i586/strchr.S: New files.
* sysdeps/i386/i586/strlen.S: New file.
* sysdeps/i386/memchr.c: Removed. There is now an assembler version.
* sysdeps/i386/i586/memcopy.h (WORD_COPY_BWD): Parameters did
not correspond to used values.
* sysdeps/unix/sysv/linux/nfs/nfs.h: New file. Simply a wrapper
around a kernel header file.
* sysdeps/unix/sysv/linux/Dist: Add it.
* sysdeps/unix/sysv/linux/Makefile [$(subdir)=sunrpc] (headers):
Likewise.
* sysdeps/unix/sysv/linux/local_lim.h: Rewrite. Instead of
defining ourself we use a kernel header file.
* sysdeps/unix/sysv/linux/i386/sysdep.h (DO_CALL): Optimize system
call handler for i586.
* sysdeps/unix/sysv/linux/sys/param.h: Add copyright and clean up.
101 lines
3.0 KiB
ArmAsm
101 lines
3.0 KiB
ArmAsm
# Alpha 21064 __mpn_addmul_1 -- Multiply a limb vector with a limb and add
|
|
# the result to a second limb vector.
|
|
|
|
# Copyright (C) 1992, 1994, 1995 Free Software Foundation, Inc.
|
|
|
|
# This file is part of the GNU MP Library.
|
|
|
|
# The GNU MP Library is free software; you can redistribute it and/or modify
|
|
# it under the terms of the GNU Library General Public License as published by
|
|
# the Free Software Foundation; either version 2 of the License, or (at your
|
|
# option) any later version.
|
|
|
|
# The GNU MP Library is distributed in the hope that it will be useful, but
|
|
# WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
|
|
# or FITNESS FOR A PARTICULAR PURPOSE. See the GNU Library General Public
|
|
# License for more details.
|
|
|
|
# You should have received a copy of the GNU Library General Public License
|
|
# along with the GNU MP Library; see the file COPYING.LIB. If not, write to
|
|
# the Free Software Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
|
|
|
|
|
|
# INPUT PARAMETERS
|
|
# res_ptr r16
|
|
# s1_ptr r17
|
|
# size r18
|
|
# s2_limb r19
|
|
|
|
# This code runs at 42 cycles/limb on the 21064.
|
|
|
|
# To improve performance for long multiplications, we would use
|
|
# 'fetch' for S1 and 'fetch_m' for RES. It's not obvious how to use
|
|
# these instructions without slowing down the general code: 1. We can
|
|
# only have two prefetches in operation at any time in the Alpha
|
|
# architecture. 2. There will seldom be any special alignment
|
|
# between RES_PTR and S1_PTR. Maybe we can simply divide the current
|
|
# loop into an inner and outer loop, having the inner loop handle
|
|
# exactly one prefetch block?
|
|
|
|
.set noreorder
|
|
.set noat
|
|
.text
|
|
.align 3
|
|
.globl __mpn_addmul_1
|
|
.ent __mpn_addmul_1 2
|
|
__mpn_addmul_1:
|
|
.frame $30,0,$26
|
|
|
|
ldq $2,0($17) # $2 = s1_limb
|
|
addq $17,8,$17 # s1_ptr++
|
|
subq $18,1,$18 # size--
|
|
mulq $2,$19,$3 # $3 = prod_low
|
|
ldq $5,0($16) # $5 = *res_ptr
|
|
umulh $2,$19,$0 # $0 = prod_high
|
|
beq $18,Lend1 # jump if size was == 1
|
|
ldq $2,0($17) # $2 = s1_limb
|
|
addq $17,8,$17 # s1_ptr++
|
|
subq $18,1,$18 # size--
|
|
addq $5,$3,$3
|
|
cmpult $3,$5,$4
|
|
stq $3,0($16)
|
|
addq $16,8,$16 # res_ptr++
|
|
beq $18,Lend2 # jump if size was == 2
|
|
|
|
.align 3
|
|
Loop: mulq $2,$19,$3 # $3 = prod_low
|
|
ldq $5,0($16) # $5 = *res_ptr
|
|
addq $4,$0,$0 # cy_limb = cy_limb + 'cy'
|
|
subq $18,1,$18 # size--
|
|
umulh $2,$19,$4 # $4 = cy_limb
|
|
ldq $2,0($17) # $2 = s1_limb
|
|
addq $17,8,$17 # s1_ptr++
|
|
addq $3,$0,$3 # $3 = cy_limb + prod_low
|
|
cmpult $3,$0,$0 # $0 = carry from (cy_limb + prod_low)
|
|
addq $5,$3,$3
|
|
cmpult $3,$5,$5
|
|
stq $3,0($16)
|
|
addq $16,8,$16 # res_ptr++
|
|
addq $5,$0,$0 # combine carries
|
|
bne $18,Loop
|
|
|
|
Lend2: mulq $2,$19,$3 # $3 = prod_low
|
|
ldq $5,0($16) # $5 = *res_ptr
|
|
addq $4,$0,$0 # cy_limb = cy_limb + 'cy'
|
|
umulh $2,$19,$4 # $4 = cy_limb
|
|
addq $3,$0,$3 # $3 = cy_limb + prod_low
|
|
cmpult $3,$0,$0 # $0 = carry from (cy_limb + prod_low)
|
|
addq $5,$3,$3
|
|
cmpult $3,$5,$5
|
|
stq $3,0($16)
|
|
addq $5,$0,$0 # combine carries
|
|
addq $4,$0,$0 # cy_limb = prod_high + cy
|
|
ret $31,($26),1
|
|
Lend1: addq $5,$3,$3
|
|
cmpult $3,$5,$5
|
|
stq $3,0($16)
|
|
addq $0,$5,$0
|
|
ret $31,($26),1
|
|
|
|
.end __mpn_addmul_1
|