mirror of
https://sourceware.org/git/glibc.git
synced 2024-12-04 10:50:07 +00:00
174 lines
3.6 KiB
ArmAsm
174 lines
3.6 KiB
ArmAsm
/* Copyright (C) 2002, 2003 Free Software Foundation, Inc.
|
|
This file is part of the GNU C Library.
|
|
Contributed by Ulrich Drepper <drepper@redhat.com>, 2002.
|
|
|
|
The GNU C Library is free software; you can redistribute it and/or
|
|
modify it under the terms of the GNU Lesser General Public
|
|
License as published by the Free Software Foundation; either
|
|
version 2.1 of the License, or (at your option) any later version.
|
|
|
|
The GNU C Library is distributed in the hope that it will be useful,
|
|
but WITHOUT ANY WARRANTY; without even the implied warranty of
|
|
MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
|
|
Lesser General Public License for more details.
|
|
|
|
You should have received a copy of the GNU Lesser General Public
|
|
License along with the GNU C Library; if not, write to the Free
|
|
Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
|
|
02111-1307 USA. */
|
|
|
|
#include <sysdep.h>
|
|
#include <pthread-errnos.h>
|
|
|
|
.text
|
|
|
|
#ifndef LOCK
|
|
# ifdef UP
|
|
# define LOCK
|
|
# else
|
|
# define LOCK lock
|
|
# endif
|
|
#endif
|
|
|
|
#define SYS_futex 202
|
|
#define FUTEX_WAIT 0
|
|
#define FUTEX_WAKE 1
|
|
|
|
/* For the calculation see asm/vsyscall.h. */
|
|
#define VSYSCALL_ADDR_vgettimeofday 0xffffffffff600000
|
|
|
|
|
|
.globl __lll_mutex_lock_wait
|
|
.type __lll_mutex_lock_wait,@function
|
|
.hidden __lll_mutex_lock_wait
|
|
.align 16
|
|
__lll_mutex_lock_wait:
|
|
pushq %r10
|
|
pushq %rdx
|
|
|
|
xorq %r10, %r10 /* No timeout. */
|
|
|
|
1:
|
|
leaq 1(%rsi), %rdx /* account for the preceeded xadd. */
|
|
movq %r10, %rsi /* movq $FUTEX_WAIT, %rsi */
|
|
movq $SYS_futex, %rax
|
|
syscall
|
|
|
|
movl $1, %esi
|
|
LOCK
|
|
xaddl %esi, (%rdi)
|
|
testl %esi, %esi
|
|
jne 1b
|
|
|
|
movl $2, (%rdi)
|
|
|
|
popq %rdx
|
|
popq %r10
|
|
retq
|
|
.size __lll_mutex_lock_wait,.-__lll_mutex_lock_wait
|
|
|
|
|
|
#ifdef NOT_IN_libc
|
|
.globl __lll_mutex_timedlock_wait
|
|
.type __lll_mutex_timedlock_wait,@function
|
|
.hidden __lll_mutex_timedlock_wait
|
|
.align 16
|
|
__lll_mutex_timedlock_wait:
|
|
/* Check for a valid timeout value. */
|
|
cmpq $1000000000, 8(%rdx)
|
|
jae 3f
|
|
|
|
pushq %r12
|
|
pushq %r13
|
|
pushq %r14
|
|
|
|
/* Stack frame for the timespec and timeval structs. */
|
|
subq $16, %rsp
|
|
|
|
movq %rdi, %r12
|
|
movq %rdx, %r13
|
|
|
|
1: leaq 1(%rax), %r14
|
|
|
|
/* Get current time. */
|
|
movq %rsp, %rdi
|
|
xorq %rsi, %rsi
|
|
movq $VSYSCALL_ADDR_vgettimeofday, %rax
|
|
/* This is a regular function call, all calleer-save registers
|
|
might be clobbered. */
|
|
callq *%rax
|
|
|
|
/* Compute relative timeout. */
|
|
movq 8(%rsp), %rax
|
|
movq $1000, %rdi
|
|
mul %rdi /* Milli seconds to nano seconds. */
|
|
movq (%r13), %rdi
|
|
movq 8(%r13), %rsi
|
|
subq (%rsp), %rdi
|
|
subq %rax, %rsi
|
|
jns 4f
|
|
addq $1000000000, %rsi
|
|
decq %rdi
|
|
4: testq %rdi, %rdi
|
|
js 5f /* Time is already up. */
|
|
|
|
/* Futex call. */
|
|
movq %rdi, (%rsp) /* Store relative timeout. */
|
|
movq %rsi, 8(%rsp)
|
|
|
|
movl %r14d, %edx
|
|
movq %rsp, %r10
|
|
xorq %rsi, %rsi /* movq $FUTEX_WAIT, %rsi */
|
|
movq %r12, %rdi
|
|
movq $SYS_futex, %rax
|
|
syscall
|
|
movq %rax, %rcx
|
|
|
|
movl $1, %eax
|
|
LOCK
|
|
xaddl %eax, (%rdi)
|
|
testl %eax, %eax
|
|
jne 7f
|
|
|
|
movl $2, (%rdi)
|
|
xorl %eax, %eax
|
|
|
|
8: addq $16, %rsp
|
|
popq %r14
|
|
popq %r13
|
|
popq %r12
|
|
retq
|
|
|
|
/* Check whether the time expired. */
|
|
7: cmpq $-ETIMEDOUT, %rcx
|
|
je 5f
|
|
jmp 1b
|
|
|
|
3: movl $EINVAL, %eax
|
|
retq
|
|
|
|
5: movl $ETIMEDOUT, %eax
|
|
jmp 8b
|
|
.size __lll_mutex_timedlock_wait,.-__lll_mutex_timedlock_wait
|
|
#endif
|
|
|
|
|
|
.globl __lll_mutex_unlock_wake
|
|
.type __lll_mutex_unlock_wake,@function
|
|
.hidden __lll_mutex_unlock_wake
|
|
.align 16
|
|
__lll_mutex_unlock_wake:
|
|
pushq %rsi
|
|
pushq %rdx
|
|
|
|
movl $0, (%rdi)
|
|
movq $FUTEX_WAKE, %rsi
|
|
movl $1, %edx /* Wake one thread. */
|
|
movq $SYS_futex, %rax
|
|
syscall
|
|
|
|
popq %rdx
|
|
popq %rsi
|
|
retq
|
|
.size __lll_mutex_unlock_wake,.-__lll_mutex_unlock_wake
|