mirror of
https://sourceware.org/git/glibc.git
synced 2024-11-23 13:30:06 +00:00
37825319ee
This patch refactors code in sysdeps/i386/fpu that forces underflow exceptions to use common macros for that purpose as far as possible. (Although some of the macros end up used in only one place, I think it's cleanest to define all these macros together so that all the code forcing underflow uses such macros. Some more uses of such macros will also be introduced when fixing remaining bugs about missing underflow exceptions, and it would be possible to do further refactoring of the macros in i386-math-asm.h to share more code by using other macros internally. Places that test for underflow by examining the representation of the argument with integer operations, rather that using floating-point comparisons on the argument or result, are unchanged by this patch.) Most of this code uses a macro MO to abstract away the differences between PIC and non-PIC memory references to constants. log1p functions, however, hardcoded PIC conditionals for this. Because the common macros rely on the use of MO, I changed the log1p functions to use the normal style here, and, for consistency, also made that change to log1pl which is otherwise unaffected by this patch. Tested for x86. * sysdeps/i386/fpu/i386-math-asm.h (DEFINE_LDBL_MIN): New macro. (FLT_CHECK_FORCE_UFLOW): Likewise. (DBL_CHECK_FORCE_UFLOW): Likewise. (FLT_CHECK_FORCE_UFLOW_NARROW): Likewise. (DBL_CHECK_FORCE_UFLOW_NARROW): Likewise. (LDBL_CHECK_FORCE_UFLOW_NONNEG_NAN): Likewise. (FLT_CHECK_FORCE_UFLOW_NONNAN): Likewise. (DBL_CHECK_FORCE_UFLOW_NONNAN): Likewise. (FLT_CHECK_FORCE_UFLOW_NONNEG): Likewise. (DBL_CHECK_FORCE_UFLOW_NONNEG): Likewise. (LDBL_CHECK_FORCE_UFLOW_NONNEG): Likewise. * sysdeps/i386/fpu/e_asin.S: Include <i386-math-asm.h>. (dbl_min): Replace with use of DEFINE_DBL_MIN. (__ieee754_asin): Use DBL_CHECK_FORCE_UFLOW. * sysdeps/i386/fpu/e_asinf.S: Include <i386-math-asm.h>. (flt_min): Replace with use of DEFINE_FLT_MIN. (__ieee754_asinf): Use FLT_CHECK_FORCE_UFLOW. * sysdeps/i386/fpu/e_atan2.S: Include <i386-math-asm.h>. (dbl_min): Replace with use of DEFINE_DBL_MIN. (__ieee754_atan2): Use DBL_CHECK_FORCE_UFLOW_NARROW. * sysdeps/i386/fpu/e_atan2f.S: Include <i386-math-asm.h>. (flt_min): Replace with use of DEFINE_FLT_MIN. (__ieee754_atan2f): Use FLT_CHECK_FORCE_UFLOW_NARROW. * sysdeps/i386/fpu/e_atanh.S: Include <i386-math-asm.h>. (dbl_min): Replace with use of DEFINE_DBL_MIN. (__ieee754_atanh): Use DBL_CHECK_FORCE_UFLOW_NONNEG. * sysdeps/i386/fpu/e_atanhf.S: Include <i386-math-asm.h>. (flt_min): Replace with use of DEFINE_FLT_MIN. (__ieee754_atanhf): Use FLT_CHECK_FORCE_UFLOW_NONNEG. * sysdeps/i386/fpu/e_exp2l.S: Include <i386-math-asm.h>. (ldbl_min): Replace with use of DEFINE_LDBL_MIN. (__ieee754_exp2l): Use LDBL_CHECK_FORCE_UFLOW_NONNEG_NAN. * sysdeps/i386/fpu/e_expl.S: Include <i386-math-asm.h>. [!USE_AS_EXPM1L] (cmin): Replace with use of DEFINE_LDBL_MIN. (IEEE754_EXPL): Use LDBL_CHECK_FORCE_UFLOW_NONNEG. * sysdeps/i386/fpu/s_atan.S: Include <i386-math-asm.h>. (dbl_min): Replace with use of DEFINE_DBL_MIN. (__atan): Use DBL_CHECK_FORCE_UFLOW. * sysdeps/i386/fpu/s_atanf.S: Include <i386-math-asm.h>. (flt_min): Replace with use of DEFINE_FLT_MIN. (__atanf): Use FLT_CHECK_FORCE_UFLOW. * sysdeps/i386/fpu/s_expm1.S: Include <i386-math-asm.h>. (dbl_min): Replace with use of DEFINE_DBL_MIN. (__expm1): Use DBL_CHECK_FORCE_UFLOW. Move underflow check after main computation. * sysdeps/i386/fpu/s_expm1f.S: Include <i386-math-asm.h>. (flt_min): Replace with use of DEFINE_FLT_MIN. (__expm1f): Use FLT_CHECK_FORCE_UFLOW. Move underflow check after main computation. * sysdeps/i386/fpu/s_log1p.S: Include <i386-math-asm.h>. (dbl_min): Replace with use of DEFINE_DBL_MIN. (MO): New macro. (__log1p): Use MO. Use DBL_CHECK_FORCE_UFLOW_NONNAN. * sysdeps/i386/fpu/s_log1pf.S: Include <i386-math-asm.h>. (flt_min): Replace with use of DEFINE_FLT_MIN. (MO): New macro. (__log1pf): Use MO. Use FLT_CHECK_FORCE_UFLOW_NONNAN. * sysdeps/i386/fpu/s_log1pl.S (MO): New macro. (__log1pl): Use MO.
110 lines
2.9 KiB
ArmAsm
110 lines
2.9 KiB
ArmAsm
/* ix87 specific implementation of arctanh function.
|
|
Copyright (C) 1996-2015 Free Software Foundation, Inc.
|
|
This file is part of the GNU C Library.
|
|
Contributed by Ulrich Drepper <drepper@cygnus.com>, 1996.
|
|
|
|
The GNU C Library is free software; you can redistribute it and/or
|
|
modify it under the terms of the GNU Lesser General Public
|
|
License as published by the Free Software Foundation; either
|
|
version 2.1 of the License, or (at your option) any later version.
|
|
|
|
The GNU C Library is distributed in the hope that it will be useful,
|
|
but WITHOUT ANY WARRANTY; without even the implied warranty of
|
|
MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
|
|
Lesser General Public License for more details.
|
|
|
|
You should have received a copy of the GNU Lesser General Public
|
|
License along with the GNU C Library; if not, see
|
|
<http://www.gnu.org/licenses/>. */
|
|
|
|
#include <machine/asm.h>
|
|
#include <i386-math-asm.h>
|
|
|
|
.section .rodata
|
|
|
|
.align ALIGNARG(4)
|
|
.type half,@object
|
|
half: .double 0.5
|
|
ASM_SIZE_DIRECTIVE(half)
|
|
.type one,@object
|
|
one: .double 1.0
|
|
ASM_SIZE_DIRECTIVE(one)
|
|
.type limit,@object
|
|
limit: .double 0.29
|
|
ASM_SIZE_DIRECTIVE(limit)
|
|
.align ALIGNARG(4)
|
|
.type ln2_2,@object
|
|
ln2_2: .tfloat 0.3465735902799726547086160
|
|
ASM_SIZE_DIRECTIVE(ln2_2)
|
|
|
|
DEFINE_FLT_MIN
|
|
|
|
#ifdef PIC
|
|
#define MO(op) op##@GOTOFF(%edx)
|
|
#else
|
|
#define MO(op) op
|
|
#endif
|
|
|
|
.text
|
|
ENTRY(__ieee754_atanhf)
|
|
movl 4(%esp), %ecx
|
|
|
|
movl %ecx, %eax
|
|
andl $0x7fffffff, %eax
|
|
cmpl $0x7f800000, %eax
|
|
ja 5f
|
|
|
|
#ifdef PIC
|
|
LOAD_PIC_REG (dx)
|
|
#endif
|
|
|
|
andl $0x80000000, %ecx // ECX == 0 iff X >= 0
|
|
|
|
fldt MO(ln2_2) // 0.5*ln2
|
|
xorl %ecx, 4(%esp)
|
|
flds 4(%esp) // |x| : 0.5*ln2
|
|
fcoml MO(half) // |x| : 0.5*ln2
|
|
fld %st(0) // |x| : |x| : 0.5*ln2
|
|
fnstsw // |x| : |x| : 0.5*ln2
|
|
sahf
|
|
jae 2f
|
|
fadd %st, %st(1) // |x| : 2*|x| : 0.5*ln2
|
|
fld %st // |x| : |x| : 2*|x| : 0.5*ln2
|
|
fsubrl MO(one) // 1-|x| : |x| : 2*|x| : 0.5*ln2
|
|
fxch // |x| : 1-|x| : 2*|x| : 0.5*ln2
|
|
fmul %st(2) // 2*|x|^2 : 1-|x| : 2*|x| : 0.5*ln2
|
|
fdivp // (2*|x|^2)/(1-|x|) : 2*|x| : 0.5*ln2
|
|
faddp // 2*|x|+(2*|x|^2)/(1-|x|) : 0.5*ln2
|
|
fcoml MO(limit) // 2*|x|+(2*|x|^2)/(1-|x|) : 0.5*ln2
|
|
fnstsw // 2*|x|+(2*|x|^2)/(1-|x|) : 0.5*ln2
|
|
sahf
|
|
jae 4f
|
|
fyl2xp1 // 0.5*ln2*ld(1+2*|x|+(2*|x|^2)/(1-|x|))
|
|
FLT_CHECK_FORCE_UFLOW_NONNEG
|
|
jecxz 3f
|
|
fchs // 0.5*ln2*ld(1+2*x+(2*x^2)/(1-x))
|
|
3: ret
|
|
|
|
.align ALIGNARG(4)
|
|
4: faddl MO(one) // 1+2*|x|+(2*|x|^2)/(1-|x|) : 0.5*ln2
|
|
fyl2x // 0.5*ln2*ld(1+2*|x|+(2*|x|^2)/(1-|x|))
|
|
jecxz 3f
|
|
fchs // 0.5*ln2*ld(1+2*x+(2*x^2)/(1-x))
|
|
3: ret
|
|
|
|
.align ALIGNARG(4)
|
|
2: faddl MO(one) // 1+|x| : |x| : 0.5*ln2
|
|
fxch // |x| : 1+|x| : 0.5*ln2
|
|
fsubrl MO(one) // 1-|x| : 1+|x| : 0.5*ln2
|
|
fdivrp // (1+|x|)/(1-|x|) : 0.5*ln2
|
|
fyl2x // 0.5*ln2*ld((1+|x|)/(1-|x|))
|
|
jecxz 3f
|
|
fchs // 0.5*ln2*ld((1+x)/(1-x))
|
|
3: ret
|
|
|
|
// x == NaN
|
|
5: flds 4(%esp)
|
|
ret
|
|
END(__ieee754_atanhf)
|
|
strong_alias (__ieee754_atanhf, __atanhf_finite)
|