mirror of
https://sourceware.org/git/glibc.git
synced 2024-12-02 09:40:13 +00:00
30891f35fa
We stopped adding "Contributed by" or similar lines in sources in 2012 in favour of git logs and keeping the Contributors section of the glibc manual up to date. Removing these lines makes the license header a bit more consistent across files and also removes the possibility of error in attribution when license blocks or files are copied across since the contributed-by lines don't actually reflect reality in those cases. Move all "Contributed by" and similar lines (Written by, Test by, etc.) into a new file CONTRIBUTED-BY to retain record of these contributions. These contributors are also mentioned in manual/contrib.texi, so we just maintain this additional record as a courtesy to the earlier developers. The following scripts were used to filter a list of files to edit in place and to clean up the CONTRIBUTED-BY file respectively. These were not added to the glibc sources because they're not expected to be of any use in future given that this is a one time task: https://gist.github.com/siddhesh/b5ecac94eabfd72ed2916d6d8157e7dc https://gist.github.com/siddhesh/15ea1f5e435ace9774f485030695ee02 Reviewed-by: Carlos O'Donell <carlos@redhat.com>
64 lines
2.1 KiB
ArmAsm
64 lines
2.1 KiB
ArmAsm
/* Round float to int floating-point values without generating
|
|
an inexact exception, sparc64 version.
|
|
|
|
Copyright (C) 2013-2021 Free Software Foundation, Inc.
|
|
This file is part of the GNU C Library.
|
|
|
|
The GNU C Library is free software; you can redistribute it and/or
|
|
modify it under the terms of the GNU Lesser General Public
|
|
License as published by the Free Software Foundation; either
|
|
version 2.1 of the License, or (at your option) any later version.
|
|
|
|
The GNU C Library is distributed in the hope that it will be useful,
|
|
but WITHOUT ANY WARRANTY; without even the implied warranty of
|
|
MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
|
|
Lesser General Public License for more details.
|
|
|
|
You should have received a copy of the GNU Lesser General Public
|
|
License along with the GNU C Library; if not, see
|
|
<https://www.gnu.org/licenses/>. */
|
|
|
|
#include <sysdep.h>
|
|
#include <libm-alias-float.h>
|
|
|
|
/* We pop constants into the FPU registers using the incoming
|
|
argument stack slots, since this avoid having to use any PIC
|
|
references. We also thus avoid having to allocate a register
|
|
window.
|
|
|
|
VIS instructions are used to facilitate the formation of
|
|
easier constants, and the propagation of the sign bit. */
|
|
|
|
#define TWO_TWENTYTHREE 0x4b000000 /* 2**23 */
|
|
|
|
#define ZERO %f10 /* 0.0 */
|
|
#define SIGN_BIT %f12 /* -0.0 */
|
|
|
|
ENTRY (__nearbyintf)
|
|
fcmps %fcc3, %f1, %f1 /* Check for sNaN */
|
|
stx %fsr, [%sp + STACK_BIAS + 144]
|
|
sethi %hi(0xf8003e0), %o5
|
|
sethi %hi(TWO_TWENTYTHREE), %o2
|
|
ldx [%sp + STACK_BIAS + 144], %o4
|
|
or %o5, %lo(0xf8003e0), %o5
|
|
fzeros ZERO
|
|
andn %o4, %o5, %o4
|
|
fnegs ZERO, SIGN_BIT
|
|
st %o2, [%sp + STACK_BIAS + 128]
|
|
stx %o4, [%sp + STACK_BIAS + 136]
|
|
ldx [%sp + STACK_BIAS + 136], %fsr
|
|
fabss %f1, %f14
|
|
ld [%sp + STACK_BIAS + 128], %f16
|
|
fcmps %fcc3, %f14, %f16
|
|
fmovsuge %fcc3, ZERO, %f16
|
|
fands %f1, SIGN_BIT, SIGN_BIT
|
|
fors %f16, SIGN_BIT, %f16
|
|
fadds %f1, %f16, %f5
|
|
fsubs %f5, %f16, %f0
|
|
fabss %f0, %f0
|
|
fors %f0, SIGN_BIT, %f0
|
|
retl
|
|
ldx [%sp + STACK_BIAS + 144], %fsr
|
|
END (__nearbyintf)
|
|
libm_alias_float (__nearbyint, nearbyint)
|