mirror of
https://sourceware.org/git/glibc.git
synced 2024-10-17 11:20:15 +00:00
ac16e90592
1998-03-06 11:35 Ulrich Drepper <drepper@cygnus.com> * posix/wordexp-test.c: Change testsuite so that it can run even for ~root != /root. 1998-03-06 Andreas Jaeger <aj@arthur.rhein-neckar.de> * math/libm-test.c (catanh_test): Change epsilon for gcc 2.8.1. 1998-03-05 Andreas Schwab <schwab@issan.informatik.uni-dortmund.de> * sysdeps/unix/sysv/linux/i386/sysdep.h (SYSCALL_ERROR_HANDLER): Don't store into global errno if we already store through __errno_location. * sysdeps/unix/i386/sysdep.S: Likewise. * sysdeps/unix/alpha/sysdep.S: Likewise. * sysdeps/unix/sysv/linux/sparc/sparc64/brk.S: Likewise. * sysdeps/unix/sysv/linux/sparc/sparc64/clone.S: Likewise. * sysdeps/unix/sysv/linux/sparc/sparc64/sysdep.h: Likewise. Add missing return to SYSCALL_ERROR_HANDLER for (!_LIBC_REENTRANT && PIC). 1998-03-05 Andreas Schwab <schwab@issan.informatik.uni-dortmund.de> * sysdeps/generic/sysdep.h (L): Remove definition. * sysdeps/i386/sysdep.h (L): Define it here instead. 1998-03-05 Thorsten Kukuk <kukuk@vt.uni-paderborn.de> * nss/getXXbyYY_r.c: Check __nss_not_use_nscd_* variable for running nscd. * nscd/nscd_getgr_r.c: Set __nss_not_use_nscd_group variable. * nscd/nscd_getpw_r.c: Set __nss_not_use_nscd_passwd variable. * nscd/nscd_proto.h: Declare __nss_not_use_nscd_* variables.
100 lines
2.3 KiB
ArmAsm
100 lines
2.3 KiB
ArmAsm
/* Copyright (C) 1997 Free Software Foundation, Inc.
|
|
This file is part of the GNU C Library.
|
|
Contributed by Richard Henderson <richard@gnu.ai.mit.edu>, 1997.
|
|
|
|
The GNU C Library is free software; you can redistribute it and/or
|
|
modify it under the terms of the GNU Library General Public License as
|
|
published by the Free Software Foundation; either version 2 of the
|
|
License, or (at your option) any later version.
|
|
|
|
The GNU C Library is distributed in the hope that it will be useful,
|
|
but WITHOUT ANY WARRANTY; without even the implied warranty of
|
|
MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
|
|
Library General Public License for more details.
|
|
|
|
You should have received a copy of the GNU Library General Public
|
|
License along with the GNU C Library; see the file COPYING.LIB. If not,
|
|
write to the Free Software Foundation, Inc., 59 Temple Place - Suite 330,
|
|
Boston, MA 02111-1307, USA. */
|
|
|
|
/* __brk is a special syscall under Linux since it never returns an
|
|
error. Instead, the error condition is indicated by returning the old
|
|
break value (instead of the new, requested one). */
|
|
|
|
#include <sysdep.h>
|
|
#define _ERRNO_H
|
|
#include <bits/errno.h>
|
|
|
|
#ifdef PIC
|
|
.section .bss
|
|
.align 8
|
|
.globl __curbrk
|
|
__curbrk: .skip 8
|
|
.type __curbrk,@object
|
|
.size __curbrk,8
|
|
#else
|
|
.common __curbrk, 8, 8
|
|
#endif
|
|
|
|
.text
|
|
ENTRY(__brk)
|
|
save %sp, -160, %sp
|
|
#ifdef PIC
|
|
1: call 2f
|
|
sethi %hi(_GLOBAL_OFFSET_TABLE_-(1b-.)), %l7
|
|
2: or %l7, %lo(_GLOBAL_OFFSET_TABLE_-(1b-.)), %l7
|
|
add %l7, %o7, %l7
|
|
#endif
|
|
|
|
LOADSYSCALL(brk)
|
|
mov %i0, %o0
|
|
|
|
ta 0x11
|
|
|
|
/* All the ways we can fail... */
|
|
bcs,pn %xcc, .Lerr1
|
|
nop
|
|
brz %i0, .Lok
|
|
subcc %i0, %o0, %g0
|
|
bne,pn %xcc, .Lerr0
|
|
|
|
/* Update __curbrk and return cleanly. */
|
|
.Lok: sethi %hi(__curbrk), %g1
|
|
or %g1, %lo(__curbrk), %g1
|
|
#ifdef PIC
|
|
ldx [%l7+%g1], %g1
|
|
stx %o0, [%g1]
|
|
#else
|
|
stx %o0, [%g4+%g1]
|
|
#endif
|
|
mov %g0, %i0
|
|
|
|
/* Don't use "ret" cause the preprocessor will eat it. */
|
|
jmpl %i7+8, %g0
|
|
restore
|
|
|
|
/* What a horrible way to die. */
|
|
.Lerr0: set ENOMEM, %o0
|
|
.Lerr1:
|
|
#ifndef _LIBC_REENTRANT
|
|
sethi %hi(errno), %g1
|
|
or %g1, %lo(errno), %g1
|
|
#ifdef PIC
|
|
ldx [%l7+%g1], %g1
|
|
st %o0, [%g1]
|
|
#else
|
|
st %o0, [%g4+%g1]
|
|
#endif
|
|
#else
|
|
call __errno_location
|
|
mov %o0,%l1
|
|
st %l1, [%o0]
|
|
#endif
|
|
sub %g0, 1, %i0
|
|
jmpl %i7+8, %g0
|
|
restore
|
|
|
|
.size __brk, .-__brk
|
|
|
|
weak_alias (__brk, brk)
|