mirror of
https://sourceware.org/git/glibc.git
synced 2024-12-02 17:50:20 +00:00
73bc81179e
* sysdeps/unix/sysv/linux/alpha/rt_sigaction.S: Fix typos. * sysdeps/unix/sysv/linux/alpha/bits/time.h (struct timeval): Follow POSIX and make tv_sec a time_t. * sysdeps/unix/sysv/linux/alpha/getitimer.S: New file to handle new tv64 syscall as well as fall back to tv32. * sysdeps/unix/sysv/linux/alpha/getrusage.S: Likewise. * sysdeps/unix/sysv/linux/alpha/gettimeofday.S: Likewise. * sysdeps/unix/sysv/linux/alpha/select.S: Likewise. * sysdeps/unix/sysv/linux/alpha/setitimer.S: Likewise. * sysdeps/unix/sysv/linux/alpha/settimeofday.S: Likewise. * sysdeps/unix/sysv/linux/alpha/utimes.S: Likewise. * sysdeps/unix/sysv/linux/alpha/wait4.S: Likewise. * sysdeps/unix/sysv/linux/alpha/syscalls.list: Add tv32 entries.
103 lines
2.6 KiB
ArmAsm
103 lines
2.6 KiB
ArmAsm
/* Copyright (C) 1998 Free Software Foundation, Inc.
|
|
This file is part of the GNU C Library.
|
|
|
|
The GNU C Library is free software; you can redistribute it and/or
|
|
modify it under the terms of the GNU Library General Public License as
|
|
published by the Free Software Foundation; either version 2 of the
|
|
License, or (at your option) any later version.
|
|
|
|
The GNU C Library is distributed in the hope that it will be useful,
|
|
but WITHOUT ANY WARRANTY; without even the implied warranty of
|
|
MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
|
|
Library General Public License for more details.
|
|
|
|
You should have received a copy of the GNU Library General Public
|
|
License along with the GNU C Library; see the file COPYING.LIB. If not,
|
|
write to the Free Software Foundation, Inc., 59 Temple Place - Suite 330,
|
|
Boston, MA 02111-1307, USA. */
|
|
|
|
#include <sysdep.h>
|
|
#define _ERRNO_H 1
|
|
#include <bits/errno.h>
|
|
|
|
/* The problem here is that initially we made struct timeval compatible with
|
|
OSF/1, using int32. But we defined time_t with uint64, and later found
|
|
that POSIX requires tv_sec to be time_t.
|
|
|
|
So now we have to do compatibility stuff. */
|
|
|
|
/* The variable is shared between all wrappers around signal handling
|
|
functions which have RT equivalents. */
|
|
.comm __libc_missing_axp_tv64, 4
|
|
|
|
.text
|
|
|
|
LEAF(__settimeofday_tv64, 16)
|
|
ldgp gp, 0(pv)
|
|
subq sp, 16, sp
|
|
#ifdef PROF
|
|
.set noat
|
|
lda AT, _mcount
|
|
jsr AT, (AT), _mcount
|
|
.set at
|
|
#endif
|
|
.prologue 1
|
|
|
|
ldl t0, __libc_missing_axp_tv64
|
|
bne t0, $do32
|
|
|
|
/* Save arguments in case we do need to fall back. */
|
|
stq a0, 0(sp)
|
|
stq a1, 8(sp)
|
|
|
|
ldi v0, SYS_ify(settimeofday)
|
|
callsys
|
|
bne a3, $err64
|
|
|
|
/* Everything ok. */
|
|
addq sp, 16, sp
|
|
ret
|
|
|
|
/* If we didn't get ENOSYS, it is a real error. */
|
|
.align 3
|
|
$err64: cmpeq v0, ENOSYS, t0
|
|
bne t0, $error
|
|
stl t0, __libc_missing_axp_tv64
|
|
|
|
/* Recover the saved arguments. */
|
|
ldq a1, 8(sp)
|
|
ldq a0, 0(sp)
|
|
|
|
.align 3
|
|
$do32:
|
|
/* Conditionally bounce the timeval down. */
|
|
beq a0, 1f
|
|
ldq t0, 0(a0)
|
|
ldq t1, 8(a0)
|
|
stl t0, 0(sp)
|
|
stl t1, 4(sp)
|
|
mov sp, a0
|
|
|
|
1: ldi v0, SYS_ify(osf_settimeofday)
|
|
callsys
|
|
bne a3, $error
|
|
|
|
addq sp, 16, sp
|
|
ret
|
|
|
|
.align 3
|
|
$error:
|
|
lda pv, __syscall_error
|
|
addq sp, 16, sp
|
|
jmp zero, (pv), __syscall_error
|
|
|
|
END(__settimeofday_tv64)
|
|
|
|
default_symbol_version (__settimeofday_tv64, __settimeofday, GLIBC_2.1)
|
|
|
|
/* It seems to me to be a misfeature of the assembler that we can only
|
|
have one version-alias per symbol. So create an alias ourselves.
|
|
The 'p' is for 'public'. *Shrug* */
|
|
strong_alias (__settimeofday_tv64, __settimeofday_tv64p)
|
|
default_symbol_version (__settimeofday_tv64p, settimeofday, GLIBC_2.1)
|