mirror of
https://sourceware.org/git/glibc.git
synced 2024-12-28 13:31:13 +00:00
f58e5f4809
This patch continues the preparation for additional _FloatN / _FloatNx function aliases by using libm_alias_ldouble for sysdeps/x86_64/fpu long double functions, so that they can have _Float64x aliases added in future. Tested for x86_64, including build-many-glibcs.py tests that installed stripped shared libraries are unchanged by the patch. * sysdeps/x86_64/fpu/e_expl.S: Include <libm-alias-ldouble.h>. [USE_AS_EXPM1L] (expm1l): Define using libm_alias_ldouble. * sysdeps/x86_64/fpu/s_ceill.S: Include <libm-alias-ldouble.h>. (ceill): Define using libm_alias_ldouble. * sysdeps/x86_64/fpu/s_copysignl.S: Include <libm-alias-ldouble.h>. (copysignl): Define using libm_alias_ldouble. * sysdeps/x86_64/fpu/s_fabsl.S: Include <libm-alias-ldouble.h>. (fabsl): Define using libm_alias_ldouble. * sysdeps/x86_64/fpu/s_floorl.S: Include <libm-alias-ldouble.h>. (floorl): Define using libm_alias_ldouble. * sysdeps/x86_64/fpu/s_fmaxl.S: Include <libm-alias-ldouble.h>. (fmaxl): Define using libm_alias_ldouble. * sysdeps/x86_64/fpu/s_fminl.S: Include <libm-alias-ldouble.h>. (fminl): Define using libm_alias_ldouble. * sysdeps/x86_64/fpu/s_llrintl.S: Include <libm-alias-ldouble.h>. (llrintl): Define using libm_alias_ldouble. (lrintl): Likewise. * sysdeps/x86_64/fpu/s_nearbyintl.S: Include <libm-alias-ldouble.h>. (nearbyintl): Define using libm_alias_ldouble. * sysdeps/x86_64/fpu/s_truncl.S: Include <libm-alias-ldouble.h>. (truncl): Define using libm_alias_ldouble. * sysdeps/x86_64/x32/fpu/s_lrintl.S: Include <libm-alias-ldouble.h>. (lrintl): Define using libm_alias_ldouble.
60 lines
1.5 KiB
ArmAsm
60 lines
1.5 KiB
ArmAsm
/* Compute minimum of two numbers, regarding NaN as missing argument.
|
|
Copyright (C) 1997-2017 Free Software Foundation, Inc.
|
|
This file is part of the GNU C Library.
|
|
Contributed by Ulrich Drepper <drepper@cygnus.com>, 1997.
|
|
|
|
The GNU C Library is free software; you can redistribute it and/or
|
|
modify it under the terms of the GNU Lesser General Public
|
|
License as published by the Free Software Foundation; either
|
|
version 2.1 of the License, or (at your option) any later version.
|
|
|
|
The GNU C Library is distributed in the hope that it will be useful,
|
|
but WITHOUT ANY WARRANTY; without even the implied warranty of
|
|
MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
|
|
Lesser General Public License for more details.
|
|
|
|
You should have received a copy of the GNU Lesser General Public
|
|
License along with the GNU C Library; if not, see
|
|
<http://www.gnu.org/licenses/>. */
|
|
|
|
#include <sysdep.h>
|
|
#include <libm-alias-ldouble.h>
|
|
|
|
.text
|
|
ENTRY(__fminl)
|
|
fldt 8(%rsp) // x
|
|
fldt 24(%rsp) // x : y
|
|
|
|
fucomi %st(1), %st
|
|
jp 2f
|
|
fcmovnb %st(1), %st
|
|
|
|
fstp %st(1)
|
|
|
|
ret
|
|
|
|
2: // Unordered.
|
|
fucomi %st(0), %st
|
|
jp 3f
|
|
// st(1) is a NaN; st(0) is not. Test if st(1) is signaling.
|
|
testb $0x40, 15(%rsp)
|
|
jz 4f
|
|
fstp %st(1)
|
|
ret
|
|
|
|
3: // st(0) is a NaN; st(1) may or may not be.
|
|
fxch
|
|
fucomi %st(0), %st
|
|
jp 4f
|
|
// st(1) is a NaN; st(0) is not. Test if st(1) is signaling.
|
|
testb $0x40, 31(%rsp)
|
|
jz 4f
|
|
fstp %st(1)
|
|
ret
|
|
|
|
4: // Both arguments are NaNs, or one is a signaling NaN.
|
|
faddp
|
|
ret
|
|
END(__fminl)
|
|
libm_alias_ldouble (__fmin, fmin)
|