mirror of
https://sourceware.org/git/glibc.git
synced 2024-11-22 21:10:07 +00:00
30891f35fa
We stopped adding "Contributed by" or similar lines in sources in 2012 in favour of git logs and keeping the Contributors section of the glibc manual up to date. Removing these lines makes the license header a bit more consistent across files and also removes the possibility of error in attribution when license blocks or files are copied across since the contributed-by lines don't actually reflect reality in those cases. Move all "Contributed by" and similar lines (Written by, Test by, etc.) into a new file CONTRIBUTED-BY to retain record of these contributions. These contributors are also mentioned in manual/contrib.texi, so we just maintain this additional record as a courtesy to the earlier developers. The following scripts were used to filter a list of files to edit in place and to clean up the CONTRIBUTED-BY file respectively. These were not added to the glibc sources because they're not expected to be of any use in future given that this is a one time task: https://gist.github.com/siddhesh/b5ecac94eabfd72ed2916d6d8157e7dc https://gist.github.com/siddhesh/15ea1f5e435ace9774f485030695ee02 Reviewed-by: Carlos O'Donell <carlos@redhat.com>
72 lines
1.1 KiB
ArmAsm
72 lines
1.1 KiB
ArmAsm
/*
|
|
* Public domain.
|
|
*
|
|
*/
|
|
|
|
#include <machine/asm.h>
|
|
|
|
RCSID("$NetBSD: s_log1p.S,v 1.7 1995/05/09 00:10:58 jtc Exp $")
|
|
|
|
.section .rodata
|
|
|
|
.align ALIGNARG(4)
|
|
/* The fyl2xp1 can only be used for values in
|
|
-1 + sqrt(2) / 2 <= x <= 1 - sqrt(2) / 2
|
|
0.29 is a safe value.
|
|
*/
|
|
limit: .tfloat 0.29
|
|
/* Please note: we use a double value here. Since 1.0 has
|
|
an exact representation this does not effect the accuracy
|
|
but it helps to optimize the code. */
|
|
one: .double 1.0
|
|
|
|
/*
|
|
* Use the fyl2xp1 function when the argument is in the range -0.29 to 0.29,
|
|
* otherwise fyl2x with the needed extra computation.
|
|
*/
|
|
#ifdef PIC
|
|
#define MO(op) op##(%rip)
|
|
#else
|
|
#define MO(op) op
|
|
#endif
|
|
|
|
.text
|
|
ENTRY(__log1pl)
|
|
fldln2
|
|
|
|
fldt 8(%rsp)
|
|
|
|
fxam
|
|
fnstsw
|
|
fld %st
|
|
testb $1, %ah
|
|
jnz 3f // in case x is NaN or ±Inf
|
|
4:
|
|
fabs
|
|
fldt MO(limit)
|
|
fcompp
|
|
fnstsw
|
|
andb $1,%ah
|
|
jz 2f
|
|
|
|
movzwl 8+8(%rsp), %eax
|
|
xorb $0x80, %ah
|
|
cmpl $0xc040, %eax
|
|
jae 5f
|
|
|
|
faddl MO(one)
|
|
5: fyl2x
|
|
ret
|
|
|
|
2: fyl2xp1
|
|
ret
|
|
|
|
3: testb $4, %ah
|
|
jnz 4b // in case x is ±Inf
|
|
fstp %st(1)
|
|
fstp %st(1)
|
|
fadd %st(0)
|
|
ret
|
|
|
|
END (__log1pl)
|