mirror of
https://sourceware.org/git/glibc.git
synced 2024-11-26 23:10:06 +00:00
389d1f1b23
* sysdeps/aarch64/crti.S: Add include of sysdep.h. (call_weak_fn): Use PTR_REG to get correct reg name in ILP32. * sysdeps/aarch64/dl-irel.h: Add include of sysdep.h. (elf_irela): Use AARCH64_R macro to get correct relocation in ILP32. * sysdeps/aarch64/dl-machine.h: Add include of sysdep.h. (elf_machine_load_address, RTLD_START, RTLD_START_1, RTLD_START, elf_machine_type_class, ELF_MACHINE_JMP_SLOT, elf_machine_rela, elf_machine_lazy_rel): Add ifdef's for ILP32 support. * sysdeps/aarch64/dl-tlsdesc.S (_dl_tlsdesc_return, _dl_tlsdesc_return_lazy, _dl_tlsdesc_dynamic, _dl_tlsdesc_resolve_hold): Extend pointers in ILP32, use PTR_REG to get correct reg name for ILP32. * sysdeps/aarch64/dl-trampoline.S (ip01): New Macro. (RELA_SIZE): New Macro. (_dl_runtime_resolve, _dl_runtime_profile): Use new macros and PTR_REG to support ILP32. * sysdeps/aarch64/jmpbuf-unwind.h (_JMPBUF_CFA_UNWINDS_ADJ): Add cast for ILP32 mode. * sysdeps/aarch64/memcmp.S (memcmp): Extend arg pointers for ILP32 mode. * sysdeps/aarch64/memcpy.S (memmove, memcpy): Ditto. * sysdeps/aarch64/memset.S (__memset): Ditto. * sysdeps/aarch64/strchr.S (strchr): Ditto. * sysdeps/aarch64/strchrnul.S (__strchrnul): Ditto. * sysdeps/aarch64/strcmp.S (strcmp): Ditto. * sysdeps/aarch64/strcpy.S (strcpy): Ditto. * sysdeps/aarch64/strlen.S (__strlen): Ditto. * sysdeps/aarch64/strncmp.S (strncmp): Ditto. * sysdeps/aarch64/strnlen.S (strnlen): Ditto. * sysdeps/aarch64/strrchr.S (strrchr): Ditto. * sysdeps/unix/sysv/linux/aarch64/clone.S: Ditto. * sysdeps/unix/sysv/linux/aarch64/setcontext.S (__setcontext): Ditto. * sysdeps/unix/sysv/linux/aarch64/swapcontext.S (__swapcontext): Ditto. * sysdeps/aarch64/__longjmp.S (__longjmp): Extend pointers in ILP32, change PTR_MANGLE call to use register numbers instead of names. * sysdeps/unix/sysv/linux/aarch64/getcontext.S (__getcontext): Ditto. * sysdeps/aarch64/setjmp.S (__sigsetjmp): Extend arg pointers for ILP32 mode, change PTR_MANGLE calls to use register numbers. * sysdeps/aarch64/start.S (_start): Ditto. * sysdeps/aarch64/nptl/bits/pthreadtypes.h (__PTHREAD_RWLOCK_INT_FLAGS_SHARED): New define. (__SIZEOF_PTHREAD_ATTR_T, __SIZEOF_PTHREAD_MUTEX_T, __SIZEOF_PTHREAD_MUTEXATTR_T, __SIZEOF_PTHREAD_COND_T, __SIZEOF_PTHREAD_COND_COMPAT_T, __SIZEOF_PTHREAD_CONDATTR_T, __SIZEOF_PTHREAD_RWLOCK_T, __SIZEOF_PTHREAD_RWLOCKATTR_T, __SIZEOF_PTHREAD_BARRIER_T, __SIZEOF_PTHREAD_BARRIERATTR_T): Make defined values dependent on __ILP32__. * sysdeps/aarch64/nptl/bits/semaphore.h (__SIZEOF_SEM_T): Change define. (sem_t): Change __align type. * sysdeps/aarch64/sysdep.h (AARCH64_R, PTR_REG, PTR_LOG_SIZE, DELOUSE, PTR_SIZE): New Macros. (LDST_PCREL, LDST_GLOBAL) Update to use PTR_REG. * sysdeps/unix/sysv/linux/aarch64/bits/fcntl.h (O_LARGEFILE): Set when in ILP32 mode. (F_GETLK64, F_SETLK64, F_SETLKW64): Only set in LP64 mode. * sysdeps/unix/sysv/linux/aarch64/dl-cache.h (DL_CACHE_DEFAULT_ID): Set elf flags for ILP32. (add_system_dir): Set ILP32 library directories. * sysdeps/unix/sysv/linux/aarch64/init-first.c (_libc_vdso_platform_setup): Set minimum kernel version for ILP32. * sysdeps/unix/sysv/linux/aarch64/ldconfig.h (SYSDEP_KNOWN_INTERPRETER_NAMES): Add ILP32 names. * sysdeps/unix/sysv/linux/aarch64/sigcontextinfo.h (GET_PC, SET_PC): New Macros. * sysdeps/unix/sysv/linux/aarch64/sysdep.h: Handle ILP32 pointers.
131 lines
3.7 KiB
ArmAsm
131 lines
3.7 KiB
ArmAsm
/* Set current context.
|
|
|
|
Copyright (C) 2009-2016 Free Software Foundation, Inc.
|
|
|
|
This file is part of the GNU C Library.
|
|
|
|
The GNU C Library is free software; you can redistribute it and/or
|
|
modify it under the terms of the GNU Lesser General Public License as
|
|
published by the Free Software Foundation; either version 2.1 of the
|
|
License, or (at your option) any later version.
|
|
|
|
The GNU C Library is distributed in the hope that it will be useful,
|
|
but WITHOUT ANY WARRANTY; without even the implied warranty of
|
|
MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
|
|
Lesser General Public License for more details.
|
|
|
|
You should have received a copy of the GNU Lesser General Public
|
|
License along with the GNU C Library; if not, see
|
|
<http://www.gnu.org/licenses/>. */
|
|
|
|
#include <sysdep.h>
|
|
#include "ucontext_i.h"
|
|
#include "ucontext-internal.h"
|
|
|
|
/* int __setcontext (const ucontext_t *ucp)
|
|
|
|
Restores the machine context in UCP and thereby resumes execution
|
|
in that context.
|
|
|
|
This implementation is intended to be used for *synchronous* context
|
|
switches only. Therefore, it does not have to restore anything
|
|
other than the PRESERVED state. */
|
|
|
|
.text
|
|
|
|
ENTRY (__setcontext)
|
|
DELOUSE (0)
|
|
/* Save a copy of UCP. */
|
|
mov x9, x0
|
|
|
|
/* Set the signal mask with
|
|
rt_sigprocmask (SIG_SETMASK, mask, NULL, _NSIG/8). */
|
|
mov x0, #SIG_SETMASK
|
|
add x1, x9, #UCONTEXT_SIGMASK
|
|
mov x2, #0
|
|
mov x3, #_NSIG8
|
|
mov x8, SYS_ify (rt_sigprocmask)
|
|
svc 0
|
|
cbz x0, 1f
|
|
b C_SYMBOL_NAME (__syscall_error)
|
|
1:
|
|
/* Restore the general purpose registers. */
|
|
mov x0, x9
|
|
cfi_def_cfa (x0, 0)
|
|
cfi_offset (x18, oX0 + 18 * SZREG)
|
|
cfi_offset (x19, oX0 + 19 * SZREG)
|
|
cfi_offset (x20, oX0 + 20 * SZREG)
|
|
cfi_offset (x21, oX0 + 21 * SZREG)
|
|
cfi_offset (x22, oX0 + 22 * SZREG)
|
|
cfi_offset (x23, oX0 + 23 * SZREG)
|
|
cfi_offset (x24, oX0 + 24 * SZREG)
|
|
cfi_offset (x25, oX0 + 25 * SZREG)
|
|
cfi_offset (x26, oX0 + 26 * SZREG)
|
|
cfi_offset (x27, oX0 + 27 * SZREG)
|
|
cfi_offset (x28, oX0 + 28 * SZREG)
|
|
cfi_offset (x29, oX0 + 29 * SZREG)
|
|
cfi_offset (x30, oX0 + 30 * SZREG)
|
|
|
|
cfi_offset ( d8, oV0 + 8 * SZVREG)
|
|
cfi_offset ( d9, oV0 + 9 * SZVREG)
|
|
cfi_offset (d10, oV0 + 10 * SZVREG)
|
|
cfi_offset (d11, oV0 + 11 * SZVREG)
|
|
cfi_offset (d12, oV0 + 12 * SZVREG)
|
|
cfi_offset (d13, oV0 + 13 * SZVREG)
|
|
cfi_offset (d14, oV0 + 14 * SZVREG)
|
|
cfi_offset (d15, oV0 + 15 * SZVREG)
|
|
ldp x18, x19, [x0, oX0 + 18 * SZREG]
|
|
ldp x20, x21, [x0, oX0 + 20 * SZREG]
|
|
ldp x22, x23, [x0, oX0 + 22 * SZREG]
|
|
ldp x24, x25, [x0, oX0 + 24 * SZREG]
|
|
ldp x26, x27, [x0, oX0 + 26 * SZREG]
|
|
ldp x28, x29, [x0, oX0 + 28 * SZREG]
|
|
ldr x30, [x0, oX0 + 30 * SZREG]
|
|
ldr x2, [x0, oSP]
|
|
mov sp, x2
|
|
|
|
/* Check for FP SIMD context. We don't support restoring
|
|
contexts created by the kernel, so this context must have
|
|
been created by getcontext. Hence we can rely on the
|
|
first extension block being the FP SIMD context. */
|
|
add x2, x0, #oEXTENSION
|
|
|
|
mov w3, #(FPSIMD_MAGIC & 0xffff)
|
|
movk w3, #(FPSIMD_MAGIC >> 16), lsl #16
|
|
ldr w1, [x2, #oHEAD + oMAGIC]
|
|
cmp w1, w3
|
|
b.ne 2f
|
|
|
|
/* Restore the FP SIMD context. */
|
|
add x3, x2, #oV0 + 8 * SZVREG
|
|
ldp q8, q9, [x3], #2 * SZVREG
|
|
ldp q10, q11, [x3], #2 * SZVREG
|
|
ldp q12, q13, [x3], #2 * SZVREG
|
|
ldp q14, q15, [x3], #2 * SZVREG
|
|
|
|
add x3, x2, oFPSR
|
|
|
|
ldr w4, [x3]
|
|
msr fpsr, x4
|
|
|
|
ldr w4, [x3, oFPCR - oFPSR]
|
|
msr fpcr, x4
|
|
|
|
2:
|
|
ldr x16, [x0, oPC]
|
|
/* Restore arg registers. */
|
|
ldp x2, x3, [x0, oX0 + 2 * SZREG]
|
|
ldp x4, x5, [x0, oX0 + 4 * SZREG]
|
|
ldp x6, x7, [x0, oX0 + 6 * SZREG]
|
|
ldp x0, x1, [x0, oX0 + 0 * SZREG]
|
|
/* Jump to the new pc value. */
|
|
br x16
|
|
PSEUDO_END (__setcontext)
|
|
weak_alias (__setcontext, setcontext)
|
|
|
|
ENTRY (__startcontext)
|
|
mov x0, x19
|
|
cbnz x0, __setcontext
|
|
1: b HIDDEN_JUMPTARGET (exit)
|
|
END (__startcontext)
|