mirror of
https://sourceware.org/git/glibc.git
synced 2024-11-22 13:00:06 +00:00
30891f35fa
We stopped adding "Contributed by" or similar lines in sources in 2012 in favour of git logs and keeping the Contributors section of the glibc manual up to date. Removing these lines makes the license header a bit more consistent across files and also removes the possibility of error in attribution when license blocks or files are copied across since the contributed-by lines don't actually reflect reality in those cases. Move all "Contributed by" and similar lines (Written by, Test by, etc.) into a new file CONTRIBUTED-BY to retain record of these contributions. These contributors are also mentioned in manual/contrib.texi, so we just maintain this additional record as a courtesy to the earlier developers. The following scripts were used to filter a list of files to edit in place and to clean up the CONTRIBUTED-BY file respectively. These were not added to the glibc sources because they're not expected to be of any use in future given that this is a one time task: https://gist.github.com/siddhesh/b5ecac94eabfd72ed2916d6d8157e7dc https://gist.github.com/siddhesh/15ea1f5e435ace9774f485030695ee02 Reviewed-by: Carlos O'Donell <carlos@redhat.com>
140 lines
3.3 KiB
ArmAsm
140 lines
3.3 KiB
ArmAsm
/* ix87 specific implementation of arcsinh.
|
|
Copyright (C) 1996-2021 Free Software Foundation, Inc.
|
|
This file is part of the GNU C Library.
|
|
|
|
The GNU C Library is free software; you can redistribute it and/or
|
|
modify it under the terms of the GNU Lesser General Public
|
|
License as published by the Free Software Foundation; either
|
|
version 2.1 of the License, or (at your option) any later version.
|
|
|
|
The GNU C Library is distributed in the hope that it will be useful,
|
|
but WITHOUT ANY WARRANTY; without even the implied warranty of
|
|
MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
|
|
Lesser General Public License for more details.
|
|
|
|
You should have received a copy of the GNU Lesser General Public
|
|
License along with the GNU C Library; if not, see
|
|
<https://www.gnu.org/licenses/>. */
|
|
|
|
#include <machine/asm.h>
|
|
#include <libm-alias-float.h>
|
|
|
|
.section .rodata
|
|
|
|
.align ALIGNARG(4)
|
|
.type huge,@object
|
|
huge: .double 1e+36
|
|
ASM_SIZE_DIRECTIVE(huge)
|
|
.type one,@object
|
|
one: .double 1.0
|
|
ASM_SIZE_DIRECTIVE(one)
|
|
.type limit,@object
|
|
limit: .double 0.29
|
|
ASM_SIZE_DIRECTIVE(limit)
|
|
|
|
#ifdef PIC
|
|
#define MO(op) op##@GOTOFF(%edx)
|
|
#else
|
|
#define MO(op) op
|
|
#endif
|
|
|
|
.text
|
|
ENTRY(__asinhf)
|
|
movl 4(%esp), %ecx
|
|
movl $0x7fffffff, %eax
|
|
andl %ecx, %eax
|
|
andl $0x80000000, %ecx
|
|
movl %eax, %edx
|
|
orl $0x807fffff, %edx
|
|
incl %edx
|
|
jz 7f // x in ±Inf or NaN
|
|
xorl %ecx, 4(%esp)
|
|
flds 4(%esp) // |x|
|
|
cmpl $0x38000000, %eax
|
|
jb 2f // |x| < 2^-14
|
|
fldln2 // log(2) : |x|
|
|
cmpl $0x47000000, %eax
|
|
fxch // |x| : log(2)
|
|
ja 3f // |x| > 2^14
|
|
#ifdef PIC
|
|
LOAD_PIC_REG (dx)
|
|
#endif
|
|
cmpl $0x40000000, %eax
|
|
ja 5f // |x| > 2
|
|
|
|
// 2^-14 <= |x| <= 2 => y = sign(x)*log1p(|x|+|x|^2/(1+sqrt(1+|x|^2)))
|
|
fld %st // |x| : |x| : log(2)
|
|
fmul %st(1) // |x|^2 : |x| : log(2)
|
|
fld %st // |x|^2 : |x|^2 : |x| : log(2)
|
|
faddl MO(one) // 1+|x|^2 : |x|^2 : |x| : log(2)
|
|
fsqrt // sqrt(1+|x|^2) : |x|^2 : |x| : log(2)
|
|
faddl MO(one) // 1+sqrt(1+|x|^2) : |x|^2 : |x| : log(2)
|
|
fdivrp // |x|^2/(1+sqrt(1+|x|^2)) : |x| : log(2)
|
|
faddp // |x|+|x|^2/(1+sqrt(1+|x|^2)) : log(2)
|
|
fcoml MO(limit)
|
|
fnstsw
|
|
sahf
|
|
ja 6f
|
|
fyl2xp1
|
|
jecxz 4f
|
|
fchs
|
|
4: ret
|
|
|
|
7: flds 4(%esp)
|
|
ret
|
|
|
|
6: faddl MO(one)
|
|
fyl2x
|
|
jecxz 4f
|
|
fchs
|
|
4: ret
|
|
|
|
// |x| < 2^-14 => y = x (inexact iff |x| != 0.0)
|
|
.align ALIGNARG(4)
|
|
2:
|
|
#ifdef PIC
|
|
LOAD_PIC_REG (dx)
|
|
#endif
|
|
jecxz 4f
|
|
fchs // x
|
|
4: fld %st // x : x
|
|
faddl MO(huge) // huge+x : x
|
|
fstp %st(0) // x
|
|
cmpl $0x00800000, %eax
|
|
jae 8f
|
|
subl $4, %esp
|
|
cfi_adjust_cfa_offset (4)
|
|
fld %st(0)
|
|
fmul %st(0)
|
|
fstps (%esp)
|
|
addl $4, %esp
|
|
cfi_adjust_cfa_offset (-4)
|
|
8: ret
|
|
|
|
// |x| > 2^14 => y = sign(x) * (log(|x|) + log(2))
|
|
.align ALIGNARG(4)
|
|
3: fyl2x // log(|x|)
|
|
fldln2 // log(2) : log(|x|)
|
|
faddp // log(|x|)+log(2)
|
|
jecxz 4f
|
|
fchs
|
|
4: ret
|
|
|
|
// |x| > 2 => y = sign(x) * log(2*|x| + 1/(|x|+sqrt(x*x+1)))
|
|
.align ALIGNARG(4)
|
|
5: fld %st // |x| : |x| : log(2)
|
|
fadd %st, %st(1) // |x| : 2*|x| : log(2)
|
|
fld %st // |x| : |x| : 2*|x| : log(2)
|
|
fmul %st(1) // |x|^2 : |x| : 2*|x| : log(2)
|
|
faddl MO(one) // 1+|x|^2 : |x| : 2*|x| : log(2)
|
|
fsqrt // sqrt(1+|x|^2) : |x| : 2*|x| : log(2)
|
|
faddp // |x|+sqrt(1+|x|^2) : 2*|x| : log(2)
|
|
fdivrl MO(one) // 1/(|x|+sqrt(1+|x|^2)) : 2*|x| : log(2)
|
|
faddp // 2*|x|+1/(|x|+sqrt(1+|x|^2)) : log(2)
|
|
fyl2x // log(2*|x|+1/(|x|+sqrt(1+|x|^2)))
|
|
jecxz 4f
|
|
fchs
|
|
4: ret
|
|
END(__asinhf)
|
|
libm_alias_float (__asinh, asinh)
|