mirror of
https://sourceware.org/git/glibc.git
synced 2024-11-27 07:20:11 +00:00
03d95bd483
This patch fixes the remaining part of bug 16560, spurious underflows from exp2 of arguments close to 0 (when the result is close to 1, so should not underflow), by just using 1+x instead of a more complicated calculation when the argument is sufficiently small. Tested for x86_64, x86 and mips64. [BZ #16560] * math/e_exp2l.c [LDBL_MANT_DIG == 106] (LDBL_EPSILON): Undefine and redefine. (__ieee754_exp2l): Do not multiply small fractional parts by M_LN2l. * sysdeps/i386/fpu/e_exp2l.S (__ieee754_exp2l): Just add 1 to small argument. * sysdeps/ieee754/dbl-64/e_exp2.c (__ieee754_exp2): Likewise. * sysdeps/ieee754/flt-32/e_exp2f.c (__ieee754_exp2f): Likewise. * sysdeps/x86_64/fpu/e_exp2l.S (__ieee754_exp2l): Likewise. * math/auto-libm-test-in: Add more tests of exp2. * math/auto-libm-test-out: Regenerated.
47 lines
1.0 KiB
ArmAsm
47 lines
1.0 KiB
ArmAsm
/*
|
|
* Written by J.T. Conklin <jtc@netbsd.org>.
|
|
* Adapted for exp2 by Ulrich Drepper <drepper@cygnus.com>.
|
|
* Public domain.
|
|
*/
|
|
|
|
#include <machine/asm.h>
|
|
|
|
ENTRY(__ieee754_exp2l)
|
|
fldt 4(%esp)
|
|
/* I added the following ugly construct because exp(+-Inf) resulted
|
|
in NaN. The ugliness results from the bright minds at Intel.
|
|
For the i686 the code can be written better.
|
|
-- drepper@cygnus.com. */
|
|
fxam /* Is NaN or +-Inf? */
|
|
fstsw %ax
|
|
movb $0x45, %dh
|
|
andb %ah, %dh
|
|
cmpb $0x05, %dh
|
|
je 1f /* Is +-Inf, jump. */
|
|
movzwl 4+8(%esp), %eax
|
|
andl $0x7fff, %eax
|
|
cmpl $0x3fbe, %eax
|
|
jge 3f
|
|
/* Argument's exponent below -65, result rounds to 1. */
|
|
fld1
|
|
faddp
|
|
ret
|
|
3: fld %st
|
|
frndint /* int(x) */
|
|
fsubr %st,%st(1) /* fract(x) */
|
|
fxch
|
|
f2xm1 /* 2^(fract(x)) - 1 */
|
|
fld1
|
|
faddp /* 2^(fract(x)) */
|
|
fscale /* e^x */
|
|
fstp %st(1)
|
|
ret
|
|
|
|
1: testl $0x200, %eax /* Test sign. */
|
|
jz 2f /* If positive, jump. */
|
|
fstp %st
|
|
fldz /* Set result to 0. */
|
|
2: ret
|
|
END (__ieee754_exp2l)
|
|
strong_alias (__ieee754_exp2l, __exp2l_finite)
|