mirror of
https://sourceware.org/git/glibc.git
synced 2024-11-18 19:10:06 +00:00
b38de2c8da
* sysdeps/unix/sysv/linux/x86_64/clone.S (thread_start): Use HIDDEN_JUMPTARGET for _exit. * sysdeps/unix/sysv/linux/m68k/clone.S (thread_start): Likewise. * sysdeps/unix/sysv/linux/i386/clone.S (thread_start): Likewise. * sysdeps/unix/sysv/linux/powerpc/clone.S: Likewise. * sysdeps/unix/_exit.S (_exit): Add libc_hidden_def.
87 lines
2.4 KiB
ArmAsm
87 lines
2.4 KiB
ArmAsm
/* Copyright (C) 2001,02 Free Software Foundation, Inc.
|
|
This file is part of the GNU C Library.
|
|
|
|
The GNU C Library is free software; you can redistribute it and/or
|
|
modify it under the terms of the GNU Lesser General Public
|
|
License as published by the Free Software Foundation; either
|
|
version 2.1 of the License, or (at your option) any later version.
|
|
|
|
The GNU C Library is distributed in the hope that it will be useful,
|
|
but WITHOUT ANY WARRANTY; without even the implied warranty of
|
|
MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
|
|
Lesser General Public License for more details.
|
|
|
|
You should have received a copy of the GNU Lesser General Public
|
|
License along with the GNU C Library; if not, write to the Free
|
|
Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
|
|
02111-1307 USA. */
|
|
|
|
/* clone() is even more special than fork() as it mucks with stacks
|
|
and invokes a function in the right context after its all over. */
|
|
|
|
#include <sysdep.h>
|
|
#define _ERRNO_H 1
|
|
#include <bits/errno.h>
|
|
#include <asm-syntax.h>
|
|
#include <bp-sym.h>
|
|
#include <bp-asm.h>
|
|
|
|
/* The userland implementation is:
|
|
int clone (int (*fn)(void *arg), void *child_stack, int flags, void *arg),
|
|
the kernel entry is:
|
|
int clone (long flags, void *child_stack).
|
|
|
|
The parameters are passed in register from userland:
|
|
rdi: fn
|
|
rsi: child_stack
|
|
rdx: flags
|
|
rcx: arg
|
|
|
|
The kernel expects:
|
|
rax: system call number
|
|
rdi: flags
|
|
rsi: child_stack */
|
|
|
|
|
|
.text
|
|
ENTRY (BP_SYM (__clone))
|
|
/* Sanity check arguments. */
|
|
movq $-EINVAL,%rax
|
|
testq %rdi,%rdi /* no NULL function pointers */
|
|
jz SYSCALL_ERROR_LABEL
|
|
testq %rsi,%rsi /* no NULL stack pointers */
|
|
jz SYSCALL_ERROR_LABEL
|
|
|
|
/* Insert the argument onto the new stack. */
|
|
subq $16,%rsi
|
|
movq %rcx,8(%rsi)
|
|
|
|
/* Save the function pointer. It will be popped off in the
|
|
child in the ebx frobbing below. */
|
|
movq %rdi,0(%rsi)
|
|
|
|
/* Do the system call. */
|
|
movq %rdx, %rdi
|
|
movq $SYS_ify(clone),%rax
|
|
syscall
|
|
|
|
testq %rax,%rax
|
|
jl SYSCALL_ERROR_LABEL
|
|
jz thread_start
|
|
|
|
L(pseudo_end):
|
|
ret
|
|
|
|
thread_start:
|
|
/* Set up arguments for the function call. */
|
|
popq %rax /* Function to call. */
|
|
popq %rdi /* Argument. */
|
|
call *%rax
|
|
/* Call exit with return value from function call. */
|
|
movq %rax, %rdi
|
|
call HIDDEN_JUMPTARGET (_exit)
|
|
|
|
PSEUDO_END (BP_SYM (__clone))
|
|
|
|
weak_alias (BP_SYM (__clone), BP_SYM (clone))
|