mirror of
https://sourceware.org/git/glibc.git
synced 2024-12-13 14:50:17 +00:00
25f1e16ef0
CET is only support for x86_64, this patch reverts: -faaee1f07ex86: Support shadow stack pointer in setjmp/longjmp. -be9ccd27c0i386: Add _CET_ENDBR to indirect jump targets in add_n.S/sub_n.S -c02695d776x86/CET: Update vfork to prevent child return -5d844e1b72i386: Enable CET support in ucontext functions -124bcde683x86: Add _CET_ENDBR to functions in crti.S -562837c002x86: Add _CET_ENDBR to functions in dl-tlsdesc.S -f753fa7deax86: Support IBT and SHSTK in Intel CET [BZ #21598] -825b58f3fbi386-mcount.S: Add _CET_ENDBR to _mcount and __fentry__ -7e119cd582i386: Use _CET_NOTRACK in i686/memcmp.S -177824e232i386: Use _CET_NOTRACK in memcmp-sse4.S -0a899af097i386: Use _CET_NOTRACK in memcpy-ssse3-rep.S -7fb613361ci386: Use _CET_NOTRACK in memcpy-ssse3.S -77a8ae0948i386: Use _CET_NOTRACK in memset-sse2-rep.S -00e7b76a8fi386: Use _CET_NOTRACK in memset-sse2.S -90d15dc577i386: Use _CET_NOTRACK in strcat-sse2.S -f1574581c7i386: Use _CET_NOTRACK in strcpy-sse2.S -4031d7484ai386/sub_n.S: Add a missing _CET_ENDBR to indirect jump - target - Checked on i686-linux-gnu.
130 lines
3.8 KiB
ArmAsm
130 lines
3.8 KiB
ArmAsm
/* Create new context.
|
|
Copyright (C) 2001-2024 Free Software Foundation, Inc.
|
|
This file is part of the GNU C Library.
|
|
|
|
The GNU C Library is free software; you can redistribute it and/or
|
|
modify it under the terms of the GNU Lesser General Public
|
|
License as published by the Free Software Foundation; either
|
|
version 2.1 of the License, or (at your option) any later version.
|
|
|
|
The GNU C Library is distributed in the hope that it will be useful,
|
|
but WITHOUT ANY WARRANTY; without even the implied warranty of
|
|
MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
|
|
Lesser General Public License for more details.
|
|
|
|
You should have received a copy of the GNU Lesser General Public
|
|
License along with the GNU C Library; if not, see
|
|
<https://www.gnu.org/licenses/>. */
|
|
|
|
#include <sysdep.h>
|
|
|
|
#include "ucontext_i.h"
|
|
|
|
|
|
ENTRY(__makecontext)
|
|
movl 4(%esp), %eax
|
|
|
|
/* Load the address of the function we are supposed to run. */
|
|
movl 8(%esp), %ecx
|
|
|
|
/* Compute the address of the stack. The information comes from
|
|
to us_stack element. */
|
|
movl oSS_SP(%eax), %edx
|
|
movl %ecx, oEIP(%eax)
|
|
addl oSS_SIZE(%eax), %edx
|
|
|
|
/* Remember the number of parameters for the exit handler since
|
|
it has to remove them. We store the number in the EBX register
|
|
which the function we will call must preserve. */
|
|
movl 12(%esp), %ecx
|
|
movl %ecx, oEBX(%eax)
|
|
|
|
/* Make room on the new stack for the parameters.
|
|
Room for the arguments, return address (== L(exitcode)) and
|
|
oLINK pointer is needed. One of the pointer sizes is subtracted
|
|
after aligning the stack. */
|
|
negl %ecx
|
|
leal -4(%edx,%ecx,4), %edx
|
|
negl %ecx
|
|
|
|
/* Align the stack. */
|
|
andl $0xfffffff0, %edx
|
|
subl $4, %edx
|
|
|
|
/* Store the future stack pointer. */
|
|
movl %edx, oESP(%eax)
|
|
|
|
/* Put the next context on the new stack (from the uc_link
|
|
element). */
|
|
movl oLINK(%eax), %eax
|
|
movl %eax, 4(%edx,%ecx,4)
|
|
|
|
/* Copy all the parameters. */
|
|
jecxz 2f
|
|
1: movl 12(%esp,%ecx,4), %eax
|
|
movl %eax, (%edx,%ecx,4)
|
|
decl %ecx
|
|
jnz 1b
|
|
2:
|
|
|
|
/* If the function we call returns we must continue with the
|
|
context which is given in the uc_link element. To do this
|
|
set the return address for the function the user provides
|
|
to a little bit of helper code which does the magic (see
|
|
below). */
|
|
#ifdef PIC
|
|
call 1f
|
|
cfi_adjust_cfa_offset (4)
|
|
1: popl %ecx
|
|
cfi_adjust_cfa_offset (-4)
|
|
addl $L(exitcode)-1b, %ecx
|
|
movl %ecx, (%edx)
|
|
#else
|
|
movl $L(exitcode), (%edx)
|
|
#endif
|
|
/* We need to terminate the FDE here instead of after ret because
|
|
the unwinder looks at ra-1 for unwind information. */
|
|
cfi_endproc
|
|
|
|
/* 'makecontext' returns no value. */
|
|
ret
|
|
|
|
/* This is the helper code which gets called if a function which
|
|
is registered with 'makecontext' returns. In this case we
|
|
have to install the context listed in the uc_link element of
|
|
the context 'makecontext' manipulated at the time of the
|
|
'makecontext' call. If the pointer is NULL the process must
|
|
terminate. */
|
|
L(exitcode):
|
|
/* This removes the parameters passed to the function given to
|
|
'makecontext' from the stack. EBX contains the number of
|
|
parameters (see above). */
|
|
leal (%esp,%ebx,4), %esp
|
|
|
|
cmpl $0, (%esp) /* Check the next context. */
|
|
je 2f /* If it is zero exit. */
|
|
|
|
call HIDDEN_JUMPTARGET(__setcontext)
|
|
/* If this returns (which can happen if the syscall fails) we'll
|
|
exit the program with the return error value (-1). */
|
|
jmp L(call_exit)
|
|
|
|
2:
|
|
/* Exit with status 0. */
|
|
xorl %eax, %eax
|
|
|
|
L(call_exit):
|
|
/* Align the stack and pass the exit code (from %eax). */
|
|
andl $0xfffffff0, %esp
|
|
subl $12, %esp
|
|
pushl %eax
|
|
|
|
call HIDDEN_JUMPTARGET(exit)
|
|
/* The 'exit' call should never return. In case it does cause
|
|
the process to terminate. */
|
|
hlt
|
|
cfi_startproc
|
|
END(__makecontext)
|
|
|
|
weak_alias (__makecontext, makecontext)
|