mirror of
https://sourceware.org/git/glibc.git
synced 2024-11-19 11:30:06 +00:00
104d0bd3ef
2000-12-08 Jakub Jelinek <jakub@redhat.com> * elf/dl-load.c (fillin_rpath): Don't assume there is '\0' at cp + len. Compute where from dirname. Reported by <jreiser@BitWagon.com>. 2000-12-08 Richard Henderson <rth@twiddle.net> * sysdeps/alpha/_mcount.S: Fix typo. * sysdeps/alpha/strncpy.S: Likewise. * sysdeps/alpha/alphaev6/Implies: New file. * sysdeps/alpha/alphaev67/Implies: New file. * sysdeps/alpha/alphaev67/ffs.S: New file. * sysdeps/alpha/alphaev67/ffsll.S: New file. * sysdeps/alpha/alphaev67/rawmemchr.S: New file. * sysdeps/alpha/alphaev67/stpcpy.S: New file. * sysdeps/alpha/alphaev67/stpncpy.S: New file. * sysdeps/alpha/rawmemchr.S: New file. * sysdeps/alpha/strcat.S: Tail call to __stxcpy. * sysdeps/alpha/strcpy.S: Likewise. From GMP 3.1.1: * sysdeps/alpha/alphaev6/addmul_1.s: New file. From rick.gorton@alpha-processor.com: * sysdeps/alpha/alphaev6/memchr.S: New file. * sysdeps/alpha/alphaev6/memcpy.S: New file. * sysdeps/alpha/alphaev6/memset.S: New file. * sysdeps/alpha/alphaev6/stxcpy.S: New file. * sysdeps/alpha/alphaev6/stxncpy.S: New file. * sysdeps/alpha/alphaev67/strcat.S: New file. * sysdeps/alpha/alphaev67/strchr.S: New file. * sysdeps/alpha/alphaev67/strlen.S: New file. * sysdeps/alpha/alphaev67/strncat.S: New file. * sysdeps/alpha/htonl.S: Use a shorter sequence. 2000-12-08 Jakub Jelinek <jakub@redhat.com> * inet/getnameinfo.c (getnameinfo): Fix NI_NOFQDN support. Reported by <pspencer@fields.utoronto.ca>. 2000-12-07 Jes Sorensen <jes@linuxcare.com> * sysdeps/ia64/elf/start.S (__data_start): Add __data_start variable. Pointed out by Hans Boehm. 2000-12-07 H.J. Lu <hjl@gnu.org> * elf/dl-version.c (match_symbol): Check map->l_name[0] for printing. 2000-12-07 Andreas Jaeger <aj@suse.de> * misc/error.c: Add format attributes for __error and __error_at_line. * nscd/dbg_log.h: Add format attribute. 2000-12-08 Ulrich Drepper <drepper@redhat.com> * misc/sys/syslog.h: Add format attributes to syslog and vsyslog. Patch by Joseph S. Myers <jsm28@cam.ac.uk>. * sysdeps/generic/dl-cache.c (HWCAP_CHECK): Fix access to _dl_hwcap. * manual/install.texi: Recommend to set LANGUAGE=C LC_ALL=C during
88 lines
2.4 KiB
ArmAsm
88 lines
2.4 KiB
ArmAsm
/* Copyright (C) 1996, 1997 Free Software Foundation, Inc.
|
|
Contributed by Richard Henderson (rth@tamu.edu)
|
|
This file is part of the GNU C Library.
|
|
|
|
The GNU C Library is free software; you can redistribute it and/or
|
|
modify it under the terms of the GNU Library General Public License as
|
|
published by the Free Software Foundation; either version 2 of the
|
|
License, or (at your option) any later version.
|
|
|
|
The GNU C Library is distributed in the hope that it will be useful,
|
|
but WITHOUT ANY WARRANTY; without even the implied warranty of
|
|
MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
|
|
Library General Public License for more details.
|
|
|
|
You should have received a copy of the GNU Library General Public
|
|
License along with the GNU C Library; see the file COPYING.LIB. If not,
|
|
write to the Free Software Foundation, Inc., 59 Temple Place - Suite 330,
|
|
Boston, MA 02111-1307, USA. */
|
|
|
|
/* Copy no more than COUNT bytes of the null-terminated string from
|
|
SRC to DST. If SRC does not cover all of COUNT, the balance is
|
|
zeroed. */
|
|
|
|
#include <sysdep.h>
|
|
|
|
.set noat
|
|
.set noreorder
|
|
|
|
.text
|
|
|
|
ENTRY(strncpy)
|
|
ldgp gp, 0(pv)
|
|
#ifdef PROF
|
|
lda AT, _mcount
|
|
jsr AT, (AT), _mcount
|
|
#endif
|
|
.prologue 1
|
|
|
|
mov a0, v0 # set return value now
|
|
beq a2, $zerocount
|
|
jsr t9, __stxncpy # do the work of the copy
|
|
|
|
bne a2, $multiword # do we have full words left?
|
|
|
|
.align 3
|
|
subq t8, 1, t2 # e0 : guess not
|
|
subq t10, 1, t3 # .. e1 :
|
|
or t2, t8, t2 # e0 : clear the bits between the last
|
|
or t3, t10, t3 # .. e1 : written byte and the last byte in
|
|
andnot t3, t2, t3 # e0 : COUNT
|
|
zap t0, t3, t0 # e1 :
|
|
stq_u t0, 0(a0) # e0 :
|
|
ret # .. e1 :
|
|
|
|
$multiword:
|
|
subq t8, 1, t7 # e0 : clear the final bits in the prev
|
|
or t7, t8, t7 # e1 : word
|
|
zapnot t0, t7, t0 # e0 :
|
|
subq a2, 1, a2 # .. e1 :
|
|
stq_u t0, 0(a0) # e0 :
|
|
addq a0, 8, a0 # .. e1 :
|
|
|
|
beq a2, 1f # e1 :
|
|
blbc a2, 0f # e1 :
|
|
|
|
stq_u zero, 0(a0) # e0 : zero one word
|
|
subq a2, 1, a2 # .. e1 :
|
|
addq a0, 8, a0 # e0 :
|
|
beq a2, 1f # .. e1 :
|
|
|
|
0: stq_u zero, 0(a0) # e0 : zero two words
|
|
subq a2, 2, a2 # .. e1 :
|
|
stq_u zero, 8(a0) # e0 :
|
|
addq a0, 16, a0 # .. e1 :
|
|
bne a2, 0b # e1 :
|
|
unop
|
|
|
|
1: ldq_u t0, 0(a0) # e0 : clear the leading bits in the final
|
|
subq t10, 1, t7 # .. e1 : word
|
|
or t7, t10, t7 # e0 :
|
|
zap t0, t7, t0 # e1 (stall)
|
|
stq_u t0, 0(a0) # e0 :
|
|
|
|
$zerocount:
|
|
ret # .. e1 :
|
|
|
|
END(strncpy)
|