mirror of
https://sourceware.org/git/glibc.git
synced 2024-11-22 04:50:07 +00:00
30891f35fa
We stopped adding "Contributed by" or similar lines in sources in 2012 in favour of git logs and keeping the Contributors section of the glibc manual up to date. Removing these lines makes the license header a bit more consistent across files and also removes the possibility of error in attribution when license blocks or files are copied across since the contributed-by lines don't actually reflect reality in those cases. Move all "Contributed by" and similar lines (Written by, Test by, etc.) into a new file CONTRIBUTED-BY to retain record of these contributions. These contributors are also mentioned in manual/contrib.texi, so we just maintain this additional record as a courtesy to the earlier developers. The following scripts were used to filter a list of files to edit in place and to clean up the CONTRIBUTED-BY file respectively. These were not added to the glibc sources because they're not expected to be of any use in future given that this is a one time task: https://gist.github.com/siddhesh/b5ecac94eabfd72ed2916d6d8157e7dc https://gist.github.com/siddhesh/15ea1f5e435ace9774f485030695ee02 Reviewed-by: Carlos O'Donell <carlos@redhat.com>
68 lines
1.3 KiB
ArmAsm
68 lines
1.3 KiB
ArmAsm
/*
|
|
* Public domain.
|
|
*/
|
|
|
|
#include <machine/asm.h>
|
|
#include <libm-alias-finite.h>
|
|
|
|
.section .rodata.cst8,"aM",@progbits,8
|
|
|
|
.p2align 3
|
|
.type one,@object
|
|
one: .double 1.0
|
|
ASM_SIZE_DIRECTIVE(one)
|
|
/* It is not important that this constant is precise. It is only
|
|
a value which is known to be on the safe side for using the
|
|
fyl2xp1 instruction. */
|
|
.type limit,@object
|
|
limit: .double 0.29
|
|
ASM_SIZE_DIRECTIVE(limit)
|
|
|
|
|
|
#ifdef PIC
|
|
# define MO(op) op##@GOTOFF(%edx)
|
|
#else
|
|
# define MO(op) op
|
|
#endif
|
|
|
|
.text
|
|
ENTRY(__ieee754_log10l)
|
|
fldlg2 // log10(2)
|
|
fldt 4(%esp) // x : log10(2)
|
|
#ifdef PIC
|
|
LOAD_PIC_REG (dx)
|
|
#endif
|
|
fxam
|
|
fnstsw
|
|
fld %st // x : x : log10(2)
|
|
sahf
|
|
jc 3f // in case x is NaN or ±Inf
|
|
4: fsubl MO(one) // x-1 : x : log10(2)
|
|
fld %st // x-1 : x-1 : x : log10(2)
|
|
fabs // |x-1| : x-1 : x : log10(2)
|
|
fcompl MO(limit) // x-1 : x : log10(2)
|
|
fnstsw // x-1 : x : log10(2)
|
|
andb $0x45, %ah
|
|
jz 2f
|
|
fxam
|
|
fnstsw
|
|
andb $0x45, %ah
|
|
cmpb $0x40, %ah
|
|
jne 5f
|
|
fabs // log10(1) is +0 in all rounding modes.
|
|
5: fstp %st(1) // x-1 : log10(2)
|
|
fyl2xp1 // log10(x)
|
|
ret
|
|
|
|
2: fstp %st(0) // x : log10(2)
|
|
fyl2x // log10(x)
|
|
ret
|
|
|
|
3: jp 4b // in case x is ±Inf
|
|
fstp %st(1)
|
|
fstp %st(1)
|
|
fadd %st(0)
|
|
ret
|
|
END(__ieee754_log10l)
|
|
libm_alias_finite (__ieee754_log10l, __log10l)
|