mirror of
https://sourceware.org/git/glibc.git
synced 2024-12-08 20:40:11 +00:00
3f823e87cc
On aarch64, alpha, arm, hppa, mips, nios2, powerpc, sh, sparc, tile, and x86_64 the clone syscall jumps to _exit after the child execution and the function ends the process execution by calling exit_group. This behavior have a small issue where threads created with CLONE_THREAD using clone syscall directly will eventually exit the whole group altogether instead of just the thread created. Also, s390, microblaze, ia64, i386, and m68k differs by calling exit syscall directly. This patch changes all architectures to call the exit syscall directly, as for s390, microblaze, ia64, i386, and m68k. This do not have change glibc internal behavior in any sort, since the only usage of clone implementation in posix_spawn calls _exit directly in the created child (fork uses a direct call to clone). Checked on x86_64-linux-gnu, i686-linux-gnu, aarch64-linux-gnu, powerpc-linux-gnu, powerpc64le-linux-gnu, sparc64-linux-gnu, and sparcv9-linux-gnu. [BZ #21512] * sysdeps/unix/sysv/linux/aarch64/clone.S (__clone): Call exit syscall instead of jump to _exit. (CLONE_VM_BIT): Remove unused define. (CLONE_VM): Likewise. (CLONE_THREAD_BIT): Likewise. (CLONE_THREAD): Likewise. * sysdeps/unix/sysv/linux/alpha/clone.S (__clone): Likewise. (CLONE_VM): Remove unused define. * sysdeps/unix/sysv/linux/arm/clone.S (__clone): Likewise. (CLONE_VM): Remove unused define. (CLONE_THREAD): Likewise. * sysdeps/unix/sysv/linux/i386/clone.S (CLONE_VM): Likewise. * sysdeps/unix/sysv/linux/ia64/clone2.S (__clone2): Call exit syscall instead of jump to _exit. * sysdeps/unix/sysv/linux/hppa/clone.S (__clone): Likewise. * sysdeps/unix/sysv/linux/mips/clone.S (__clone): Likewise. (CLONE_VM): Remove unused define. (CLONE_THREAD): Likewise. * sysdeps/unix/sysv/linux/nios2/clone.S (__clone): Likewise. (CLONE_VM): Remove unused define. * sysdeps/unix/sysv/linux/powerpc/powerpc32/clone.S (__clone): Likewise. (CLONE_VM): Remove unused define. (CLONE_THREAD): Likewise. * sysdeps/unix/sysv/linux/powerpc/powerpc64/clone.S (__clone): Likewise. (CLONE_VM): Remove unused define. (CLONE_THREAD): Likewise. * sysdeps/unix/sysv/linux/sh/clone.S (__clone): Likewise. * sysdeps/unix/sysv/linux/sparc/sparc32/clone.S (__clone): Likewise. (CLONE_VM): Remove unused define. * sysdeps/unix/sysv/linux/sparc/sparc64/clone.S (__clone): Likewise. (CLONE_VM): Remove unused define. * sysdeps/unix/sysv/linux/tile/clone.S (__clone): Likewise. * sysdeps/unix/sysv/linux/x86_64/clone.S (__clone): Likewise. (CLONE_VM): Remove unused define. * sysdeps/unix/sysv/linux/Makefile (tests): Add tst-clone3. * sysdeps/unix/sysv/linux/tst-clone3.c: New file. Fix
110 lines
2.9 KiB
ArmAsm
110 lines
2.9 KiB
ArmAsm
/* Copyright (C) 1996-2017 Free Software Foundation, Inc.
|
|
This file is part of the GNU C Library.
|
|
Contributed by Andreas Schwab (schwab@issan.informatik.uni-dortmund.de)
|
|
|
|
The GNU C Library is free software; you can redistribute it and/or
|
|
modify it under the terms of the GNU Lesser General Public
|
|
License as published by the Free Software Foundation; either
|
|
version 2.1 of the License, or (at your option) any later version.
|
|
|
|
The GNU C Library is distributed in the hope that it will be useful,
|
|
but WITHOUT ANY WARRANTY; without even the implied warranty of
|
|
MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
|
|
Lesser General Public License for more details.
|
|
|
|
You should have received a copy of the GNU Lesser General Public
|
|
License along with the GNU C Library. If not, see
|
|
<http://www.gnu.org/licenses/>. */
|
|
|
|
/* clone() is even more special than fork() as it mucks with stacks
|
|
and invokes a function in the right context after its all over. */
|
|
|
|
#include <sysdep.h>
|
|
#define _ERRNO_H 1
|
|
#include <bits/errno.h>
|
|
#include <tls.h>
|
|
|
|
/* int clone(int (*fn)(void *arg), void *child_stack, int flags, void *arg,
|
|
void *parent_tidptr, void *tls, void *child_tidptr) */
|
|
|
|
.text
|
|
ENTRY (__clone)
|
|
|
|
/* Sanity check arguments. */
|
|
movel #-EINVAL, %d0
|
|
movel 4(%sp), %a0 /* no NULL function pointers */
|
|
tstl %a0
|
|
jeq SYSCALL_ERROR_LABEL
|
|
movel 8(%sp), %a1 /* no NULL stack pointers */
|
|
tstl %a1
|
|
jeq SYSCALL_ERROR_LABEL
|
|
|
|
/* Allocate space and copy the argument onto the new stack. */
|
|
movel 16(%sp), -(%a1)
|
|
|
|
/* Do the system call */
|
|
movel 12+0(%sp), %d1 /* get flags */
|
|
movel %d3, -(%a1) /* save %d3 and get parent_tidptr */
|
|
movel %d3, -(%sp)
|
|
cfi_adjust_cfa_offset (4)
|
|
cfi_rel_offset (%d3, 0)
|
|
movel 20+4(%sp), %d3
|
|
movel %d4, -(%a1) /* save %d4 and get child_tidptr */
|
|
movel %d4, -(%sp)
|
|
cfi_adjust_cfa_offset (4)
|
|
cfi_rel_offset (%d4, 0)
|
|
movel 28+8(%sp), %d4
|
|
movel %d5, -(%a1) /* save %d5 and get tls */
|
|
movel %d5, -(%sp)
|
|
cfi_adjust_cfa_offset (4)
|
|
cfi_rel_offset (%d5, 0)
|
|
movel 24+12(%sp), %d5
|
|
/* save %d2 and get stack pointer */
|
|
#ifdef __mcoldfire__
|
|
movel %d2, -(%a1)
|
|
movel %d2, -(%sp)
|
|
cfi_adjust_cfa_offset (4)
|
|
cfi_rel_offset (%d2, 0)
|
|
movel %a1, %d2
|
|
#else
|
|
exg %d2, %a1 /* save %d2 and get stack pointer */
|
|
cfi_register (%d2, %a1)
|
|
#endif
|
|
movel #SYS_ify (clone), %d0
|
|
|
|
/* End FDE now, because in the child the unwind info will be
|
|
wrong. */
|
|
cfi_endproc
|
|
|
|
trap #0
|
|
#ifdef __mcoldfire__
|
|
movel (%sp)+, %d2
|
|
#else
|
|
exg %d2, %a1 /* restore %d2 */
|
|
#endif
|
|
movel (%sp)+, %d5 /* restore %d5, %d4 and %d3 */
|
|
movel (%sp)+, %d4
|
|
movel (%sp)+, %d3
|
|
|
|
tstl %d0
|
|
jmi SYSCALL_ERROR_LABEL
|
|
jeq 1f
|
|
|
|
rts
|
|
|
|
1:
|
|
cfi_startproc
|
|
cfi_undefined (pc) /* Mark end of stack */
|
|
subl %fp, %fp /* terminate the stack frame */
|
|
jsr (%a0)
|
|
movel %d0, %d1
|
|
movel #SYS_ify (exit), %d0
|
|
trap #0
|
|
cfi_endproc
|
|
|
|
cfi_startproc
|
|
PSEUDO_END (__clone)
|
|
|
|
libc_hidden_def (__clone)
|
|
weak_alias (__clone, clone)
|