mirror of
https://sourceware.org/git/glibc.git
synced 2024-09-20 16:40:54 +00:00
5ae9d168f6
1997-03-21 20:55 Ulrich Drepper <drepper@cygnus.com> * sysdeps/generic/machine-gmon.h: Update copyright. * sysdeps/i386/Makefile [$(subdir)=gmon] (sysdep_routines): Add i386-mcount. * sysdeps/i386/dl-machine.h [PROF] (_dl_runtime_resolve): Don't use regparam mechanism for call of `fixup' call. * sysdeps/i386/Dist: New file. * sysdeps/i386/i386-mcount.S: New file. `mcount' entry point. * sysdeps/i386/machine-gmon.h: New file. i386 specific version of gmon definitions. 1997-03-20 13:39 Andreas Jaeger <aj@arthur.pfalz.de> * stdlib/tst-strtol.c (main): Save the value of errno since printf may modify it, use the saved errno everywhere. * stdlib/tst-strtod.c (main): Likewise. 1997-03-21 05:54 Ulrich Drepper <drepper@cygnus.com> * posix/glob.c (glob): Fix completely broken handling of GLOB_BRACE and partly broken handling of GLOB_TILDE. Reported by Dennis Henriksen <opus@flamingo.osrl.dk>. 1997-03-20 20:22 Ulrich Drepper <drepper@cygnus.com> * sysdeps/unix/sysv/linux/readv.c: Don't emulate readv with small UIO_FASTIOV value by multiple readv calls since we need atomicity. * sysdeps/unix/sysv/linux/writev.c: Likewise. Reported by Matthis Urlichs. 1997-03-20 04:34 Roland McGrath <roland@baalperazim.frob.com> * sysdeps/unix/sysv/linux/i386/sysdep.S (CALL_MCOUNT): Clear this macro so ENTRY(__syscall_error) doesn't insert a call to _mcount, which clobbers %eax. * Makeconfig [$(elf)=yes] (+prector, +postctor): New variables for crtbegin.o/crtend.o, using gcc to find them. (+link): Use them. 1997-03-20 00:06 Richard Henderson <rth@tamu.edu> * gmon/sys/gmon.h: Revert the bulk of the 960930 changes, as they affect the alignment, and therefore the end padding of the structs. Reported by David Mosberger <davidm@azstarnet.com>. * gmon.c: Declare the variables with aligned tags to compensate. Use __writev instead of write for the I/O. * misc/sys/uio.h: Declare __writev and __readv. * sysdeps/posix/readv.c: Rename and alias readv to __readv. * sysdeps/posix/writev.c: Likewise for writev. * sysdeps/stub/readv.c: Likewise. * sysdeps/stub/writev.c: Likewise. * sysdeps/unix/syscalls.list: Likewise. * sysdeps/unix/sysv/linux/readv.c: Likewise. * sysdeps/unix/sysv/linux/writev.c: Likewise. * stdlib/testdiv.c: Exit with error status when we have an error. * sysdeps/alpha/div.S: Initialize `quotient' and `mask'. * sysdeps/alpha/ldiv.S: Likewise. * sysdeps/unix/sysv/linux/alpha/ioperm.c: Include ctype.h for isdigit. 1997-03-20 14:51 Ulrich Drepper <drepper@cygnus.com> * nis/nis_file.c: Unify error handling. 1997-03-19 18:36 Thorsten Kukuk <kukuk@vt.uni-paderborn.de> * nis/nis_file.c (writeColdStartFile): Fix typo. * nis/nis_free.c (nis_free_endpoints): Use unsigned int. * nis/nis_free.c (nis_free_servers): Likewise. * nis/rpcsvc/nislib.h: Likewise. * sunrpc/rpc/netdb.h: Add setrpcent and endrpcent prototypes.
109 lines
2.8 KiB
ArmAsm
109 lines
2.8 KiB
ArmAsm
/* Copyright (C) 1996, 1997 Free Software Foundation, Inc.
|
|
This file is part of the GNU C Library.
|
|
Contributed by Richard Henderson <rth@tamu.edu>.
|
|
|
|
The GNU C Library is free software; you can redistribute it and/or
|
|
modify it under the terms of the GNU Library General Public License as
|
|
published by the Free Software Foundation; either version 2 of the
|
|
License, or (at your option) any later version.
|
|
|
|
The GNU C Library is distributed in the hope that it will be useful,
|
|
but WITHOUT ANY WARRANTY; without even the implied warranty of
|
|
MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
|
|
Library General Public License for more details.
|
|
|
|
You should have received a copy of the GNU Library General Public
|
|
License along with the GNU C Library; see the file COPYING.LIB. If not,
|
|
write to the Free Software Foundation, Inc., 59 Temple Place - Suite 330,
|
|
Boston, MA 02111-1307, USA. */
|
|
|
|
#include <sysdep.h>
|
|
|
|
#ifdef __linux__
|
|
# include <asm/gentrap.h>
|
|
# include <asm/pal.h>
|
|
#else
|
|
# include <machine/pal.h>
|
|
#endif
|
|
|
|
.set noat
|
|
|
|
.align 4
|
|
.globl ldiv
|
|
.ent ldiv
|
|
ldiv:
|
|
.frame sp, 0, ra
|
|
#ifdef PROF
|
|
ldgp gp, 0(pv)
|
|
lda AT, _mcount
|
|
jsr AT, (AT), _mcount
|
|
.prologue 1
|
|
#else
|
|
.prologue 0
|
|
#endif
|
|
|
|
#define divisor t1
|
|
#define mask t2
|
|
#define quotient t3
|
|
#define modulus t4
|
|
#define tmp1 t5
|
|
#define tmp2 t6
|
|
#define compare t7
|
|
|
|
/* find correct sign for input to unsigned divide loop. */
|
|
mov a1, modulus # e0 :
|
|
mov a2, divisor # .. e1 :
|
|
negq a1, tmp1 # e0 :
|
|
negq a2, tmp2 # .. e1 :
|
|
mov zero, quotient # e0 :
|
|
mov 1, mask # .. e1 :
|
|
cmovlt a1, tmp1, modulus # e0 :
|
|
cmovlt a2, tmp2, divisor # .. e1 :
|
|
beq a2, $divbyzero # e1 :
|
|
unop # :
|
|
|
|
/* shift divisor left. */
|
|
1: cmpult divisor, modulus, compare # e0 :
|
|
blt divisor, 2f # .. e1 :
|
|
addq divisor, divisor, divisor # e0 :
|
|
addq mask, mask, mask # .. e1 :
|
|
bne compare, 1b # e1 :
|
|
unop # :
|
|
|
|
/* start to go right again. */
|
|
2: addq quotient, mask, tmp2 # e1 :
|
|
srl mask, 1, mask # .. e0 :
|
|
cmpule divisor, modulus, compare # e0 :
|
|
subq modulus, divisor, tmp1 # .. e1 :
|
|
cmovne compare, tmp2, quotient # e1 :
|
|
srl divisor, 1, divisor # .. e0 :
|
|
cmovne compare, tmp1, modulus # e0 :
|
|
bne mask, 2b # .. e1 :
|
|
|
|
/* find correct sign for result. */
|
|
xor a1, a2, compare # e0 :
|
|
negq quotient, tmp1 # .. e1 :
|
|
negq modulus, tmp2 # e0 :
|
|
cmovlt compare, tmp1, quotient # .. e1 :
|
|
cmovlt a1, tmp2, modulus # e1 :
|
|
|
|
/* and store it away in the structure. */
|
|
9: stq quotient, 0(a0) # .. e0 :
|
|
mov a0, v0 # e1 :
|
|
stq modulus, 8(a0) # .. e0 :
|
|
ret # e1 :
|
|
|
|
$divbyzero:
|
|
mov a0, v0
|
|
lda a0, GEN_INTDIV
|
|
call_pal PAL_gentrap
|
|
|
|
/* if trap returns, return zero. */
|
|
stq zero, 0(v0)
|
|
stq zero, 8(v0)
|
|
ret
|
|
|
|
.end ldiv
|
|
|
|
weak_alias(ldiv, lldiv)
|