mirror of
https://sourceware.org/git/glibc.git
synced 2024-12-02 09:40:13 +00:00
903af5af9a
Various exp2 implementations in glibc can miss underflow exceptions when the scaling down part of the calculation is exact (or, in the x86 case, when the conversion from extended precision to the target precision is exact). This patch forces the exception in a similar way to previous fixes. The x86 exp2f changes may in fact not be needed for this purpose - it's likely to be the case that no argument of type float has an exp2 result so close to an exact subnormal float value that it equals that value when rounded to 64 bits (even taking account of variation between different x86 implementations). However, they are included for consistency with the changes to exp2 and so as to fix the exp2f part of bug 18875 by ensuring that excess range and precision is removed from underflowing return values. Tested for x86_64, x86 and mips64. [BZ #16521] [BZ #18875] * math/e_exp2l.c (__ieee754_exp2l): Force underflow exception for small results. * sysdeps/i386/fpu/e_exp2.S (dbl_min): New object. (MO): New macro. (__ieee754_exp2): For small results, force underflow exception and remove excess range and precision from return value. * sysdeps/i386/fpu/e_exp2f.S (flt_min): New object. (MO): New macro. (__ieee754_exp2f): For small results, force underflow exception and remove excess range and precision from return value. * sysdeps/i386/fpu/e_exp2l.S (ldbl_min): New object. (MO): New macro. (__ieee754_exp2l): Force underflow exception for small results. * sysdeps/ieee754/dbl-64/e_exp2.c (__ieee754_exp2): Likewise. * sysdeps/ieee754/flt-32/e_exp2f.c (__ieee754_exp2f): Likewise. * sysdeps/x86_64/fpu/e_exp2l.S (ldbl_min): New object. (MO): New macro. (__ieee754_exp2l): Force underflow exception for small results. * math/auto-libm-test-in: Add more tests or exp2. * math/auto-libm-test-out: Regenerated.
71 lines
1.4 KiB
ArmAsm
71 lines
1.4 KiB
ArmAsm
/*
|
|
* Written by J.T. Conklin <jtc@netbsd.org>.
|
|
* Adapted for exp2 by Ulrich Drepper <drepper@cygnus.com>.
|
|
* Public domain.
|
|
*/
|
|
|
|
#include <machine/asm.h>
|
|
|
|
.section .rodata.cst8,"aM",@progbits,8
|
|
|
|
.p2align 3
|
|
.type dbl_min,@object
|
|
dbl_min: .byte 0, 0, 0, 0, 0, 0, 0x10, 0
|
|
ASM_SIZE_DIRECTIVE(dbl_min)
|
|
|
|
#ifdef PIC
|
|
# define MO(op) op##@GOTOFF(%ecx)
|
|
#else
|
|
# define MO(op) op
|
|
#endif
|
|
|
|
.text
|
|
ENTRY(__ieee754_exp2)
|
|
#ifdef PIC
|
|
LOAD_PIC_REG (cx)
|
|
#endif
|
|
fldl 4(%esp)
|
|
/* I added the following ugly construct because exp(+-Inf) resulted
|
|
in NaN. The ugliness results from the bright minds at Intel.
|
|
For the i686 the code can be written better.
|
|
-- drepper@cygnus.com. */
|
|
fxam /* Is NaN or +-Inf? */
|
|
fstsw %ax
|
|
movb $0x45, %dh
|
|
andb %ah, %dh
|
|
cmpb $0x05, %dh
|
|
je 1f /* Is +-Inf, jump. */
|
|
fld %st
|
|
frndint /* int(x) */
|
|
fsubr %st,%st(1) /* fract(x) */
|
|
fxch
|
|
f2xm1 /* 2^(fract(x)) - 1 */
|
|
fld1
|
|
faddp /* 2^(fract(x)) */
|
|
fscale /* e^x */
|
|
fstp %st(1)
|
|
fldl MO(dbl_min)
|
|
fld %st(1)
|
|
fucompp
|
|
fnstsw
|
|
sahf
|
|
jnc 3f
|
|
subl $8, %esp
|
|
cfi_adjust_cfa_offset (8)
|
|
fld %st(0)
|
|
fmul %st(0)
|
|
fstpl (%esp)
|
|
fstpl (%esp)
|
|
fldl (%esp)
|
|
addl $8, %esp
|
|
cfi_adjust_cfa_offset (-8)
|
|
3: ret
|
|
|
|
1: testl $0x200, %eax /* Test sign. */
|
|
jz 2f /* If positive, jump. */
|
|
fstp %st
|
|
fldz /* Set result to 0. */
|
|
2: ret
|
|
END (__ieee754_exp2)
|
|
strong_alias (__ieee754_exp2, __exp2_finite)
|