mirror of
https://sourceware.org/git/glibc.git
synced 2024-12-29 05:51:10 +00:00
25f1e16ef0
CET is only support for x86_64, this patch reverts: -faaee1f07ex86: Support shadow stack pointer in setjmp/longjmp. -be9ccd27c0i386: Add _CET_ENDBR to indirect jump targets in add_n.S/sub_n.S -c02695d776x86/CET: Update vfork to prevent child return -5d844e1b72i386: Enable CET support in ucontext functions -124bcde683x86: Add _CET_ENDBR to functions in crti.S -562837c002x86: Add _CET_ENDBR to functions in dl-tlsdesc.S -f753fa7deax86: Support IBT and SHSTK in Intel CET [BZ #21598] -825b58f3fbi386-mcount.S: Add _CET_ENDBR to _mcount and __fentry__ -7e119cd582i386: Use _CET_NOTRACK in i686/memcmp.S -177824e232i386: Use _CET_NOTRACK in memcmp-sse4.S -0a899af097i386: Use _CET_NOTRACK in memcpy-ssse3-rep.S -7fb613361ci386: Use _CET_NOTRACK in memcpy-ssse3.S -77a8ae0948i386: Use _CET_NOTRACK in memset-sse2-rep.S -00e7b76a8fi386: Use _CET_NOTRACK in memset-sse2.S -90d15dc577i386: Use _CET_NOTRACK in strcat-sse2.S -f1574581c7i386: Use _CET_NOTRACK in strcpy-sse2.S -4031d7484ai386/sub_n.S: Add a missing _CET_ENDBR to indirect jump - target - Checked on i686-linux-gnu.
58 lines
1.9 KiB
ArmAsm
58 lines
1.9 KiB
ArmAsm
/* BSD `_setjmp' entry point to `sigsetjmp (..., 0)'. i386 version.
|
|
Copyright (C) 1994-2024 Free Software Foundation, Inc.
|
|
This file is part of the GNU C Library.
|
|
|
|
The GNU C Library is free software; you can redistribute it and/or
|
|
modify it under the terms of the GNU Lesser General Public
|
|
License as published by the Free Software Foundation; either
|
|
version 2.1 of the License, or (at your option) any later version.
|
|
|
|
The GNU C Library is distributed in the hope that it will be useful,
|
|
but WITHOUT ANY WARRANTY; without even the implied warranty of
|
|
MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
|
|
Lesser General Public License for more details.
|
|
|
|
You should have received a copy of the GNU Lesser General Public
|
|
License along with the GNU C Library; if not, see
|
|
<https://www.gnu.org/licenses/>. */
|
|
|
|
/* This just does a tail-call to `__sigsetjmp (ARG, 0)'.
|
|
We cannot do it in C because it must be a tail-call, so frame-unwinding
|
|
in setjmp doesn't clobber the state restored by longjmp. */
|
|
|
|
#include <sysdep.h>
|
|
#include <pointer_guard.h>
|
|
#include <jmpbuf-offsets.h>
|
|
#include <stap-probe.h>
|
|
|
|
#define PARMS 4 /* no space for saved regs */
|
|
#define JMPBUF PARMS
|
|
#define SIGMSK JMPBUF+4
|
|
|
|
ENTRY (_setjmp)
|
|
|
|
xorl %eax, %eax
|
|
movl JMPBUF(%esp), %edx
|
|
|
|
/* Save registers. */
|
|
movl %ebx, (JB_BX*4)(%edx)
|
|
movl %esi, (JB_SI*4)(%edx)
|
|
movl %edi, (JB_DI*4)(%edx)
|
|
leal JMPBUF(%esp), %ecx /* Save SP as it will be after we return. */
|
|
#ifdef PTR_MANGLE
|
|
PTR_MANGLE (%ecx)
|
|
#endif
|
|
movl %ecx, (JB_SP*4)(%edx)
|
|
movl 0(%esp), %ecx /* Save PC we are returning to now. */
|
|
LIBC_PROBE (setjmp, 3, 4@%edx, -4@$0, 4@%ecx)
|
|
#ifdef PTR_MANGLE
|
|
PTR_MANGLE (%ecx)
|
|
#endif
|
|
movl %ecx, (JB_PC*4)(%edx)
|
|
movl %ebp, (JB_BP*4)(%edx) /* Save caller's frame pointer. */
|
|
|
|
movl %eax, JB_SIZE(%edx) /* No signal mask set. */
|
|
ret
|
|
END (_setjmp)
|
|
libc_hidden_def (_setjmp)
|