mirror of
https://sourceware.org/git/glibc.git
synced 2024-12-25 20:21:07 +00:00
0cb313f7cb
As discussed in libc-alpha [1] current clone with CLONE_VM (without
CLONE_THREAD set) will reset the pthread pid/tid fields to -1. The
issue is since memory is shared between the parent and child it will
clobber parent's cached pid/tid leading to internal inconsistencies
if the value is not restored.
And even it is restored it may lead to racy conditions when between
set/restore a thread might invoke pthread function that validate the
pthread with INVALID_TD_P/INVALID_NOT_TERMINATED_TD_P and thus get
wrong results.
As stated in BZ19957, previously reports of this behaviour was close
with EWONTFIX due the fact usage of clone outside glibc is tricky
since glibc requires consistent internal pthread, while using clone
directly may not provide it. However since now posix_spawn uses
clone (CLONE_VM) to fixes various issues related to previous vfork
usage this issue requires fixing.
The vfork implementation also does something similar, but instead
it negates and restores only the *pid* field and functions that
might access its value know to handle such case (getpid, raise
and pthread ones that uses INVALID_TD_P/INVALID_NOT_TERMINATED_TD_P
macros that check only *tid* field). Also vfork does not call
__clone directly, instead calling either __NR_vfork or __NR_clone
directly.
So this patch removes this clone behavior by avoiding setting
the pthread pid/tid field for CLONE_VM. There is no need to
check for CLONE_THREAD, since the minimum supported kernel in all
architecture implies that CLONE_VM must be used with CLONE_THREAD,
otherwise clone returns EINVAL.
Instead of current approach of:
int clone(int (*fn)(void *), void *child_stack, int flags, ...)
[...]
if (flags & CLONE_THREAD)
goto do_syscall;
pid_t new_value;
if (flags & CLONE_VM)
new_value = -1;
else
new_value = getpid ();
THREAD_SETMEM (THREAD_SELF, pid, new_value);
THREAD_SETMEM (THREAD_SELF, tid, new_value);
do_syscall:
[...]
The new approach uses:
int clone(int (*fn)(void *), void *child_stack, int flags, ...)
[...]
if (flags & CLONE_VM)
goto do_syscall;
pid_t new_value = getpid ();
THREAD_SETMEM (THREAD_SELF, pid, new_value);
THREAD_SETMEM (THREAD_SELF, tid, new_value);
do_syscall:
[...]
It also removes the linux tst-getpid2.c test which expects the previous
behavior and instead add another clone test.
Tested on x86_64, i686, x32, powerpc64le, aarch64, armhf, s390, and
s390x. I also did limited check on mips32 and sparc64 (using the new
added test).
I also got reviews from both m68k, hppa, and tile. So I presume for
these architecture the patch works.
The fixes for alpha, microblaze, sh, ia64, and nio2 have not been
tested.
[1] https://sourceware.org/ml/libc-alpha/2016-04/msg00307.html
* sysdeps/unix/sysv/linux/Makefile [$(subdir) == nptl] (test): Remove
tst-getpid2.
(test): Add tst-clone2.
* sysdeps/unix/sysv/linux/tst-clone2.c: New file.
* sysdeps/unix/sysv/linux/aarch64/clone.S (__clone): Do not change
pid/tid fields for CLONE_VM.
* sysdeps/unix/sysv/linux/arm/clone.S: Likewise.
* sysdeps/unix/sysv/linux/i386/clone.S: Likewise.
* sysdeps/unix/sysv/linux/mips/clone.S: Likewise.
* sysdeps/unix/sysv/linux/powerpc/powerpc32/clone.S: Likewise.
* sysdeps/unix/sysv/linux/powerpc/powerpc64/clone.S: Likewise.
* sysdeps/unix/sysv/linux/s390/s390-32/clone.S: Likewise.
* sysdeps/unix/sysv/linux/s390/s390-64/clone.S: Likewise.
* sysdeps/unix/sysv/linux/sparc/sparc32/clone.S: Likewise.
* sysdeps/unix/sysv/linux/sparc/sparc64/clone.S: Likewise.
* sysdeps/unix/sysv/linux/x86_64/clone.S: Likewise.
* sysdeps/unix/sysv/linux/tst-getpid2.c: Remove file.
137 lines
3.2 KiB
ArmAsm
137 lines
3.2 KiB
ArmAsm
/* Copyright (C) 1996-2016 Free Software Foundation, Inc.
|
|
This file is part of the GNU C Library.
|
|
Contributed by Richard Henderson <rth@tamu.edu>, 1996.
|
|
|
|
The GNU C Library is free software; you can redistribute it and/or
|
|
modify it under the terms of the GNU Lesser General Public
|
|
License as published by the Free Software Foundation; either
|
|
version 2.1 of the License, or (at your option) any later version.
|
|
|
|
The GNU C Library is distributed in the hope that it will be useful,
|
|
but WITHOUT ANY WARRANTY; without even the implied warranty of
|
|
MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
|
|
Lesser General Public License for more details.
|
|
|
|
You should have received a copy of the GNU Lesser General Public
|
|
License along with the GNU C Library. If not, see
|
|
<http://www.gnu.org/licenses/>. */
|
|
|
|
/* clone() is even more special than fork() as it mucks with stacks
|
|
and invokes a function in the right context after its all over. */
|
|
|
|
#include <sysdep.h>
|
|
#define _ERRNO_H 1
|
|
#include <bits/errno.h>
|
|
|
|
#define CLONE_VM 0x00000100
|
|
|
|
/* int clone(int (*fn)(void *arg), void *child_stack, int flags,
|
|
void *arg, pid_t *ptid, void *tls, pid_t *ctid);
|
|
|
|
Note that everything past ARG is technically optional, based
|
|
on FLAGS, and that CTID is arg 7, and thus is on the stack.
|
|
However, since a load from top-of-stack better be legal always,
|
|
we don't bother checking FLAGS. */
|
|
|
|
.text
|
|
.align 4
|
|
.globl __clone
|
|
.ent __clone
|
|
.usepv __clone, USEPV_PROF
|
|
|
|
cfi_startproc
|
|
__clone:
|
|
#ifdef PROF
|
|
ldgp gp,0(pv)
|
|
lda AT, _mcount
|
|
jsr AT, (AT), _mcount
|
|
#endif
|
|
|
|
/* Sanity check arguments. */
|
|
ldiq v0, EINVAL
|
|
beq a0, SYSCALL_ERROR_LABEL /* no NULL function pointers */
|
|
beq a1, SYSCALL_ERROR_LABEL /* no NULL stack pointers */
|
|
|
|
/* Save the fn ptr and arg on the new stack. */
|
|
subq a1, 32, a1
|
|
stq a0, 0(a1)
|
|
stq a3, 8(a1)
|
|
stq a2, 16(a1)
|
|
|
|
/* The syscall is of the form clone(flags, usp, ptid, ctid, tls).
|
|
Shift the flags, ptid, ctid, tls arguments into place; the
|
|
child_stack argument is already correct. */
|
|
mov a2, a0
|
|
mov a4, a2
|
|
ldq a3, 0(sp)
|
|
mov a5, a4
|
|
|
|
/* Do the system call. */
|
|
ldiq v0, __NR_clone
|
|
call_pal PAL_callsys
|
|
|
|
bne a3, SYSCALL_ERROR_LABEL
|
|
beq v0, thread_start
|
|
|
|
/* Successful return from the parent. */
|
|
ret
|
|
|
|
PSEUDO_END(__clone)
|
|
cfi_endproc
|
|
|
|
/* Load up the arguments to the function. Put this block of code in
|
|
its own function so that we can terminate the stack trace with our
|
|
debug info. */
|
|
|
|
.align 4
|
|
.ent thread_start
|
|
cfi_startproc
|
|
thread_start:
|
|
mov 0, fp
|
|
cfi_def_cfa_register(fp)
|
|
cfi_undefined(ra)
|
|
|
|
/* Check and see if we need to reset the PID. */
|
|
ldq t0, 16(sp)
|
|
lda t1, CLONE_VM
|
|
and t0, t1, t2
|
|
beq t2, 2f
|
|
1:
|
|
|
|
/* Load up the arguments. */
|
|
ldq pv, 0(sp)
|
|
ldq a0, 8(sp)
|
|
addq sp, 32, sp
|
|
|
|
/* Call the user's function. */
|
|
jsr ra, (pv)
|
|
ldgp gp, 0(ra)
|
|
|
|
/* Call _exit rather than doing it inline for breakpoint purposes. */
|
|
mov v0, a0
|
|
#ifdef PIC
|
|
bsr ra, HIDDEN_JUMPTARGET(_exit) !samegp
|
|
#else
|
|
jsr ra, HIDDEN_JUMPTARGET(_exit)
|
|
#endif
|
|
|
|
/* Die horribly. */
|
|
.align 4
|
|
halt
|
|
|
|
.align 4
|
|
2:
|
|
rduniq
|
|
mov v0, s0
|
|
lda v0, __NR_getxpid
|
|
callsys
|
|
3:
|
|
stl v0, PID_OFFSET(s0)
|
|
stl v0, TID_OFFSET(s0)
|
|
br 1b
|
|
cfi_endproc
|
|
.end thread_start
|
|
|
|
libc_hidden_def (__clone)
|
|
weak_alias (__clone, clone)
|