mirror of
https://sourceware.org/git/glibc.git
synced 2025-01-10 03:10:09 +00:00
5a2cf833f5
Commitc73c96a4a1updated memcpy.S and mempcpy.S, but omitted memmove.S and memset.S. As a result, the static library built as PIC, whether with or without multiarch support, contains two definitions for each of the __memmove_chk and __memset_chk symbols. /usr/lib/gcc/i686-pc-linux-gnu/14/../../../../i686-pc-linux-gnu/bin/ld: /usr/lib/gcc/i686-pc-linux-gnu/14/../../../../lib/libc.a(memset-ia32.o): in function `__memset_chk': /var/tmp/portage/sys-libs/glibc-2.39-r3/work/glibc-2.39/string/../sysdeps/i386/i686/memset.S:32: multiple definition of `__memset_chk'; /usr/lib/gcc/i686-pc-linux-gnu/14/../../../../lib/libc.a(memset_chk.o):/var/tmp/portage/sys-libs/glibc-2.39-r3/work/glibc-2.39/debug/../sysdeps/i386/i686/multiarch/memset_chk.c:24: first defined here After this change, regardless of PIC options, the static library, built for i686 with multiarch contains implementations of these functions respectively from debug/memmove_chk.c and debug/memset_chk.c, and without multiarch contains implementations of these functions respectively from sysdeps/i386/memmove_chk.S and sysdeps/i386/memset_chk.S. This ensures that memmove and memset won't pull in __chk_fail and the routines it calls. Reported-by: Sam James <sam@gentoo.org> Tested-by: Sam James <sam@gentoo.org> Fixes:c73c96a4a1("i686: Fix build with --disable-multiarch") Signed-off-by: Gabi Falk <gabifalk@gmx.com> Reviewed-by: H.J. Lu <hjl.tools@gmail.com> Reviewed-by: Dmitry V. Levin <ldv@altlinux.org>
81 lines
2.0 KiB
ArmAsm
81 lines
2.0 KiB
ArmAsm
/* memset/bzero -- set memory area to CH/0
|
|
Highly optimized version for ix86, x>=6.
|
|
Copyright (C) 1999-2024 Free Software Foundation, Inc.
|
|
This file is part of the GNU C Library.
|
|
|
|
The GNU C Library is free software; you can redistribute it and/or
|
|
modify it under the terms of the GNU Lesser General Public
|
|
License as published by the Free Software Foundation; either
|
|
version 2.1 of the License, or (at your option) any later version.
|
|
|
|
The GNU C Library is distributed in the hope that it will be useful,
|
|
but WITHOUT ANY WARRANTY; without even the implied warranty of
|
|
MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
|
|
Lesser General Public License for more details.
|
|
|
|
You should have received a copy of the GNU Lesser General Public
|
|
License along with the GNU C Library; if not, see
|
|
<https://www.gnu.org/licenses/>. */
|
|
|
|
#include <sysdep.h>
|
|
#include "asm-syntax.h"
|
|
|
|
#define PARMS 4+4 /* space for 1 saved reg */
|
|
#define RTN PARMS
|
|
#define DEST RTN
|
|
#define CHR DEST+4
|
|
#define LEN CHR+4
|
|
|
|
.text
|
|
#if defined SHARED && IS_IN (libc)
|
|
ENTRY_CHK (__memset_chk)
|
|
movl 12(%esp), %eax
|
|
cmpl %eax, 16(%esp)
|
|
jb HIDDEN_JUMPTARGET (__chk_fail)
|
|
END_CHK (__memset_chk)
|
|
libc_hidden_builtin_def (__memset_chk)
|
|
#endif
|
|
ENTRY (memset)
|
|
|
|
cld
|
|
pushl %edi
|
|
cfi_adjust_cfa_offset (4)
|
|
movl DEST(%esp), %edx
|
|
movl LEN(%esp), %ecx
|
|
movzbl CHR(%esp), %eax
|
|
jecxz 1f
|
|
movl %edx, %edi
|
|
cfi_rel_offset (edi, 0)
|
|
andl $3, %edx
|
|
jz 2f /* aligned */
|
|
jp 3f /* misaligned at 3, store just one byte below */
|
|
stosb /* misaligned at 1 or 2, store two bytes */
|
|
decl %ecx
|
|
jz 1f
|
|
3: stosb
|
|
decl %ecx
|
|
jz 1f
|
|
xorl $1, %edx
|
|
jnz 2f /* was misaligned at 2 or 3, now aligned */
|
|
stosb /* was misaligned at 1, store third byte */
|
|
decl %ecx
|
|
2: movl %ecx, %edx
|
|
shrl $2, %ecx
|
|
andl $3, %edx
|
|
imul $0x01010101, %eax
|
|
rep
|
|
stosl
|
|
movl %edx, %ecx
|
|
rep
|
|
stosb
|
|
|
|
1:
|
|
movl DEST(%esp), %eax /* start address of destination is result */
|
|
popl %edi
|
|
cfi_adjust_cfa_offset (-4)
|
|
cfi_restore (edi)
|
|
|
|
ret
|
|
END (memset)
|
|
libc_hidden_builtin_def (memset)
|