mirror of
https://sourceware.org/git/glibc.git
synced 2024-12-02 09:40:13 +00:00
581c785bf3
I used these shell commands: ../glibc/scripts/update-copyrights $PWD/../gnulib/build-aux/update-copyright (cd ../glibc && git commit -am"[this commit message]") and then ignored the output, which consisted lines saying "FOO: warning: copyright statement not found" for each of 7061 files FOO. I then removed trailing white space from math/tgmath.h, support/tst-support-open-dev-null-range.c, and sysdeps/x86_64/multiarch/strlen-vec.S, to work around the following obscure pre-commit check failure diagnostics from Savannah. I don't know why I run into these diagnostics whereas others evidently do not. remote: *** 912-#endif remote: *** 913: remote: *** 914- remote: *** error: lines with trailing whitespace found ... remote: *** error: sysdeps/unix/sysv/linux/statx_cp.c: trailing lines
120 lines
2.3 KiB
ArmAsm
120 lines
2.3 KiB
ArmAsm
/* Copy memory block and return pointer to beginning of destination block
|
|
For Intel 80x86, x>=6.
|
|
This file is part of the GNU C Library.
|
|
Copyright (C) 2003-2022 Free Software Foundation, Inc.
|
|
|
|
The GNU C Library is free software; you can redistribute it and/or
|
|
modify it under the terms of the GNU Lesser General Public
|
|
License as published by the Free Software Foundation; either
|
|
version 2.1 of the License, or (at your option) any later version.
|
|
|
|
The GNU C Library is distributed in the hope that it will be useful,
|
|
but WITHOUT ANY WARRANTY; without even the implied warranty of
|
|
MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
|
|
Lesser General Public License for more details.
|
|
|
|
You should have received a copy of the GNU Lesser General Public
|
|
License along with the GNU C Library; if not, see
|
|
<https://www.gnu.org/licenses/>. */
|
|
|
|
#include <sysdep.h>
|
|
#include "asm-syntax.h"
|
|
|
|
#define PARMS 4+4 /* one spilled register */
|
|
#define RTN PARMS
|
|
|
|
.text
|
|
|
|
#ifdef USE_AS_BCOPY
|
|
# define SRC RTN
|
|
# define DEST SRC+4
|
|
# define LEN DEST+4
|
|
#else
|
|
# define DEST RTN
|
|
# define SRC DEST+4
|
|
# define LEN SRC+4
|
|
|
|
# if defined PIC && IS_IN (libc)
|
|
ENTRY_CHK (__memmove_chk)
|
|
movl 12(%esp), %eax
|
|
cmpl %eax, 16(%esp)
|
|
jb HIDDEN_JUMPTARGET (__chk_fail)
|
|
END_CHK (__memmove_chk)
|
|
# endif
|
|
#endif
|
|
|
|
ENTRY (memmove)
|
|
|
|
pushl %edi
|
|
cfi_adjust_cfa_offset (4)
|
|
|
|
movl LEN(%esp), %ecx
|
|
movl DEST(%esp), %edi
|
|
cfi_rel_offset (edi, 0)
|
|
movl %esi, %edx
|
|
movl SRC(%esp), %esi
|
|
cfi_register (esi, edx)
|
|
|
|
movl %edi, %eax
|
|
subl %esi, %eax
|
|
cmpl %eax, %ecx
|
|
ja 3f
|
|
|
|
cld
|
|
shrl $1, %ecx
|
|
jnc 1f
|
|
movsb
|
|
1: shrl $1, %ecx
|
|
jnc 2f
|
|
movsw
|
|
2: rep
|
|
movsl
|
|
movl %edx, %esi
|
|
cfi_restore (esi)
|
|
#ifndef USE_AS_BCOPY
|
|
movl DEST(%esp), %eax
|
|
#endif
|
|
|
|
popl %edi
|
|
cfi_adjust_cfa_offset (-4)
|
|
cfi_restore (edi)
|
|
|
|
ret
|
|
|
|
cfi_adjust_cfa_offset (4)
|
|
cfi_rel_offset (edi, 0)
|
|
cfi_register (esi, edx)
|
|
|
|
/* Backward copying. */
|
|
3: std
|
|
leal -1(%edi, %ecx), %edi
|
|
leal -1(%esi, %ecx), %esi
|
|
shrl $1, %ecx
|
|
jnc 1f
|
|
movsb
|
|
1: subl $1, %edi
|
|
subl $1, %esi
|
|
shrl $1, %ecx
|
|
jnc 2f
|
|
movsw
|
|
2: subl $2, %edi
|
|
subl $2, %esi
|
|
rep
|
|
movsl
|
|
movl %edx, %esi
|
|
cfi_restore (esi)
|
|
#ifndef USE_AS_BCOPY
|
|
movl DEST(%esp), %eax
|
|
#endif
|
|
|
|
cld
|
|
popl %edi
|
|
cfi_adjust_cfa_offset (-4)
|
|
cfi_restore (edi)
|
|
|
|
ret
|
|
END (memmove)
|
|
#ifndef USE_AS_BCOPY
|
|
libc_hidden_builtin_def (memmove)
|
|
#endif
|