mirror of
https://sourceware.org/git/glibc.git
synced 2024-12-09 04:41:16 +00:00
3f823e87cc
On aarch64, alpha, arm, hppa, mips, nios2, powerpc, sh, sparc, tile, and x86_64 the clone syscall jumps to _exit after the child execution and the function ends the process execution by calling exit_group. This behavior have a small issue where threads created with CLONE_THREAD using clone syscall directly will eventually exit the whole group altogether instead of just the thread created. Also, s390, microblaze, ia64, i386, and m68k differs by calling exit syscall directly. This patch changes all architectures to call the exit syscall directly, as for s390, microblaze, ia64, i386, and m68k. This do not have change glibc internal behavior in any sort, since the only usage of clone implementation in posix_spawn calls _exit directly in the created child (fork uses a direct call to clone). Checked on x86_64-linux-gnu, i686-linux-gnu, aarch64-linux-gnu, powerpc-linux-gnu, powerpc64le-linux-gnu, sparc64-linux-gnu, and sparcv9-linux-gnu. [BZ #21512] * sysdeps/unix/sysv/linux/aarch64/clone.S (__clone): Call exit syscall instead of jump to _exit. (CLONE_VM_BIT): Remove unused define. (CLONE_VM): Likewise. (CLONE_THREAD_BIT): Likewise. (CLONE_THREAD): Likewise. * sysdeps/unix/sysv/linux/alpha/clone.S (__clone): Likewise. (CLONE_VM): Remove unused define. * sysdeps/unix/sysv/linux/arm/clone.S (__clone): Likewise. (CLONE_VM): Remove unused define. (CLONE_THREAD): Likewise. * sysdeps/unix/sysv/linux/i386/clone.S (CLONE_VM): Likewise. * sysdeps/unix/sysv/linux/ia64/clone2.S (__clone2): Call exit syscall instead of jump to _exit. * sysdeps/unix/sysv/linux/hppa/clone.S (__clone): Likewise. * sysdeps/unix/sysv/linux/mips/clone.S (__clone): Likewise. (CLONE_VM): Remove unused define. (CLONE_THREAD): Likewise. * sysdeps/unix/sysv/linux/nios2/clone.S (__clone): Likewise. (CLONE_VM): Remove unused define. * sysdeps/unix/sysv/linux/powerpc/powerpc32/clone.S (__clone): Likewise. (CLONE_VM): Remove unused define. (CLONE_THREAD): Likewise. * sysdeps/unix/sysv/linux/powerpc/powerpc64/clone.S (__clone): Likewise. (CLONE_VM): Remove unused define. (CLONE_THREAD): Likewise. * sysdeps/unix/sysv/linux/sh/clone.S (__clone): Likewise. * sysdeps/unix/sysv/linux/sparc/sparc32/clone.S (__clone): Likewise. (CLONE_VM): Remove unused define. * sysdeps/unix/sysv/linux/sparc/sparc64/clone.S (__clone): Likewise. (CLONE_VM): Remove unused define. * sysdeps/unix/sysv/linux/tile/clone.S (__clone): Likewise. * sysdeps/unix/sysv/linux/x86_64/clone.S (__clone): Likewise. (CLONE_VM): Remove unused define. * sysdeps/unix/sysv/linux/Makefile (tests): Add tst-clone3. * sysdeps/unix/sysv/linux/tst-clone3.c: New file. Fix
83 lines
2.1 KiB
ArmAsm
83 lines
2.1 KiB
ArmAsm
/* Copyright (C) 1996-2017 Free Software Foundation, Inc.
|
|
This file is part of the GNU C Library.
|
|
Contributed by Pat Beirne <patb@corelcomputer.com>
|
|
|
|
The GNU C Library is free software; you can redistribute it and/or
|
|
modify it under the terms of the GNU Lesser General Public
|
|
License as published by the Free Software Foundation; either
|
|
version 2.1 of the License, or (at your option) any later version.
|
|
|
|
The GNU C Library is distributed in the hope that it will be useful,
|
|
but WITHOUT ANY WARRANTY; without even the implied warranty of
|
|
MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
|
|
Lesser General Public License for more details.
|
|
|
|
You should have received a copy of the GNU Lesser General Public
|
|
License along with the GNU C Library. If not, see
|
|
<http://www.gnu.org/licenses/>. */
|
|
|
|
/* clone() is even more special than fork() as it mucks with stacks
|
|
and invokes a function in the right context after its all over. */
|
|
|
|
#include <sysdep.h>
|
|
#include <tcb-offsets.h>
|
|
#define _ERRNO_H 1
|
|
#include <bits/errno.h>
|
|
|
|
/* int clone(int (*fn)(void *arg), void *child_stack, int flags, void *arg,
|
|
pid_t *ptid, struct user_desc *tls, pid_t *ctid); */
|
|
|
|
.text
|
|
ENTRY(__clone)
|
|
@ sanity check args
|
|
cmp r0, #0
|
|
ite ne
|
|
cmpne r1, #0
|
|
moveq r0, #-EINVAL
|
|
beq PLTJMP(syscall_error)
|
|
|
|
@ insert the args onto the new stack
|
|
str r3, [r1, #-4]!
|
|
str r0, [r1, #-4]!
|
|
|
|
@ do the system call
|
|
@ get flags
|
|
mov r0, r2
|
|
mov ip, r2
|
|
@ new sp is already in r1
|
|
push {r4, r7}
|
|
cfi_adjust_cfa_offset (8)
|
|
cfi_rel_offset (r4, 0)
|
|
cfi_rel_offset (r7, 4)
|
|
ldr r2, [sp, #8]
|
|
ldr r3, [sp, #12]
|
|
ldr r4, [sp, #16]
|
|
ldr r7, =SYS_ify(clone)
|
|
swi 0x0
|
|
cfi_endproc
|
|
cmp r0, #0
|
|
beq 1f
|
|
pop {r4, r7}
|
|
blt PLTJMP(C_SYMBOL_NAME(__syscall_error))
|
|
RETINSTR(, lr)
|
|
|
|
cfi_startproc
|
|
PSEUDO_END (__clone)
|
|
|
|
1:
|
|
.fnstart
|
|
.cantunwind
|
|
@ pick the function arg and call address off the stack and execute
|
|
ldr r0, [sp, #4]
|
|
ldr ip, [sp], #8
|
|
BLX (ip)
|
|
|
|
@ and we are done, passing the return value through r0
|
|
ldr r7, =SYS_ify(exit)
|
|
swi 0x0
|
|
|
|
.fnend
|
|
|
|
libc_hidden_def (__clone)
|
|
weak_alias (__clone, clone)
|