mirror of
https://sourceware.org/git/glibc.git
synced 2024-12-04 19:00:09 +00:00
8beba15d53
GDB failed to detect the outermost frame while showing the backtrace
within a thread:
Backtrace stopped: previous frame identical to this frame (corrupt stack?)
Before this patch, the start routines like thread_start had no cfi information.
GDB is then using the prologue unwinder if no cfi information is available.
This unwinder tries to unwind r15 and stops e.g. if r15 was updated or
on some jump-instructions.
On older glibc-versions (before commit "Remove cached PID/TID in clone"
c579f48edb), the thread_start function used
such a jump-instruction and GDB did not fail with an error.
This patch adds cfi information for _start, thread_start and __makecontext_ret
and marks r14 as undefined which marks the frame as outermost frame and GDB
stops the backtrace. Also tested different gcc versions in order to test
_Unwind_Backtrace() in libgcc as this is used by backtrace() in glibc.
ChangeLog:
* sysdeps/s390/s390-64/start.S (_start): Add cfi information for r14.
* sysdeps/s390/s390-32/start.S: (_start): Likewise
* sysdeps/unix/sysv/linux/s390/s390-64/clone.S
(thread_start): Likewise.
* sysdeps/unix/sysv/linux/s390/s390-32/clone.S
(thread_start): Likewise.
* sysdeps/unix/sysv/linux/s390/s390-64/__makecontext_ret.S
(__makecontext_ret): Likewise.
* sysdeps/unix/sysv/linux/s390/s390-32/__makecontext_ret.S
(__makecontext_ret): Likewise.
71 lines
2.5 KiB
ArmAsm
71 lines
2.5 KiB
ArmAsm
/* Wrapper around clone system call. 64 bit S/390 version.
|
|
Copyright (C) 2001-2017 Free Software Foundation, Inc.
|
|
Contributed by Martin Schwidefsky (schwidefsky@de.ibm.com).
|
|
This file is part of the GNU C Library.
|
|
|
|
The GNU C Library is free software; you can redistribute it and/or
|
|
modify it under the terms of the GNU Lesser General Public
|
|
License as published by the Free Software Foundation; either
|
|
version 2.1 of the License, or (at your option) any later version.
|
|
|
|
The GNU C Library is distributed in the hope that it will be useful,
|
|
but WITHOUT ANY WARRANTY; without even the implied warranty of
|
|
MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
|
|
Lesser General Public License for more details.
|
|
|
|
You should have received a copy of the GNU Lesser General Public
|
|
License along with the GNU C Library; if not, see
|
|
<http://www.gnu.org/licenses/>. */
|
|
|
|
/* clone is even more special than fork as it mucks with stacks
|
|
and invokes a function in the right context after its all over. */
|
|
|
|
#include <sysdep.h>
|
|
#include <tls.h>
|
|
#define _ERRNO_H 1
|
|
#include <bits/errno.h>
|
|
|
|
/* int __clone(int (*fn)(void *arg), void *child_stack, int flags, void *arg,
|
|
pid_t *parent_tid, void *tls, pid_t *child_tid); */
|
|
/* sys_clone (void *child_stack, unsigned long flags,
|
|
pid_t *parent_tid, pid_t *child_tid, void *tls); */
|
|
|
|
.text
|
|
ENTRY(__clone)
|
|
stg %r6,48(%r15) /* store %r6 to save area */
|
|
cfi_offset (%r6,-112)
|
|
lgr %r0,%r5 /* move *arg out of the way */
|
|
ltgr %r1,%r2 /* check fn and move to %r1 */
|
|
jz error /* no NULL function pointers */
|
|
ltgr %r2,%r3 /* check child_stack and move to %r2 */
|
|
jz error /* no NULL stack pointers */
|
|
lgr %r3,%r4 /* move flags to %r3 */
|
|
lgr %r4,%r6 /* move parent_tid to %r4 */
|
|
lg %r5,168(%r15) /* load child_tid from stack */
|
|
lg %r6,160(%r15) /* load tls from stack */
|
|
svc SYS_ify(clone)
|
|
ltgr %r2,%r2 /* check return code */
|
|
jz thread_start
|
|
lg %r6,48(%r15) /* restore %r6 */
|
|
jgm SYSCALL_ERROR_LABEL
|
|
br %r14
|
|
error:
|
|
lghi %r2,-EINVAL
|
|
jg SYSCALL_ERROR_LABEL
|
|
PSEUDO_END (__clone)
|
|
|
|
thread_start:
|
|
cfi_startproc
|
|
/* Mark r14 as undefined in order to stop unwinding here! */
|
|
cfi_undefined (r14)
|
|
/* fn is in gpr 1, arg in gpr 0 */
|
|
lgr %r2,%r0 /* set first parameter to void *arg */
|
|
aghi %r15,-160 /* make room on the stack for the save area */
|
|
xc 0(8,%r15),0(%r15)
|
|
basr %r14,%r1 /* jump to fn */
|
|
DO_CALL (exit, 1)
|
|
cfi_endproc
|
|
|
|
libc_hidden_def (__clone)
|
|
weak_alias (__clone, clone)
|