mirror of
https://sourceware.org/git/glibc.git
synced 2024-12-03 10:21:05 +00:00
76a66d510a
http://sourceware.org/ml/libc-alpha/2013-07/msg00205.html These all wrongly specified float constants in a 64-bit word. * sysdeps/powerpc/powerpc64/fpu/s_ceilf.S: Correct float constants for little-endian. * sysdeps/powerpc/powerpc64/fpu/s_floorf.S: Likewise. * sysdeps/powerpc/powerpc64/fpu/s_nearbyintf.S: Likewise. * sysdeps/powerpc/powerpc64/fpu/s_rintf.S: Likewise. * sysdeps/powerpc/powerpc64/fpu/s_roundf.S: Likewise. * sysdeps/powerpc/powerpc64/fpu/s_truncf.S: Likewise.
58 lines
1.7 KiB
ArmAsm
58 lines
1.7 KiB
ArmAsm
/* float ceil function. PowerPC64 version.
|
|
Copyright (C) 2004-2013 Free Software Foundation, Inc.
|
|
This file is part of the GNU C Library.
|
|
|
|
The GNU C Library is free software; you can redistribute it and/or
|
|
modify it under the terms of the GNU Lesser General Public
|
|
License as published by the Free Software Foundation; either
|
|
version 2.1 of the License, or (at your option) any later version.
|
|
|
|
The GNU C Library is distributed in the hope that it will be useful,
|
|
but WITHOUT ANY WARRANTY; without even the implied warranty of
|
|
MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
|
|
Lesser General Public License for more details.
|
|
|
|
You should have received a copy of the GNU Lesser General Public
|
|
License along with the GNU C Library; if not, see
|
|
<http://www.gnu.org/licenses/>. */
|
|
|
|
#include <sysdep.h>
|
|
|
|
.section ".toc","aw"
|
|
.p2align 3
|
|
.LC0: /* 2**23 */
|
|
.long 0x4b000000
|
|
.long 0x0
|
|
.section ".text"
|
|
|
|
EALIGN (__ceilf, 4, 0)
|
|
CALL_MCOUNT 0
|
|
mffs fp11 /* Save current FPU rounding mode. */
|
|
lfs fp13,.LC0@toc(2)
|
|
fabs fp0,fp1
|
|
fsubs fp12,fp13,fp13 /* generate 0.0 */
|
|
fcmpu cr7,fp0,fp13 /* if (fabs(x) > TWO23) */
|
|
fcmpu cr6,fp1,fp12 /* if (x > 0.0) */
|
|
bnllr- cr7
|
|
mtfsfi 7,2 /* Set rounding mode toward +inf. */
|
|
ble- cr6,.L4
|
|
fadds fp1,fp1,fp13 /* x+= TWO23; */
|
|
fsubs fp1,fp1,fp13 /* x-= TWO23; */
|
|
fabs fp1,fp1 /* if (x == 0.0) */
|
|
/* x = 0.0; */
|
|
mtfsf 0x01,fp11 /* restore previous rounding mode. */
|
|
blr
|
|
.L4:
|
|
bge- cr6,.L9 /* if (x < 0.0) */
|
|
fsubs fp1,fp1,fp13 /* x-= TWO23; */
|
|
fadds fp1,fp1,fp13 /* x+= TWO23; */
|
|
fnabs fp1,fp1 /* if (x == 0.0) */
|
|
/* x = -0.0; */
|
|
.L9:
|
|
mtfsf 0x01,fp11 /* restore previous rounding mode. */
|
|
blr
|
|
END (__ceilf)
|
|
|
|
weak_alias (__ceilf, ceilf)
|
|
|