mirror of
https://sourceware.org/git/glibc.git
synced 2024-10-01 03:27:48 +00:00
b15cb49505
2000-10-14 Ulrich Drepper <drepper@redhat.com> * math/libm-test.inc (frexp_test): Add L suffix also to parameters. (hypot_test): Likewise. * sysdeps/generic/printf_fphex.c: Compute width of decimal point string correctly. Handle padding correctly. * sysdeps/ia64/fpu/printf_fphex.c: Use sizeof in _itowa parameters correctly. * sysdeps/ieee754/ldbl-128/printf_fphex.c: Likewise. * sysdeps/ieee754/ldbl-96/printf_fphex.c: Likewise. 2000-10-12 Alan Modra <alan@linuxcare.com.au> * FAQ.in: Add --start-group and --end-group. 2000-10-12 Alan Modra <alan@linuxcare.com.au> * malloc/memusage.c: Conditionalize stack usage calculation on stack direction. 2000-10-12 Alan Modra <alan@linuxcare.com.au> * config.h.in: Add ASM_LINE_SEP. * configure.in: Add test for comment and line separators. * include/libc-symbols.h: Define and use ASM_LINE_SEP, and add tabs to placate some hppa assemblers. * sysdeps/hppa/sysdep.h: Likewise. * sysdeps/gnu/siglist.c: Insert \n and \t into inline asm. * sysdeps/unix/sysv/linux/errlist.c: Likewise. 2000-10-12 David Huggins-Daines <dhd@linuxcare.com> * sysdeps/unix/sysv/linux/Makefile: Include <bits/initspin> in $(sysdep_headers). * sysdeps/unix/sysv/linux/bits/initspin.h: Dummy version for non-threaded platforms. 2000-10-12 David Huggins-Daines <dhd@linuxcare.com> * configure.in: Add definitions for hppa. * elf/elf.h: Add PLABEL32 relocation for hppa ELF32, comments for IPLT and EPLT relocations. * shlib-versions: Version symbol definitions for hppa-linux. * sysdeps/unix/sysv/linux/configure.in: Define $arch_minimum_kernel for hppa. 2000-10-12 David Huggins-Daines <dhd@linuxcare.com> * sysdeps/hppa/Makefile: New file. * sysdeps/hppa/Versions: New file. * sysdeps/hppa/setjmp.S: New file. * sysdeps/hppa/__longjmp.S: New file. * sysdeps/hppa/bits/setjmp.h: New file. * sysdeps/hppa/frame.h: New file. * sysdeps/hppa/add_n.s: Don't use %r19 (linkage table pointer). * sysdeps/hppa/sub_n.s: Likewise. * sysdeps/hppa/lshift.s: Likewise. * sysdeps/hppa/rshift.s: Likewise. * sysdeps/hppa/udiv_qrnnd.s: Likewise. * sysdeps/hppa/hppa1.1/addmul_1.s: Likewise. * sysdeps/hppa/hppa1.1/submul_1.s: Likewise. * sysdeps/hppa/hppa1.1/mul_1.s: Likewise. * sysdeps/hppa/hppa1.1/udiv_qrnnd.s: Likewise. * sysdeps/hppa/dl-machine.h: New file. * sysdeps/hppa/dl-fptr.c: New file (note that this is almost identical to the IA-64 one). * sysdeps/hppa/dl-lookupcfg.h: Likewise. * sysdeps/hppa/dl-symaddr.c: Likewise. * sysdeps/hppa/elf/initfini.c: New file. * sysdeps/hppa/elf/start.S: New file. * sysdeps/hppa/fpu/bits/fenv.h: New file. * sysdeps/hppa/fpu/fclrexcpt.c: New file. * sysdeps/hppa/fpu/fedisblxcpt.c: New file. * sysdeps/hppa/fpu/feenablxcpt.c: New file. * sysdeps/hppa/fpu/fegetenv.c: New file. * sysdeps/hppa/fpu/fegetexcept.c: New file. * sysdeps/hppa/fpu/fegetround.c: New file. * sysdeps/hppa/fpu/feholdexcpt.c: New file. * sysdeps/hppa/fpu/fesetenv.c: New file. * sysdeps/hppa/fpu/fesetround.c: New file. * sysdeps/hppa/fpu/feupdateenv.c: New file. * sysdeps/hppa/fpu/fegetexcptflg.c: New file. * sysdeps/hppa/fpu/fraiseexcpt.c: New file. * sysdeps/hppa/fpu/fsetexcptflg.c: New file. * sysdeps/hppa/fpu/ftestexcept.c: New file. * sysdeps/unix/sysv/linux/hppa/Makefile: New file. * sysdeps/unix/sysv/linux/hppa/Versions: New file. * sysdeps/unix/sysv/linux/hppa/syscalls.list: New file. * sysdeps/unix/sysv/linux/hppa/sysdep.c: New file. * sysdeps/unix/sysv/linux/hppa/sysdep.h: New file. * sysdeps/unix/sysv/linux/hppa/bits/fcntl.h: New file. * sysdeps/unix/sysv/linux/hppa/bits/ioctls.h: New file. * sysdeps/unix/sysv/linux/hppa/bits/mman.h: New file. * sysdeps/unix/sysv/linux/hppa/bits/sigaction.h: New file. * sysdeps/unix/sysv/linux/hppa/bits/signum.h: New file. * sysdeps/unix/sysv/linux/hppa/brk.c: New file. * sysdeps/unix/sysv/linux/hppa/clone.S: New file. * sysdeps/unix/sysv/linux/hppa/socket.S: New file. * sysdeps/unix/sysv/linux/hppa/syscall.S: New file. * sysdeps/unix/sysv/linux/hppa/setrlimit.c: New file. * sysdeps/unix/sysv/linux/hppa/getrlimit.c: New file. * sysdeps/unix/sysv/linux/hppa/getrlimit64.c: New file. * sysdeps/unix/sysv/linux/hppa/kernel_sigaction.h: New file. * sysdeps/unix/sysv/linux/hppa/kernel_stat.h: New file. * sysdeps/unix/sysv/linux/hppa/mmap.c: New file. * sysdeps/unix/sysv/linux/hppa/profil-counter.h: New file. * sysdeps/unix/sysv/linux/hppa/procfs.h: New file. * sysdeps/unix/sysv/linux/hppa/ucontext.h: New file. * sysdeps/unix/sysv/linux/hppa/umount.c: New file. 2000-10-12 Alan Modra <alan@linuxcare.com.au> * sysdeps/hppa/hppa1.1/Implies: New file. * sysdeps/hppa/memusage.h: New file.
101 lines
3.0 KiB
ArmAsm
101 lines
3.0 KiB
ArmAsm
;! HP-PA-1.1 __mpn_mul_1 -- Multiply a limb vector with a limb and store
|
|
;! the result in a second limb vector.
|
|
|
|
;! Copyright (C) 1992, 1993, 1994 Free Software Foundation, Inc.
|
|
|
|
;! This file is part of the GNU MP Library.
|
|
|
|
;! The GNU MP Library is free software; you can redistribute it and/or modify
|
|
;! it under the terms of the GNU Library General Public License as published by
|
|
;! the Free Software Foundation; either version 2 of the License, or (at your
|
|
;! option) any later version.
|
|
|
|
;! The GNU MP Library is distributed in the hope that it will be useful, but
|
|
;! WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
|
|
;! or FITNESS FOR A PARTICULAR PURPOSE. See the GNU Library General Public
|
|
;! License for more details.
|
|
|
|
;! You should have received a copy of the GNU Library General Public License
|
|
;! along with the GNU MP Library; see the file COPYING.LIB. If not, write to
|
|
;! the Free Software Foundation, Inc., 59 Temple Place - Suite 330, Boston,
|
|
;! MA 02111-1307, USA.
|
|
|
|
|
|
;! INPUT PARAMETERS
|
|
;! res_ptr r26
|
|
;! s1_ptr r25
|
|
;! size r24
|
|
;! s2_limb r23
|
|
|
|
;! This runs at 9 cycles/limb on a PA7000. With the used instructions, it can
|
|
;! not become faster due to data cache contention after a store. On the
|
|
;! PA7100 it runs at 7 cycles/limb, and that can not be improved either, since
|
|
;! only the xmpyu does not need the integer pipeline, so the only dual-issue
|
|
;! we will get are addc+xmpyu. Unrolling would not help either CPU.
|
|
|
|
;! We could use fldds to read two limbs at a time from the S1 array, and that
|
|
;! could bring down the times to 8.5 and 6.5 cycles/limb for the PA7000 and
|
|
;! PA7100, respectively. We don't do that since it does not seem worth the
|
|
;! (alignment) troubles...
|
|
|
|
;! At least the PA7100 is rumored to be able to deal with cache-misses
|
|
;! without stalling instruction issue. If this is true, and the cache is
|
|
;! actually also lockup-free, we should use a deeper software pipeline, and
|
|
;! load from S1 very early; (The loads and stores to -12(sp) will surely be
|
|
;! in the cache.)
|
|
|
|
.text
|
|
.export __mpn_mul_1
|
|
__mpn_mul_1:
|
|
.proc
|
|
.callinfo frame=64,no_calls
|
|
.entry
|
|
|
|
ldo 64(%r30),%r30
|
|
fldws,ma 4(%r25),%fr5
|
|
stw %r23,-16(%r30) ;! move s2_limb ...
|
|
addib,= -1,%r24,L$just_one_limb
|
|
fldws -16(%r30),%fr4 ;! ... into fr4
|
|
add %r0,%r0,%r0 ;! clear carry
|
|
xmpyu %fr4,%fr5,%fr6
|
|
fldws,ma 4(%r25),%fr7
|
|
fstds %fr6,-16(%r30)
|
|
xmpyu %fr4,%fr7,%fr8
|
|
ldw -12(%r30),%r20 ;! least significant limb in product
|
|
ldw -16(%r30),%r28
|
|
|
|
fstds %fr8,-16(%r30)
|
|
addib,= -1,%r24,L$end
|
|
ldw -12(%r30),%r1
|
|
|
|
;! Main loop
|
|
L$loop:
|
|
fldws,ma 4(%r25),%fr5
|
|
stws,ma %r20,4(%r26)
|
|
addc %r28,%r1,%r20
|
|
xmpyu %fr4,%fr5,%fr6
|
|
ldw -16(%r30),%r28
|
|
fstds %fr6,-16(%r30)
|
|
addib,<> -1,%r24,L$loop
|
|
ldw -12(%r30),%r1
|
|
|
|
L$end:
|
|
stws,ma %r20,4(%r26)
|
|
addc %r28,%r1,%r20
|
|
ldw -16(%r30),%r28
|
|
stws,ma %r20,4(%r26)
|
|
addc %r0,%r28,%r28
|
|
bv 0(%r2)
|
|
ldo -64(%r30),%r30
|
|
|
|
L$just_one_limb:
|
|
xmpyu %fr4,%fr5,%fr6
|
|
fstds %fr6,-16(%r30)
|
|
ldw -16(%r30),%r28
|
|
ldo -64(%r30),%r30
|
|
bv 0(%r2)
|
|
fstws %fr6R,0(%r26)
|
|
|
|
.exit
|
|
.procend
|