mirror of
https://sourceware.org/git/glibc.git
synced 2024-11-17 02:20:10 +00:00
5ac4c397b7
* sysdeps/mips/elf/start.S: Use __PIC__ instead of PIC. * sysdeps/mips/mips64/add_n.S: Likewise. * sysdeps/mips/mips64/bsd-_setjmp.S: Likewise. * sysdeps/mips/mips64/lshift.S: Likewise. * sysdeps/mips/mips64/mul_1.S: Likewise. * sysdeps/mips/mips64/rshift.S: Likewise. * sysdeps/mips/mips64/setjmp.S: Likewise. * sysdeps/mips/mips64/sub_n.S: Likewise. * sysdeps/mips/mips64/submul_1.S: Likewise. * sysdeps/mips/dl-machine.h (elf_machine_got_rel): Remove strtab and update comment. The strtab from _dl_relocate_object can be used.
130 lines
2.4 KiB
ArmAsm
130 lines
2.4 KiB
ArmAsm
/* MIPS3 __mpn_add_n -- Add two limb vectors of the same length > 0 and
|
|
* store sum in a third limb vector.
|
|
*
|
|
* Copyright (C) 1995, 2000 Free Software Foundation, Inc.
|
|
*
|
|
* This file is part of the GNU MP Library.
|
|
*
|
|
* The GNU MP Library is free software; you can redistribute it and/or modify
|
|
* it under the terms of the GNU Library General Public License as published by
|
|
* the Free Software Foundation; either version 2 of the License, or (at your
|
|
* option) any later version.
|
|
*
|
|
* The GNU MP Library is distributed in the hope that it will be useful, but
|
|
* WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
|
|
* or FITNESS FOR A PARTICULAR PURPOSE. See the GNU Library General Public
|
|
* License for more details.
|
|
*
|
|
* You should have received a copy of the GNU Library General Public License
|
|
* along with the GNU MP Library; see the file COPYING.LIB. If not, write to
|
|
* the Free Software Foundation, Inc., 59 Temple Place - Suite 330, Boston,
|
|
* MA 02111-1307, USA.
|
|
*/
|
|
|
|
#include <sysdep.h>
|
|
|
|
/*
|
|
* INPUT PARAMETERS
|
|
* res_ptr $4
|
|
* s1_ptr $5
|
|
* s2_ptr $6
|
|
* size $7
|
|
*/
|
|
#ifdef __PIC__
|
|
.option pic2
|
|
#endif
|
|
.text
|
|
.align 2
|
|
.globl __mpn_add_n
|
|
.ent __mpn_add_n
|
|
__mpn_add_n:
|
|
.set noreorder
|
|
#ifdef __PIC__
|
|
.cpload t9
|
|
#endif
|
|
.set nomacro
|
|
|
|
ld $10,0($5)
|
|
ld $11,0($6)
|
|
|
|
daddiu $7,$7,-1
|
|
and $9,$7,4-1 # number of limbs in first loop
|
|
beq $9,$0,.L0 # if multiple of 4 limbs, skip first loop
|
|
move $2,$0
|
|
|
|
dsubu $7,$7,$9
|
|
|
|
.Loop0: daddiu $9,$9,-1
|
|
ld $12,8($5)
|
|
daddu $11,$11,$2
|
|
ld $13,8($6)
|
|
sltu $8,$11,$2
|
|
daddu $11,$10,$11
|
|
sltu $2,$11,$10
|
|
sd $11,0($4)
|
|
or $2,$2,$8
|
|
|
|
daddiu $5,$5,8
|
|
daddiu $6,$6,8
|
|
move $10,$12
|
|
move $11,$13
|
|
bne $9,$0,.Loop0
|
|
daddiu $4,$4,8
|
|
|
|
.L0: beq $7,$0,.Lend
|
|
nop
|
|
|
|
.Loop: daddiu $7,$7,-4
|
|
|
|
ld $12,8($5)
|
|
daddu $11,$11,$2
|
|
ld $13,8($6)
|
|
sltu $8,$11,$2
|
|
daddu $11,$10,$11
|
|
sltu $2,$11,$10
|
|
sd $11,0($4)
|
|
or $2,$2,$8
|
|
|
|
ld $10,16($5)
|
|
daddu $13,$13,$2
|
|
ld $11,16($6)
|
|
sltu $8,$13,$2
|
|
daddu $13,$12,$13
|
|
sltu $2,$13,$12
|
|
sd $13,8($4)
|
|
or $2,$2,$8
|
|
|
|
ld $12,24($5)
|
|
daddu $11,$11,$2
|
|
ld $13,24($6)
|
|
sltu $8,$11,$2
|
|
daddu $11,$10,$11
|
|
sltu $2,$11,$10
|
|
sd $11,16($4)
|
|
or $2,$2,$8
|
|
|
|
ld $10,32($5)
|
|
daddu $13,$13,$2
|
|
ld $11,32($6)
|
|
sltu $8,$13,$2
|
|
daddu $13,$12,$13
|
|
sltu $2,$13,$12
|
|
sd $13,24($4)
|
|
or $2,$2,$8
|
|
|
|
daddiu $5,$5,32
|
|
daddiu $6,$6,32
|
|
|
|
bne $7,$0,.Loop
|
|
daddiu $4,$4,32
|
|
|
|
.Lend: daddu $11,$11,$2
|
|
sltu $8,$11,$2
|
|
daddu $11,$10,$11
|
|
sltu $2,$11,$10
|
|
sd $11,0($4)
|
|
j $31
|
|
or $2,$2,$8
|
|
|
|
.end __mpn_add_n
|