mirror of
https://sourceware.org/git/glibc.git
synced 2024-12-12 22:30:12 +00:00
56d7f02931
* sysdeps/m68k/lshift.S: Likewise. * sysdeps/m68k/rshift.S: Likewise. * sysdeps/m68k/sub_n.S: Likewise. * sysdeps/m68k/m68020/addmul_1.S: Likewise. * sysdeps/m68k/m68020/mul_1.S: Likewise. * sysdeps/m68k/m68020/submul_1.S: Likewise. * sysdeps/unix/sysv/linux/m68k/sysdep.S: Use ENTRY macro. [_LIBC_REENTRANT]: Don't store into global errno. * sysdeps/m68k/sysdep.h: New file. * sysdeps/unix/sysv/linux/m68k/sysdep.h: Use it. Use the macros ENTRY, CALL_MCOUNT, JUMPTARGET and syscall_error from there. (DO_CALL): Change to expect syscall name as argument. (PSEUDO): Pass syscall_name to DO_CALL. (SYSCALL_ERROR_HANDLER) [_LIBC_REENTRANT]: Don't store into global errno.
81 lines
2.1 KiB
ArmAsm
81 lines
2.1 KiB
ArmAsm
/* mc68020 __mpn_addmul_1 -- Multiply a limb vector with a limb and add
|
|
the result to a second limb vector.
|
|
|
|
Copyright (C) 1992, 1994, 1996, 1998 Free Software Foundation, Inc.
|
|
|
|
This file is part of the GNU MP Library.
|
|
|
|
The GNU MP Library is free software; you can redistribute it and/or modify
|
|
it under the terms of the GNU Library General Public License as published by
|
|
the Free Software Foundation; either version 2 of the License, or (at your
|
|
option) any later version.
|
|
|
|
The GNU MP Library is distributed in the hope that it will be useful, but
|
|
WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
|
|
or FITNESS FOR A PARTICULAR PURPOSE. See the GNU Library General Public
|
|
License for more details.
|
|
|
|
You should have received a copy of the GNU Library General Public License
|
|
along with the GNU MP Library; see the file COPYING.LIB. If not, write to
|
|
the Free Software Foundation, Inc., 59 Temple Place - Suite 330, Boston,
|
|
MA 02111-1307, USA. */
|
|
|
|
/*
|
|
INPUT PARAMETERS
|
|
res_ptr (sp + 4)
|
|
s1_ptr (sp + 8)
|
|
s1_size (sp + 12)
|
|
s2_limb (sp + 16)
|
|
*/
|
|
|
|
#include "sysdep.h"
|
|
#include "asm-syntax.h"
|
|
|
|
TEXT
|
|
ENTRY(__mpn_addmul_1)
|
|
|
|
#define res_ptr a0
|
|
#define s1_ptr a1
|
|
#define s1_size d2
|
|
#define s2_limb d4
|
|
|
|
/* Save used registers on the stack. */
|
|
moveml R(d2)-R(d5),MEM_PREDEC(sp)
|
|
|
|
/* Copy the arguments to registers. Better use movem? */
|
|
movel MEM_DISP(sp,20),R(res_ptr)
|
|
movel MEM_DISP(sp,24),R(s1_ptr)
|
|
movel MEM_DISP(sp,28),R(s1_size)
|
|
movel MEM_DISP(sp,32),R(s2_limb)
|
|
|
|
eorw #1,R(s1_size)
|
|
clrl R(d1)
|
|
clrl R(d5)
|
|
lsrl #1,R(s1_size)
|
|
bcc L(L1)
|
|
subql #1,R(s1_size)
|
|
subl R(d0),R(d0) /* (d0,cy) <= (0,0) */
|
|
|
|
L(Loop:)
|
|
movel MEM_POSTINC(s1_ptr),R(d3)
|
|
mulul R(s2_limb),R(d1):R(d3)
|
|
addxl R(d0),R(d3)
|
|
addxl R(d5),R(d1)
|
|
addl R(d3),MEM_POSTINC(res_ptr)
|
|
L(L1:) movel MEM_POSTINC(s1_ptr),R(d3)
|
|
mulul R(s2_limb),R(d0):R(d3)
|
|
addxl R(d1),R(d3)
|
|
addxl R(d5),R(d0)
|
|
addl R(d3),MEM_POSTINC(res_ptr)
|
|
|
|
dbf R(s1_size),L(Loop)
|
|
addxl R(d5),R(d0)
|
|
subl #0x10000,R(s1_size)
|
|
bcc L(Loop)
|
|
|
|
/* Restore used registers from stack frame. */
|
|
moveml MEM_POSTINC(sp),R(d2)-R(d5)
|
|
|
|
rts
|
|
END(__mpn_addmul_1)
|