mirror of
https://sourceware.org/git/glibc.git
synced 2024-10-08 15:07:38 +00:00
510ca033d6
* sysdeps/unix/sysv/linux/alpha/speed.c (speeds): Add entry for 460800 baud. * sysdeps/unix/sysv/linux/alpha/statbuf.h: New file. * sysdeps/unix/sysv/linux/Makefile (headers): Add alpha/ptrace.h. * sysdeps/unix/sysv/linux/alpha/alpha/ptrace.h: New file. * sysdeps/libm-ieee754/s_scalbnf.c: Call __scalbnf instead of scalbnf. * sysdeps/generic/sigset.h (__sigismember, __sigaddset, __sigdelset): Add declaration to keep ANSI compilers quiet. * sysdeps/alpha/__math.h (cabs): Remove underscores from struct __cabs_complex member names in call to __hypot(). * sysdeps/alpha/copysign.S, sysdeps/alpha/fabs.S: New files. * sysdeps/alpha/divrem.h: Renamed from sysdeps/alpha/divrem.S to avoid name collision with math library. * sysdeps/alpha/divl.S, sysdeps/alpha/divlu.S, sysdeps/alpha/divq.S, sysdeps/alpha/divqu.S, sysdeps/alpha/reml.S, sysdeps/alpha/remlu.S, sysdeps/alpha/remq.S, sysdeps/alpha/remqu.S: Include divrem.h instead of divrem.S. * sysdeps/unix/alpha/sysdep.h: Include regdef.h. Define LEAF macro to simplify declaration of leaf functions. * sysdeps/alpha/_mcount.S, sysdeps/alpha/bb_init_func.S, sysdeps/alpha/bsd-setjmp.S, sysdeps/alpha/ffs.S, sysdeps/alpha/htonl.S, sysdeps/alpha/htons.S, sysdeps/alpha/memchr.S, sysdeps/alpha/setjmp.S, sysdeps/alpha/strlen.S, sysdeps/alpha/udiv_qrnnd.S, sysdeps/unix/sysv/linux/alpha/brk.S, sysdeps/unix/sysv/linux/alpha/ieee_get_fp_control.S, sysdeps/unix/sysv/linux/alpha/ieee_set_fp_control.S, sysdeps/unix/sysv/linux/alpha/pipe.S, sysdeps/unix/sysv/linux/sigsuspend.S, sysdeps/unix/sysv/linux/alpha/syscall.S, sysdeps/unix/sysv/linux/alpha/sysdep.S: Remove include of regdef.h. sysdep.h includes it now. Replace ENTRY by LEAF with appropriate framesize declaration. Replace "lda pv,sym/jsr pv" by "jsr sym". * sysdeps/unix/sysv/linux/alpha/sysdep.h (NO_UNDERSCORES): Don't define. * sysdeps/unix/sysv/linux/alpha/syscalls.list: Added getsockopt, ptrace, and sysctl. * sysdeps/unix/sysv/linux/alpha/profil-counter.h: File removed. * sysdeps/unix/sysv/linux/alpha/ioperm.c: Modify to support dynamic recognition of platform type. (_bus_base): New function. * sysdeps/unix/sysv/linux/alpha/llseek.S: New file. * sunrpc/rpc/rpc.h, sunrpc/rpc/svc.h: Avoid nested comments since they produce ugly warnings by gcc. * posix/sys/types.h [__USE_MISC]: Add typedef for ulong. Wed Mar 27 10:26:21 1996 David Mosberger-Tang <davidm@azstarnet.com> * sysdeps/alpha/setjmp.S: Must establish global pointer before address of __sigsetjmp_aux can be loaded.
71 lines
2.2 KiB
ArmAsm
71 lines
2.2 KiB
ArmAsm
/* Copyright (C) 1996 Free Software Foundation, Inc.
|
|
Contributed by David Mosberger (davidm@cs.arizona.edu).
|
|
|
|
This file is part of the GNU C Library.
|
|
|
|
The GNU C Library is free software; you can redistribute it and/or
|
|
modify it under the terms of the GNU Library General Public License as
|
|
published by the Free Software Foundation; either version 2 of the
|
|
License, or (at your option) any later version.
|
|
|
|
The GNU C Library is distributed in the hope that it will be useful,
|
|
but WITHOUT ANY WARRANTY; without even the implied warranty of
|
|
MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
|
|
Library General Public License for more details.
|
|
|
|
You should have received a copy of the GNU Library General Public
|
|
License along with the GNU C Library; see the file COPYING.LIB. If
|
|
not, write to the Free Software Foundation, Inc., 675 Mass Ave,
|
|
Cambridge, MA 02139, USA. */
|
|
|
|
/* Finds length of a 0-terminated string. Optimized for the Alpha
|
|
architecture:
|
|
|
|
- memory accessed as aligned quadwords only
|
|
- uses bcmpge to compare 8 bytes in parallel
|
|
- does binary search to find 0 byte in last
|
|
quadword (HAKMEM needed 12 instructions to
|
|
do this instead of the 9 instructions that
|
|
binary search needs). */
|
|
|
|
#include <sysdep.h>
|
|
|
|
.set noreorder
|
|
.set noat
|
|
|
|
ENTRY(strlen)
|
|
ldq_u t0, 0(a0) # load first quadword (a0 may be misaligned)
|
|
lda t1, -1(zero)
|
|
insqh t1, a0, t1
|
|
andnot a0, 7, v0
|
|
or t1, t0, t0
|
|
cmpbge zero, t0, t1 # t1 <- bitmask: bit i == 1 <==> i-th byte == 0
|
|
bne t1, found
|
|
|
|
loop: ldq t0, 8(v0)
|
|
addq v0, 8, v0 # addr += 8
|
|
nop # helps dual issue last two insns
|
|
cmpbge zero, t0, t1
|
|
beq t1, loop
|
|
|
|
found: blbs t1, done # make aligned case fast
|
|
negq t1, t2
|
|
and t1, t2, t1
|
|
|
|
and t1, 0x0f, t0
|
|
addq v0, 4, t2
|
|
cmoveq t0, t2, v0
|
|
|
|
and t1, 0x33, t0
|
|
addq v0, 2, t2
|
|
cmoveq t0, t2, v0
|
|
|
|
and t1, 0x55, t0
|
|
addq v0, 1, t2
|
|
cmoveq t0, t2, v0
|
|
|
|
done: subq v0, a0, v0
|
|
ret
|
|
|
|
.end strlen
|