mirror of
https://sourceware.org/git/glibc.git
synced 2024-12-14 07:10:05 +00:00
035c012e32
It turns out the startup code in csu/elf-init.c has a perfect pair of ROP gadgets (see Marco-Gisbert and Ripoll-Ripoll, "return-to-csu: A New Method to Bypass 64-bit Linux ASLR"). These functions are not needed in dynamically-linked binaries because DT_INIT/DT_INIT_ARRAY are already processed by the dynamic linker. However, the dynamic linker skipped the main program for some reason. For maximum backwards compatibility, this is not changed, and instead, the main map is consulted from __libc_start_main if the init function argument is a NULL pointer. For statically linked binaries, the old approach based on linker symbols is still used because there is nothing else available. A new symbol version __libc_start_main@@GLIBC_2.34 is introduced because new binaries running on an old libc would not run their ELF constructors, leading to difficult-to-debug issues.
116 lines
3.8 KiB
ArmAsm
116 lines
3.8 KiB
ArmAsm
/* Startup code compliant to the ELF m68k ABI.
|
|
Copyright (C) 1996-2021 Free Software Foundation, Inc.
|
|
This file is part of the GNU C Library.
|
|
|
|
The GNU C Library is free software; you can redistribute it and/or
|
|
modify it under the terms of the GNU Lesser General Public
|
|
License as published by the Free Software Foundation; either
|
|
version 2.1 of the License, or (at your option) any later version.
|
|
|
|
In addition to the permissions in the GNU Lesser General Public
|
|
License, the Free Software Foundation gives you unlimited
|
|
permission to link the compiled version of this file with other
|
|
programs, and to distribute those programs without any restriction
|
|
coming from the use of this file. (The GNU Lesser General Public
|
|
License restrictions do apply in other respects; for example, they
|
|
cover modification of the file, and distribution when not linked
|
|
into another program.)
|
|
|
|
Note that people who make modified versions of this file are not
|
|
obligated to grant this special exception for their modified
|
|
versions; it is their choice whether to do so. The GNU Lesser
|
|
General Public License gives permission to release a modified
|
|
version without this exception; this exception also makes it
|
|
possible to release a modified version which carries forward this
|
|
exception.
|
|
|
|
The GNU C Library is distributed in the hope that it will be useful,
|
|
but WITHOUT ANY WARRANTY; without even the implied warranty of
|
|
MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
|
|
Lesser General Public License for more details.
|
|
|
|
You should have received a copy of the GNU Lesser General Public
|
|
License along with the GNU C Library. If not, see
|
|
<https://www.gnu.org/licenses/>. */
|
|
|
|
/* This is the canonical entry point, usually the first thing in the text
|
|
segment. The SVR4/m68k ABI says that when the entry point runs,
|
|
most registers' values are unspecified, except for:
|
|
|
|
%a1 Contains a function pointer to be registered with `atexit'.
|
|
This is how the dynamic linker arranges to have DT_FINI
|
|
functions called for shared libraries that have been loaded
|
|
before this code runs.
|
|
|
|
%sp The stack contains the arguments and environment:
|
|
0(%sp) argc
|
|
4(%sp) argv[0]
|
|
...
|
|
(4*argc)(%sp) NULL
|
|
(4*(argc+1))(%sp) envp[0]
|
|
...
|
|
NULL
|
|
*/
|
|
|
|
#include <sysdep.h>
|
|
|
|
.text
|
|
.globl _start
|
|
.type _start,@function
|
|
_start:
|
|
/* Clear the frame pointer. The ABI suggests this be done, to mark
|
|
the outermost frame obviously. */
|
|
sub.l %fp, %fp
|
|
|
|
/* Extract the arguments as encoded on the stack and set up the
|
|
arguments for `main': argc, argv. envp will be determined
|
|
later in __libc_start_main. */
|
|
move.l (%sp)+, %d0 /* Pop the argument count. */
|
|
move.l %sp, %a0 /* The argument vector starts just at the
|
|
current stack top. */
|
|
|
|
/* Provide the highest stack address to the user code (for stacks
|
|
which grow downward). */
|
|
pea (%sp)
|
|
|
|
pea (%a1) /* Push address of the shared library
|
|
termination function. */
|
|
|
|
/* These used to be addresses of the .fini and .init entry points. */
|
|
clr.l -(%sp)
|
|
clr.l -(%sp)
|
|
|
|
#ifdef PIC
|
|
/* Load PIC register. */
|
|
LOAD_GOT (%a5)
|
|
|
|
pea (%a0) /* Push second argument: argv. */
|
|
move.l %d0, -(%sp) /* Push first argument: argc. */
|
|
|
|
move.l main@GOT(%a5), -(%sp)
|
|
|
|
/* Call the user's main function, and exit with its value. But
|
|
let the libc call main. */
|
|
jbsr __libc_start_main@PLTPC
|
|
#else
|
|
|
|
pea (%a0) /* Push second argument: argv. */
|
|
move.l %d0, -(%sp) /* Push first argument: argc. */
|
|
|
|
pea main
|
|
|
|
/* Call the user's main function, and exit with its value. But
|
|
let the libc call main. */
|
|
jbsr __libc_start_main
|
|
#endif
|
|
|
|
illegal /* Crash if somehow `exit' does return. */
|
|
|
|
/* Define a symbol for the first piece of initialized data. */
|
|
.data
|
|
.globl __data_start
|
|
__data_start:
|
|
.long 0
|
|
.weak data_start
|
|
data_start = __data_start
|