mirror of
https://sourceware.org/git/glibc.git
synced 2024-09-20 08:30:00 +00:00
df179d8808
The i386/x86_64 versions of logl return sNaN for sNaN input. This patch fixes them to add a NaN input to itself so that qNaN is returned in this case. Tested for x86_64 and x86 (including a build for i586 to cover the non-i686 logl version). [BZ #20227] * sysdeps/i386/fpu/e_logl.S (__ieee754_logl): Add NaN input to itself. * sysdeps/i386/i686/fpu/e_logl.S (__ieee754_logl): Likewise. * sysdeps/x86_64/fpu/e_logl.S (__ieee754_logl): Likewise. * math/libm-test.inc (log_test_data): Add sNaN tests.
95 lines
2.0 KiB
ArmAsm
95 lines
2.0 KiB
ArmAsm
/*
|
|
* Written by J.T. Conklin <jtc@netbsd.org>.
|
|
* Public domain.
|
|
*
|
|
* Adapted for `long double' by Ulrich Drepper <drepper@cygnus.com>.
|
|
* Changed to use fyl2xp1 for values near 1, <drepper@cygnus.com>.
|
|
* Adapted for i686 instructions.
|
|
*/
|
|
|
|
#include <machine/asm.h>
|
|
|
|
.section .rodata.cst8,"aM",@progbits,8
|
|
|
|
.p2align 3
|
|
.type one,@object
|
|
one: .double 1.0
|
|
ASM_SIZE_DIRECTIVE(one)
|
|
/* It is not important that this constant is precise. It is only
|
|
a value which is known to be on the safe side for using the
|
|
fyl2xp1 instruction. */
|
|
.type limit,@object
|
|
limit: .double 0.29
|
|
ASM_SIZE_DIRECTIVE(limit)
|
|
|
|
|
|
#ifdef PIC
|
|
# define MO(op) op##@GOTOFF(%edx)
|
|
#else
|
|
# define MO(op) op
|
|
#endif
|
|
|
|
.text
|
|
ENTRY(__ieee754_logl)
|
|
fldln2 // log(2)
|
|
fldt 4(%esp) // x : log(2)
|
|
fucomi %st
|
|
jp 3f
|
|
#ifdef PIC
|
|
LOAD_PIC_REG (dx)
|
|
#endif
|
|
fld %st // x : x : log(2)
|
|
movzwl 4+8(%esp), %eax
|
|
cmpl $0xc000, %eax
|
|
jae 5f // x <= -2, avoid overflow from -LDBL_MAX - 1.
|
|
fsubl MO(one) // x-1 : x : log(2)
|
|
5: fld %st // x-1 : x-1 : x : log(2)
|
|
fabs // |x-1| : x-1 : x : log(2)
|
|
fld MO(limit) // 0.29 : |x-1| : x-1 : x : log(2)
|
|
fcomip %st(1) // |x-1| : x-1 : x : log(2)
|
|
fstp %st(0) // x-1 : x : log(2)
|
|
jc 2f
|
|
fxam
|
|
fnstsw
|
|
andb $0x45, %ah
|
|
cmpb $0x40, %ah
|
|
jne 4f
|
|
fabs // log(1) is +0 in all rounding modes.
|
|
4: fstp %st(1) // x-1 : log(2)
|
|
fyl2xp1 // log(x)
|
|
ret
|
|
|
|
2: fstp %st(0) // x : log(2)
|
|
fyl2x // log(x)
|
|
ret
|
|
|
|
3: fstp %st(1)
|
|
fadd %st(0)
|
|
ret
|
|
END (__ieee754_logl)
|
|
|
|
ENTRY(__logl_finite)
|
|
fldln2 // log(2)
|
|
fldt 4(%esp) // x : log(2)
|
|
#ifdef PIC
|
|
LOAD_PIC_REG (dx)
|
|
#endif
|
|
fld %st // x : x : log(2)
|
|
fsubl MO(one) // x-1 : x : log(2)
|
|
fld %st // x-1 : x-1 : x : log(2)
|
|
fabs // |x-1| : x-1 : x : log(2)
|
|
fld MO(limit) // 0.29 : |x-1| : x-1 : x : log(2)
|
|
fcomip %st(1) // |x-1| : x-1 : x : log(2)
|
|
fstp %st(0) // x-1 : x : log(2)
|
|
jc 2b
|
|
fxam
|
|
fnstsw
|
|
andb $0x45, %ah
|
|
cmpb $0x40, %ah
|
|
jne 6f
|
|
fabs // log(1) is +0 in all rounding modes.
|
|
6: fstp %st(1) // x-1 : log(2)
|
|
fyl2xp1 // log(x)
|
|
ret
|
|
END(__logl_finite)
|